DocumentazioneSezioni
MQL5 RiferimentoFunzioni ComuniGetTickCount64 

GetTickCount64

La funzione GetTickCount64() restituisce il numero di millisecondi trascorsi dall'avvio del sistema.

ulong  GetTickCount64();

Valore di ritorno

Un valore di tipo ulong.

Nota

Il contatore è limitato alla precisione del timer di sistema, che di solito restituisce un risultato con una precisione di 10-16 millisecondi. Diversamente da GetTickCount, che è di tipo uint e il cui contenuto overflowa ogni 49.7 giorni in caso di funzionamento continuo del computer, GetTickCount64() può essere utilizzato per un tempo di funzionamento illimitato del computer e non è soggetto ad overflow.

Esempio:

#define MAX_SIZE 40
 
//+------------------------------------------------------------------------------------+
//| Script per misurare il tempo di calcolo di 40 numeri Fibonacci                     |
//+------------------------------------------------------------------------------------+
void OnStart()
  {
   long fib_array[MAX_SIZE];
 
//-- memorizza il valore iniziale
   ulong start=GetTickCount64();
//--- un ciclo, in cui calcoliamo un dato numero di numeri dalla serie di Fibonacci
   for(int i=0;i<MAX_SIZE;i++) 
      fib_array[i]=TestFibo(i);
//-- ottenere il tempo trascorso in millisecondi
   ulong time=GetTickCount64()-start;
 
//-- visualizza il messaggio di errore nel journal dell'Expert
   ArrayPrint(fib_array);
   PrintFormat("Calculating the first %d Fibonacci numbers took %I64u ms",MAX_SIZE,time);
  }
//+--------------------------------------------------------------------------------------------------+
//| Funzione per ottenere un numero di Fibonacci dal suo numero di serie                             |
//+--------------------------------------------------------------------------------------------------+
long TestFibo(long n)
  {
//-- primo membro della serie di Fibonacci
   if(n<2)
      return(1);
//--- tutti i membri successivi sono calcolati utilizzando questa equazione
   return(TestFibo(n-2)+TestFibo(n-1));
  }

Guarda anche

Data ed Ora, EventSetMillisecondTimer, GetTickCount, GetMicrosecondCount