DocumentaçãoSeções
Referência MQL5Funções de StringStringCompare 

StringCompare

A função compara duas strings e retorna o resultada da comparação na forma de um inteiro.

int  StringCompare(
   const string&  string1,                 // a primeira string na comparação
   const string&  string2,                 // a segunda string na comparação
   bool           case_sensitive=true      // seleção do modo sensibilidade à maiúscula/minúscula para a comparação
   );

Parâmetros

string1

[in]  A primeira string.

string2

[in]  A segunda string.

case_sensitive=true

[in]  Seleção do modo de sensibilidade à maiúscula/minúscula. Se for true, então "A">"a". Se for false, então "A"="a". Por default, o valor é igual a true.

Valor do Retorno

  • -1 (menos um), se string1<string2
  • 0 (zero), se string1=string2
  • 1 (um), se string1>string2

Observação

As strings são comparadas símbolo a símbolo, os símbolos são comparados na ordem alfabética em concordância como o código de página corrente.

Exemplo:

void OnStart()
  {
//--- qual é maior - apple ou home?
   string s1="Apple";
   string s2="home";
 
//--- compara com sensibilidade à maiúscula/minúscula 
   int result1=StringCompare(s1,s2);
   if(result1>0) PrintFormat("Comparação sensível caso: %s > %s",s1,s2);
   else
     {
      if(result1<0)PrintFormat("Comparação sensível caso: %s < %s",s1,s2);
      else PrintFormat("Comparação sensível caso: %s = %s",s1,s2);
     }
 
//--- Comparação insensível caso
   int result2=StringCompare(s1,s2,false);
   if(result2>0) PrintFormat("Comparação insensível caso: %s > %s",s1,s2);
   else
     {
      if(result2<0)PrintFormat("Comparação insensível caso: %s < %s",s1,s2);
      else PrintFormat("Comparação insensível caso: %s = %s",s1,s2);
     }
/* Resultado:
    Comparação sensível caso: Apple < home
    Comparação insensível caso: Apple < home
*/
  }

Também Veja

Tipo de String, CharToString(), ShortToString(), StringToCharArray(), StringToShortArray(), StringGetCharacter(), Uso de um Código de Página