ChartXYToTimePrice

bool  ChartXYToTimePrice(
   long           chart_id,     // 차트 ID
   int            x,            // 차트의 X좌표
   int            y,            // 차트의 Y좌표
   int&           sub_window,   // 하위 창의 번호
   datetime&      time,         // 차트의 시간
   double&        price         // 차트의 가격
   );

//+------------------------------------------------------------------+
//| ChartEvent 기능                                              |
//+------------------------------------------------------------------+
void OnChartEvent(const int id,
                  const long &lparam,
                  const double &dparam,
                  const string &sparam)
  {
//--- 차트에 이벤트 매개변수 표시
   Comment(__FUNCTION__,": id=",id," lparam=",lparam," dparam=",dparam," sparam=",sparam);
//--- 차트의 마우스 클릭 이벤트인 경우
   if(id==CHARTEVENT_CLICK)
     {
      //--- 변수를 준비
      int      x     =(int)lparam;
      int      y     =(int)dparam;
      datetime dt    =0;
      double   price =0;
      int      window=0;
      //--- 날짜/시간 단위로 X 및 Y 좌표 변환
      if(ChartXYToTimePrice(0,x,y,window,dt,price))
        {
         PrintFormat("Window=%d X=%d  Y=%d  =>  Time=%s  Price=%G",window,x,y,TimeToString(dt),price);
         //--- 역방향 변환 수행: (X,Y) => (Time,Price)
         if(ChartTimePriceToXY(0,window,dt,price,x,y))
            PrintFormat("Time=%s  Price=%G  =>  X=%d  Y=%d",TimeToString(dt),price,x,y);
         else
            Print("ChartTimePriceToXY return error code: ",GetLastError());
         //--- 열 삭제
         ObjectDelete(0,"V Line");
         ObjectDelete(0,"H Line");
         //--- 크로스헤어의 가로 및 세로열을 작성
         ObjectCreate(0,"H Line",OBJ_HLINE,window,dt,price);
         ObjectCreate(0,"V Line",OBJ_VLINE,window,dt,price);
         ChartRedraw(0);
        }
      else
         Print("ChartXYToTimePrice return error code: ",GetLastError());
      Print("+--------------------------------------------------------------+");
     }
  }