DocumentationSections
Référence MQL5Fonctions sur les FichiersFileReadComplexDouble 

FileReadComplexDouble

Lit un nombre de type complex depuis un fichier binaire ou CSV à partir de la position courante du pointeur de fichier.

complex FileReadComplexDouble(
   int     file_handle     // Handle du fichier
   );

Paramètres

file_handle

[in]  Descripteur de fichier renvoyé par la fonction FileOpen().

La valeur rendue

Valeur du type complex.

Note

Pour obtenir des informations sur l'erreur, appelez GetLastError().

Lit 16 octets depuis un fichier binaire.

Lit dans un fichier CSV une chaîne depuis la position courante jusqu'au séparateur (ou jusqu'à la fin de la ligne de texte) et convertit la chaîne lue en une valeur du type complex.

Appel équivalent de la fonction FileRead avec un paramètre de type complex :

complex complex_value;
FileRead(file_handle,complex_value);

 

Exemple:

//+------------------------------------------------------------------+
//|                                         TestWriteReadComplex.mq5 |
//|                                  Copyright 2026, MetaQuotes Ltd. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2026, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
//+------------------------------------------------------------------+
//| Fonction de démarrage du programme de script                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
   complex  complex_value=1.012345+0.0001i;
   complexf complexf_value=complexf(0.00678+0.005i);
//--- écriture dans un fichier CSV
   int  file_handle=FileOpen("complex.csv",FILE_CSV|FILE_WRITE|FILE_ANSI);
   uint written=FileWriteComplexDouble(file_handle,complex_value);
   Print("written ",written," bytes");
   FileWriteString(file_handle,"\t");
   written=FileWriteComplexFloat(file_handle,complexf_value);
   Print("written ",written," bytes");
   FileWriteString(file_handle,"\n");
   FileClose(file_handle);
   complex  complex_value2;
   complexf complexf_value2;
//--- lecture depuis un fichier CSV
   file_handle=FileOpen("complex.csv",FILE_CSV|FILE_READ|FILE_ANSI);
   complex_value2=FileReadComplexDouble(file_handle);
   complexf_value2=FileReadComplexFloat(file_handle);
   FileClose(file_handle);
   Print("complex_value2=",complex_value2);
   Print("complexf_value2=",complexf_value2);
//--- écriture dans un fichier binaire
   file_handle=FileOpen("complex.bin",FILE_BIN|FILE_WRITE);
   written=FileWriteComplexDouble(file_handle,complex_value);
   Print("\nwritten ",written," bytes");
   written=FileWriteComplexFloat(file_handle,complexf_value);
   Print("written ",written," bytes");
   FileClose(file_handle);
   complex  complex_value3;
   complexf complexf_value3;
//--- lecture depuis un fichier binaire
   file_handle=FileOpen("complex.bin",FILE_BIN|FILE_READ);
   complex_value3=FileReadComplexDouble(file_handle);
   complexf_value3=FileReadComplexFloat(file_handle);
   FileClose(file_handle);
   Print("complex_value3=",complex_value3);
   Print("complexf_value3=",complexf_value3);
  }

Sortie dans le journal des Experts

   written 17 bytes
   written 27 bytes
   complex_value2=(1.012345,0.0001)
   complexf_value2=(0.0067799999,0.0049999999)
   
   written 16 bytes
   written 8 bytes
   complex_value3=(1.012345,0.0001)
   complexf_value3=(0.0067799999,0.0049999999)

Voir aussi

Nombre complexe (complex, complexf), FileRead, FileReadDouble, FileWriteComplexDouble