Скачать MetaTrader 5

OBJ_EXPANSION

Расширение Фибоначчи.

ObjFiboExpansion

Примечание

Для "Расширения Фибоначчи" можно указать режим продолжения отображения вправо и/или влево (свойства OBJPROP_RAY_RIGHT и OBJPROP_RAY_LEFT соответственно).

Также можно указать количество линий-уровней, их значения и цвет.

Пример

Следующий скрипт создает и перемещает на графике "Расширение Фибоначчи". Для создания и изменения свойств графического объекта написаны специальные функции, которые вы можете использовать "как есть" в своих собственных программах.

 

//--- описание
#property description "Скрипт строит графический объект \"Расширение Фибоначчи\"."
#property description "Координаты точек привязки задаются в процентах от"
#property description "размеров окна графика."
//--- покажем окно входных параметров при запуске скрипта
#property script_show_inputs
//--- входные параметры скрипта
input string          InpName="FiboExpansion";   // Имя объекта
input int             InpDate1=10;               // Дата 1-ой точки в %
input int             InpPrice1=55;              // Цена 1-ой точки в %
input int             InpDate2=30;               // Дата 2-ой точки в %
input int             InpPrice2=10;              // Цена 2-ой точки в %
input int             InpDate3=80;               // Дата 3-ей точки в %
input int             InpPrice3=75;              // Цена 3-ей точки в %
input color           InpColor=clrRed;           // Цвет объекта
input ENUM_LINE_STYLE InpStyle=STYLE_DASHDOTDOT// Стиль линий
input int             InpWidth=2;                // Толщина линий
input bool            InpBack=false;             // Объект на заднем плане
input bool            InpSelection=true;         // Выделить для перемещений
input bool            InpRayLeft=false;          // Продолжение объекта влево
input bool            InpRayRight=false;         // Продолжение объекта вправо
input bool            InpHidden=true;            // Скрыт в списке объектов
input long            InpZOrder=0;               // Приоритет на нажатие мышью
//+------------------------------------------------------------------+
//| Cоздает "Расширение Фибоначчи" по заданным координатам           |
//+------------------------------------------------------------------+
bool FiboExpansionCreate(const long            chart_ID=0,           // ID графика
                         const string          name="FiboExpansion"// имя канала
                         const int             sub_window=0,         // номер подокна 
                         datetime              time1=0,              // время первой точки
                         double                price1=0,             // цена первой точки
                         datetime              time2=0,              // время второй точки
                         double                price2=0,             // цена второй точки
                         datetime              time3=0,              // время третьей точки
                         double                price3=0,             // цена третьей точки
                         const color           clr=clrRed,           // цвет объекта
                         const ENUM_LINE_STYLE style=STYLE_SOLID,    // стиль линий
                         const int             width=1,              // толщина линий
                         const bool            back=false,           // на заднем плане
                         const bool            selection=true,       // выделить для перемещений
                         const bool            ray_left=false,       // продолжение объекта влево
                         const bool            ray_right=false,      // продолжение объекта вправо
                         const bool            hidden=true,          // скрыт в списке объектов
                         const long            z_order=0)            // приоритет на нажатие мышью
  {
//--- установим координаты точек привязки, если они не заданы
   ChangeFiboExpansionEmptyPoints(time1,price1,time2,price2,time3,price3);
//--- сбросим значение ошибки
   ResetLastError();
//--- создадим "Расширение Фибоначчи" по заданным координатам
   if(!ObjectCreate(chart_ID,name,OBJ_EXPANSION,sub_window,time1,price1,time2,price2,time3,price3))
     {
      Print(__FUNCTION__,
            ": не удалось создать \"Расширение Фибоначчи\"! Код ошибки = ",GetLastError());
      return(false);
     }
//--- установим цвет объекта
   ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- установим стиль линий
   ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- установим толщину линий
   ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- отобразим на переднем (false) или заднем (true) плане
   ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- включим (true) или отключим (false) режим выделения объекта для перемещений
//--- при создании графического объекта функцией ObjectCreate, по умолчанию объект
//--- нельзя выделить и перемещать. Внутри же этого метода параметр selection
//--- по умолчанию равен true, что позволяет выделять и перемещать этот объект
   ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
   ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- включим (true) или отключим (false) режим продолжения отображения объекта влево
   ObjectSetInteger(chart_ID,name,OBJPROP_RAY_LEFT,ray_left);
//--- включим (true) или отключим (false) режим продолжения отображения объекта вправо
   ObjectSetInteger(chart_ID,name,OBJPROP_RAY_RIGHT,ray_right);
//--- скроем (true) или отобразим (false) имя графического объекта в списке объектов
   ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- установим приоритет на получение события нажатия мыши на графике
   ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- успешное выполнение
   return(true);
  }
//+------------------------------------------------------------------+
//| Задает количество уровней и их параметры                         |
//+------------------------------------------------------------------+
bool FiboExpansionLevelsSet(int             levels,               // количество линий уровня
                            double          &values[],            // значения линий уровня
                            color           &colors[],            // цвет линий уровня
                            ENUM_LINE_STYLE &styles[],            // стиль линий уровня
                            int             &widths[],            // толщина линий уровня
                            const long      chart_ID=0,           // ID графика
                            const string    name="FiboExpansion"// имя объекта
  {
//--- проверим размеры массивов
   if(levels!=ArraySize(colors) || levels!=ArraySize(styles) ||
      levels!=ArraySize(widths) || levels!=ArraySize(widths))
     {
      Print(__FUNCTION__,": длина массива не соответствует количеству уровней, ошибка!");
      return(false);
     }
//--- установим количество уровней
   ObjectSetInteger(chart_ID,name,OBJPROP_LEVELS,levels);
//--- установим свойства уровней в цикле
   for(int i=0;i<levels;i++)
     {
      //--- значение уровня
      ObjectSetDouble(chart_ID,name,OBJPROP_LEVELVALUE,i,values[i]);
      //--- цвет уровня
      ObjectSetInteger(chart_ID,name,OBJPROP_LEVELCOLOR,i,colors[i]);
      //--- стиль уровня
      ObjectSetInteger(chart_ID,name,OBJPROP_LEVELSTYLE,i,styles[i]);
      //--- толщина уровня
      ObjectSetInteger(chart_ID,name,OBJPROP_LEVELWIDTH,i,widths[i]);
      //--- описание уровня
      ObjectSetString(chart_ID,name,OBJPROP_LEVELTEXT,i,"FE "+DoubleToString(100*values[i],1));
     }
//--- успешное выполнение
   return(true);
  }
//+------------------------------------------------------------------+
//| Перемещает точку привязки "Расширения Фибоначчи"                 |
//+------------------------------------------------------------------+
bool FiboExpansionPointChange(const long   chart_ID=0,           // ID графика
                              const string name="FiboExpansion"// имя объекта
                              const int    point_index=0,        // номер точки привязки
                              datetime     time=0,               // координата времени точки привязки
                              double       price=0)              // координата цены точки привязки
  {
//--- если координаты точки не заданы, то перемещаем ее на текущий бар с ценой Bid
   if(!time)
      time=TimeCurrent();
   if(!price)
      price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- сбросим значение ошибки
   ResetLastError();
//--- переместим точку привязки
   if(!ObjectMove(chart_ID,name,point_index,time,price))
     {
      Print(__FUNCTION__,
            ": не удалось переместить точку привязки! Код ошибки = ",GetLastError());
      return(false);
     }
//--- успешное выполнение
   return(true);
  }
//+------------------------------------------------------------------+
//| Удаляет "Расширение Фибоначчи"                                   |
//+------------------------------------------------------------------+
bool FiboExpansionDelete(const long   chart_ID=0,           // ID графика
                         const string name="FiboExpansion"// имя объекта
  {
//--- сбросим значение ошибки
   ResetLastError();
//--- удалим объект
   if(!ObjectDelete(chart_ID,name))
     {
      Print(__FUNCTION__,
            ": не удалось удалить \"Расширение Фибоначчи\"! Код ошибки = ",GetLastError());
      return(false);
     }
//--- успешное выполнение
   return(true);
  }
//+------------------------------------------------------------------+
//| Проверяет значения точек привязки "Расширения Фибоначчи" и для   |
//| пустых значений устанавливает значения по умолчанию              |
//+------------------------------------------------------------------+
void ChangeFiboExpansionEmptyPoints(datetime &time1,double &price1,datetime &time2,
                                    double &price2,datetime &time3,double &price3)
  {
//--- если время третьей (правой) точки не задано, то она будет на текущем баре
   if(!time3)
      time3=TimeCurrent();
//--- если цена третьей точки не задана, то она будет иметь значение Bid
   if(!price3)
      price3=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- если время первой (левой) точки не задано, то она лежит на 9 баров левее третьей
//--- массив для приема времени открытия 10 последних баров
   datetime temp[];
   ArrayResize(temp,10);
   if(!time1)
     {
      CopyTime(Symbol(),Period(),time3,10,temp);
      //--- установим первую точку на 9 баров левее второй
      time1=temp[0];
     }
//--- если цена первой точки не задана, то она совпадает с ценой третьей точки
   if(!price1)
      price1=price3;
//--- если время второй точки не задано, то она лежит на 7 баров левее третьей
   if(!time2)
      time2=temp[2];
//--- если цена второй точки не задана, сдвинем ее на 250 пунктов ниже первой
   if(!price2)
      price2=price1-250*SymbolInfoDouble(Symbol(),SYMBOL_POINT);
  }
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- проверим входные параметры на корректность
   if(InpDate1<0 || InpDate1>100 || InpPrice1<0 || InpPrice1>100 || 
      InpDate2<0 || InpDate2>100 || InpPrice2<0 || InpPrice2>100 || 
      InpDate3<0 || InpDate3>100 || InpPrice3<0 || InpPrice3>100)
     {
      Print("Ошибка! Некорректные значения входных параметров!");
      return;
     }
//--- количество видимых баров в окне графика
   int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- размер массива price
   int accuracy=1000;
//--- массивы для хранения значений дат и цен, которые будут использованы
//--- для установки и изменения координат точек привязки объекта
   datetime date[];
   double   price[];
//--- выделение памяти
   ArrayResize(date,bars);
   ArrayResize(price,accuracy);
//--- заполним массив дат
   ResetLastError();
   if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
     {
      Print("Не удалось скопировать значения времени! Код ошибки = ",GetLastError());
      return;
     }
//--- заполним массив цен
//--- найдем максимальное и минимальное значение графика
   double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
   double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- определим шаг изменения цены и заполним массив
   double step=(max_price-min_price)/accuracy;
   for(int i=0;i<accuracy;i++)
      price[i]=min_price+i*step;
//--- определим точки для рисования "Расширения Фибоначчи"
   int d1=InpDate1*(bars-1)/100;
   int d2=InpDate2*(bars-1)/100;
   int d3=InpDate3*(bars-1)/100;
   int p1=InpPrice1*(accuracy-1)/100;
   int p2=InpPrice2*(accuracy-1)/100;
   int p3=InpPrice3*(accuracy-1)/100;
//--- создадим "Расширение Фибоначчи"
   if(!FiboExpansionCreate(0,InpName,0,date[d1],price[p1],date[d2],price[p2],date[d3],price[p3],
      InpColor,InpStyle,InpWidth,InpBack,InpSelection,InpRayLeft,InpRayRight,InpHidden,InpZOrder))
     {
      return;
     }
//--- перерисуем график и подождем 1 секунду
   ChartRedraw();
   Sleep(1000);
//--- теперь будем перемещать точки привязки
//--- счетчик цикла
   int v_steps=accuracy/10;
//--- перемещаем первую точку привязки
   for(int i=0;i<v_steps;i++)
     {
      //--- возьмем следующее значение
      if(p1>1)
         p1-=1;
      //--- сдвигаем точку
      if(!FiboExpansionPointChange(0,InpName,0,date[d1],price[p1]))
         return;
      //--- проверим факт принудительного завершения скрипта
      if(IsStopped())
         return;
      //--- перерисуем график
      ChartRedraw();
     }
//--- задержка в 1 секунду
   Sleep(1000);
//--- счетчик цикла
   v_steps=accuracy/2;
//--- перемещаем третью точку привязки
   for(int i=0;i<v_steps;i++)
     {
      //--- возьмем следующее значение
      if(p3>1)
         p3-=1;
      //--- сдвигаем точку
      if(!FiboExpansionPointChange(0,InpName,2,date[d3],price[p3]))
         return;
      //--- проверим факт принудительного завершения скрипта
      if(IsStopped())
         return;
      //--- перерисуем график
      ChartRedraw();
     }
//--- задержка в 1 секунду
   Sleep(1000);
//--- счетчик цикла
   v_steps=accuracy*4/5;
//--- перемещаем вторую точку привязки
   for(int i=0;i<v_steps;i++)
     {
      //--- возьмем следующее значение
      if(p2<accuracy-1)
         p2+=1;
      //--- сдвигаем точку
      if(!FiboExpansionPointChange(0,InpName,1,date[d2],price[p2]))
         return;
      //--- проверим факт принудительного завершения скрипта
      if(IsStopped())
         return;
      //--- перерисуем график
      ChartRedraw();
     }
//--- задержка в 1 секунду
   Sleep(1000);
//--- удалим объект с графика
   FiboExpansionDelete(0,InpName);
   ChartRedraw();
//--- задержка в 1 секунду
   Sleep(1000);
//---
  }


Обновлено: 2015.12.03