//--- description
#property description "Le script dessine l'objet graphique \"Eventail de Gann\"."
#property description "Les coordonnées du point d'ancrage sont définies en pourcentage de"
#property description "la taille de la fenêtre du graphique."
//--- affichage de la fenêtre des paramètres d'entrée lors du lancement du script
#property script_show_inputs
//--- paramètres d'entrée du script
input string InpName="GannFan"; // Nom de l'éventail
input int InpDate1=15; // Date du premier point, %
input int InpPrice1=25; // Prix du premier point, %
input int InpDate2=85; // Date du second point, %
input double InpScale=2.0; // Echelle
input bool InpDirection=false; // Direction de la tendance
input color InpColor=clrRed; // Couleur de l'éventail
input ENUM_LINE_STYLE InpStyle=STYLE_DASHDOTDOT; // Style des lignes de l'éventail
input int InpWidth=1; // Largeur des lignes de l'éventail
input bool InpBack=false; // Eventail en arrière plan
input bool InpSelection=true; // Mise en surbrillance pour déplacer
input bool InpHidden=true; // Caché dans la liste des objets
input long InpZOrder=0; // Priorité du clic de souris
//+----------------------------------------------------------------------------------------------------+
//| Crée l'Eventail de Gann |
//+----------------------------------------------------------------------------------------------------+
bool GannFanCreate(const long chart_ID=0, // identifiant du graphique
const string name="GannFan", // nom de l'éventail
const int sub_window=0, // indice de sous-fenêtre
datetime time1=0, // heure du premier point
double price1=0, // prix du premier point
datetime time2=0, // heure du deuxième point
const double scale=1.0, // Echelle
const bool direction=true, // direction de la tendance
const color clr=clrRed, // couleur de l'éventail
const ENUM_LINE_STYLE style=STYLE_SOLID, // style des lignes de l'éventail
const int width=1, // largeur des lignes de l'éventail
const bool back=false, // en arrière plan
const bool selection=true, // mise en surbrillance pour le déplacement
const bool hidden=true, // caché dans la liste des objets
const long z_order=0) // priorité pour le clic de souris
{
//--- définit les coordonnées du point d'ancrage si elles ne sont pas définies
ChangeGannFanEmptyPoints(time1,price1,time2);
//--- réinitialise la valeur d'erreur
ResetLastError();
//--- crée l'Eventail de Gann aux coordonnées données
if(!ObjectCreate(chart_ID,name,OBJ_GANNFAN,sub_window,time1,price1,time2,0))
{
Print(__FUNCTION__,
" : échec de création de l'\"Eventail de Gann\" ! Code d'erreur = ",GetLastError());
return(false);
}
//--- change l'échelle (nombre de pips par barre)
ObjectSetDouble(chart_ID,name,OBJPROP_SCALE,scale);
//--- change la direction de la tendance de l'Eventail de Gann (true - baissière, false - haussière)
ObjectSetInteger(chart_ID,name,OBJPROP_DIRECTION,direction);
//--- définit la couleur de l'éventail
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- définit le style d'affichage des lignes de l'éventail
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- définit la largeur des lignes de l'éventail
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- affiche en premier plan (false) ou en arrière-plan (true)
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- active (true) ou désactive (false) le mode de mise en surbrillance de l'éventail pour le déplacement
//--- lors de la création d'un objet graphique utilisant la fonction ObjectCreate, l'objet ne peut pas être
//--- mis en surbrillance et déplacé par défaut. Dans cette méthode, le paramètre de sélection
//--- est vrai par défaut, permettant de mettre en surbrillance et de déplacer l'objet
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- masque (true) ou affiche (false) le nom de l'objet graphique dans la liste des objets
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- définit la priorité pour recevoir l'événement d'un clic de souris dans le graphique
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- exécution réussie
return(true);
}
//+----------------------------------------------------------------------------------------------------+
//| Déplace le point d'ancrage de l'Eventail de Gann |
//+----------------------------------------------------------------------------------------------------+
bool GannFanPointChange(const long chart_ID=0, // identifiant du graphique
const string name="GannFan", // nom de l'éventail
const int point_index=0, // indice du point d'ancrage
datetime time=0, // coordonnées du point d'ancrage temporel
double price=0) // coordonnées du point d'ancrage prix
{
//--- si la position du point n'est pas définie, le déplace vers la barre courante du prix Bid
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- réinitialise la valeur d'erreur
ResetLastError();
//--- déplace le point d'ancrage de l'éventail
if(!ObjectMove(chart_ID,name,point_index,time,price))
{
Print(__FUNCTION__,
" : impossible de déplacer le point d'ancrage ! Code d'erreur = ",GetLastError());
return(false);
}
//--- exécution réussie
return(true);
}
//+----------------------------------------------------------------------------------------------------+
//| Change l'échelle de l'Eventail de Gann |
//+----------------------------------------------------------------------------------------------------+
bool GannFanScaleChange(const long chart_ID=0, // identifiant du graphique
const string name="GannFan", // nom de l'éventail
const double scale=1.0) // Echelle
{
//--- réinitialise la valeur d'erreur
ResetLastError();
//--- change l'échelle (nombre de pips par barre)
if(!ObjectSetDouble(chart_ID,name,OBJPROP_SCALE,scale))
{
Print(__FUNCTION__,
" : échec de changement de l'échelle ! Code d'erreur = ",GetLastError());
return(false);
}
//--- exécution réussie
return(true);
}
//+----------------------------------------------------------------------------------------------------+
//| Change la direction de la tendance de l'Eventail de Gann |
//+----------------------------------------------------------------------------------------------------+
bool GannFanDirectionChange(const long chart_ID=0, // identifiant du graphique
const string name="GannFan", // nom de l'éventail
const bool direction=true) // direction de la tendance
{
//--- réinitialise la valeur d'erreur
ResetLastError();
//--- change la direction de la tendance de l'Eventail de Gann
if(!ObjectSetInteger(chart_ID,name,OBJPROP_DIRECTION,direction))
{
Print(__FUNCTION__,
" : échec de changement de l'échelle ! Code d'erreur = ",GetLastError());
return(false);
}
//--- exécution réussie
return(true);
}
//+----------------------------------------------------------------------------------------------------+
//| La fonction supprime l'Eventail de Gann du graphique |
//+----------------------------------------------------------------------------------------------------+
bool GannFanDelete(const long chart_ID=0, // identifiant du graphique
const string name="GannFan") // nom de l'éventail
{
//--- réinitialise la valeur d'erreur
ResetLastError();
//--- supprime l'Eventail de Gann
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
" : échec de suppression de l'\"Eventail de Gann\" ! Code d'erreur = ",GetLastError());
return(false);
}
//--- exécution réussie
return(true);
}
//+----------------------------------------------------------------------------------------------------+
//| Vérifie les valeurs des points d'ancrage de l'Eventail de Gann et définit la valeur |
//| par défaut des points vides |
//+----------------------------------------------------------------------------------------------------+
void ChangeGannFanEmptyPoints(datetime &time1,double &price1,datetime &time2)
{
//--- si l'heure du deuxième point n'est pas définie, il sera mis sur la barre courante
if(!time2)
time2=TimeCurrent();
//--- si l'heure du premier point n'est pas réglée, il est mis 9 barres à gauche du deuxième point
if(!time1)
{
//--- tableau pour recevoir l'heure d'ouverture des 10 dernières barres
datetime temp[10];
CopyTime(Symbol(),Period(),time2,10,temp);
//--- définit le premier point 9 barres à gauche du deuxième
time1=temp[0];
}
//--- si le prix du premier point n'est pas défini, il aura la valeur Bid
if(!price1)
price1=SymbolInfoDouble(Symbol(),SYMBOL_BID);
}
//+----------------------------------------------------------------------------------------------------+
//| Fonction de démarrage du script |
//+----------------------------------------------------------------------------------------------------+
void OnStart()
{
//--- vérifie l'exactitude des paramètres d'entrée
if(InpDate1<0 || InpDate1>100 || InpPrice1<0 || InpPrice1>100 ||
InpDate2<0 || InpDate2>100)
{
Print("Erreur ! Valeurs incorrectes des paramètres d'entrée !");
return;
}
//--- nombre de barres visibles dans la fenêtre du graphique
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- taille du tableau des prix
int accuracy=1000;
//--- tableaux pour stocker les valeurs de date et de prix à utiliser
//--- pour le réglage et la modification des coordonnées des points d'ancrage de l'éventail
datetime date[];
double price[];
//--- allocation mémoire
ArrayResize(date,bars);
ArrayResize(price,accuracy);
//--- remplit le tableau de dates
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("N'a pas réussi à copier les valeurs de l'heure ! Code d'erreur = ",GetLastError());
return;
}
//--- remplit le tableau des prix
//--- trouve les valeurs les plus élevées et les plus faibles du graphique
double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- définit un changement de prix et remplit le tableau
double step=(max_price-min_price)/accuracy;
for(int i=0;i<accuracy;i++)
price[i]=min_price+i*step;
//--- définit les points pour dessiner l'Eventail de Gann
int d1=InpDate1*(bars-1)/100;
int d2=InpDate2*(bars-1)/100;
int p1=InpPrice1*(accuracy-1)/100;
//--- crée l'Eventail de Gann
if(!GannFanCreate(0,InpName,0,date[d1],price[p1],date[d2],InpScale,InpDirection,
InpColor,InpStyle,InpWidth,InpBack,InpSelection,InpHidden,InpZOrder))
{
return;
}
//--- redéssine le graphique et attend 1 seconde
ChartRedraw();
Sleep(1000);
//--- déplace maintenant les points d'ancrage de l'éventail
//--- compteur de boucle
int v_steps=accuracy/2;
//--- déplace le premier point d'ancrage verticalement
for(int i=0;i<v_steps;i++)
{
//--- utilise la valeur suivante
if(p1<accuracy-1)
p1+=1;
//--- déplace le point
if(!GannFanPointChange(0,InpName,0,date[d1],price[p1]))
return;
//--- vérifie si l'exécution du script a été stoppée
if(IsStopped())
return;
//--- redessine le graphique
ChartRedraw();
}
//--- délai de 1 seconde
Sleep(1000);
//--- change la direction de la tendance de l'éventail en tendance baissière
GannFanDirectionChange(0,InpName,true);
//--- redessine le graphique
ChartRedraw();
//--- délai de 1 seconde
Sleep(1000);
//--- supprime l'éventail du graphique
GannFanDelete(0,InpName);
ChartRedraw();
//--- délai de 1 seconde
Sleep(1000);
//---
}
|
