DocumentazioneSezioni
MQL5 RiferimentoFunzioni con i FileFileReadComplexDouble 

FileReadComplexDouble

Legge un numero di tipo complex da un file binario o CSV dalla posizione corrente del puntatore del file.

complex FileReadComplexDouble(
   int     file_handle     // Handle del file
   );

Parametri

file_handle

[in]  Descrittore di file restituito da FileOpen().

Valore restituito

Valore del tipo complex.

Nota

Per ottenere informazioni sull'errore, chiamare GetLastError().

Legge 16 byte da un file binario.

Da un file CSV legge una stringa dalla posizione corrente fino al separatore (oppure fino alla fine della riga di testo) e converte la stringa letta in un valore del tipo complex.

Chiamata equivalente della funzione FileRead con un parametro di tipo complex:

complex complex_value;
FileRead(file_handle,complex_value);

 

Esempio:

//+------------------------------------------------------------------+
//|                                         TestWriteReadComplex.mq5 |
//|                                  Copyright 2026, MetaQuotes Ltd. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2026, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
//+------------------------------------------------------------------+
//| Funzione di avvio del programma Script                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
   complex  complex_value=1.012345+0.0001i;
   complexf complexf_value=complexf(0.00678+0.005i);
//--- scrittura in un file CSV
   int  file_handle=FileOpen("complex.csv",FILE_CSV|FILE_WRITE|FILE_ANSI);
   uint written=FileWriteComplexDouble(file_handle,complex_value);
   Print("written ",written," bytes");
   FileWriteString(file_handle,"\t");
   written=FileWriteComplexFloat(file_handle,complexf_value);
   Print("written ",written," bytes");
   FileWriteString(file_handle,"\n");
   FileClose(file_handle);
   complex  complex_value2;
   complexf complexf_value2;
//--- lettura da un file CSV
   file_handle=FileOpen("complex.csv",FILE_CSV|FILE_READ|FILE_ANSI);
   complex_value2=FileReadComplexDouble(file_handle);
   complexf_value2=FileReadComplexFloat(file_handle);
   FileClose(file_handle);
   Print("complex_value2=",complex_value2);
   Print("complexf_value2=",complexf_value2);
//--- scrittura in un file binario
   file_handle=FileOpen("complex.bin",FILE_BIN|FILE_WRITE);
   written=FileWriteComplexDouble(file_handle,complex_value);
   Print("\nwritten ",written," bytes");
   written=FileWriteComplexFloat(file_handle,complexf_value);
   Print("written ",written," bytes");
   FileClose(file_handle);
   complex  complex_value3;
   complexf complexf_value3;
//--- lettura da un file binario
   file_handle=FileOpen("complex.bin",FILE_BIN|FILE_READ);
   complex_value3=FileReadComplexDouble(file_handle);
   complexf_value3=FileReadComplexFloat(file_handle);
   FileClose(file_handle);
   Print("complex_value3=",complex_value3);
   Print("complexf_value3=",complexf_value3);
  }

Output nel journal degli Expert

   written 17 bytes
   written 27 bytes
   complex_value2=(1.012345,0.0001)
   complexf_value2=(0.0067799999,0.0049999999)
   
   written 16 bytes
   written 8 bytes
   complex_value3=(1.012345,0.0001)
   complexf_value3=(0.0067799999,0.0049999999)

Vedi anche

Numero complesso (complex, complexf), FileRead, FileReadDouble, FileWriteComplexDouble