//--- descrizione
#property description "Lo script crea l'oggetto grafico \"Testo\"."
//--- mostra la finestra dei parametri di input durante il lancio dello script
#property script_show_inputs
//--- parametri di input dello script
input string InpFont="Arial"; // Font
input int InpFontSize=10; // Grandezza del font
input color InpColor=clrRed; // Colore
input double InpAngle=90.0; // Angolo di pendenza in gradi
input ENUM_ANCHOR_POINT InpAnchor=ANCHOR_LEFT; // Tipo di ancora
input bool InpBack=false; // Oggetto di sottofondo
input bool InpSelection=false; // Evidenzia di movimento
input bool InpHidden=true; // Nascosta nella lista oggetti
input long InpZOrder=0; // Priorità per il click del mouse
//+--------------------------------------------------------------------------------+
//| Crea l'oggetto Testo |
//+--------------------------------------------------------------------------------+
bool TextCreate(const long chart_ID=0, // ID del chart
const string name="Text", // nome dell'oggetto
const int sub_window=0, // indice sottofinestra
datetime time=0, // orario punto di ancoraggio
double price=0, // prezzo punto di ancoraggio
const string text="Text", // il testo stesso
const string font="Arial", // font
const int font_size=10, // grandezza del font
const color clr=clrRed, // colore
const double angle=0.0, // inclinazione del testo
const ENUM_ANCHOR_POINT anchor=ANCHOR_LEFT_UPPER, // tipo di ancora
const bool back=false, // in sottofondo
const bool selection=false, // evidenzia movimento
const bool hidden=true, // nascosto nella lista oggetti
const long z_order=0) // priorità per il click del mouse
{
//--- imposta coordinate punto di ancoraggio se non sono impostate
ChangeTextEmptyPoint(time,price);
//--- resetta il valore dell' errore
ResetLastError();
//--- crea l'oggetto Testo
if(!ObjectCreate(chart_ID,name,OBJ_TEXT,sub_window,time,price))
{
Print(__FUNCTION__,
": fallimento nel creare l'oggetto \"Testo\"! Error code = ",GetLastError());
return(false);
}
//--- imposta il testo
ObjectSetString(chart_ID,name,OBJPROP_TEXT,text);
//--- imposta il font
ObjectSetString(chart_ID,name,OBJPROP_FONT,font);
//--- imposta grandezza font
ObjectSetInteger(chart_ID,name,OBJPROP_FONTSIZE,font_size);
//--- imposta l'angolo di inclinazione del testo
ObjectSetDouble(chart_ID,name,OBJPROP_ANGLE,angle);
//--- imposta il tipo di ancora
ObjectSetInteger(chart_ID,name,OBJPROP_ANCHOR,anchor);
//--- imposta il colore
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- mostra in primo piano (false) o sottofondo (true)
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- abilita (true) o disabilita (false) la modalità di spostamento dell'oggetto con il mouse
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- nascondi (true) o mostra (falso) il nome di oggetto grafico nella lista degli oggetti
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- imposta la priorità per ricevere l'evento di un clic del mouse nel grafico
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- esecuzione avvenuta
return(true);
}
//+--------------------------------------------------------------------------------+
//| Sposta il punto di ancoraggio |
//+--------------------------------------------------------------------------------+
bool TextMove(const long chart_ID=0, // ID del chart
const string name="Text", // nome dell'oggetto
datetime time=0, // coordinate tempo, del punto di ancoraggio
double price=0) // coordinate prezzo del punto di ancoraggio
{
//--- se il punto della posizione non è impostato, spostarlo nella barra corrente che ha il prezzo Bid
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- resetta il valore dell' errore
ResetLastError();
//--- sposta il punto di ancoraggio
if(!ObjectMove(chart_ID,name,0,time,price))
{
Print(__FUNCTION__,
": fallimento nello spostare il punto di ancoraggio! Error code = ",GetLastError());
return(false);
}
//--- esecuzione avvenuta
return(true);
}
//+--------------------------------------------------------------------------------+
//| Cambia il testo dell'oggetto |
//+--------------------------------------------------------------------------------+
bool TextChange(const long chart_ID=0, // ID del chart
const string name="Text", // nome dell'oggetto
const string text="Text") // testo
{
//--- resetta il valore dell' errore
ResetLastError();
//--- cambia il testo dell'oggetto
if(!ObjectSetString(chart_ID,name,OBJPROP_TEXT,text))
{
Print(__FUNCTION__,
": fallimento nel cambiare il testo! Error code = ",GetLastError());
return(false);
}
//--- esecuzione avvenuta
return(true);
}
//+--------------------------------------------------------------------------------+
//| Elimina l'oggetto Testo |
//+--------------------------------------------------------------------------------+
bool TextDelete(const long chart_ID=0, // ID del chart
const string name="Text") // nome dell'oggetto
{
//--- resetta il valore dell' errore
ResetLastError();
//--- elimina l'oggetto
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": fallimento nell'eliminare l'oggetto \"Testo\"! Error code = ",GetLastError());
return(false);
}
//--- esecuzione avvenuta
return(true);
}
//+--------------------------------------------------------------------------------+
//| Controlla i valori di punto di ancoraggio ed imposta i valori di default |
//| per quelli vuoti |
//+--------------------------------------------------------------------------------+
void ChangeTextEmptyPoint(datetime &time,double &price)
{
//--- se il tempo del punto non è impostato, sarà sulla barra corrente
if(!time)
time=TimeCurrent();
//--- se il prezzo del punto non è impostato, avrà un valore Bid
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
}
//+--------------------------------------------------------------------------------+
//| Funzione di avvio del programma Script |
//+--------------------------------------------------------------------------------+
voidOnStart()
{
datetime date[]; // array per memorizzare le date di barre visibili
double low[]; // array per memorizzare i prezzi Low delle barre visibili
double high[]; // array memorizzare i prezzi High di barre visibili
//--- Numero di barre visibili nella finestra del chart
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- allocazione della memoria
ArrayResize(date,bars);
ArrayResize(low,bars);
ArrayResize(high,bars);
//--- riempie l'array delle date
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("Fallimento nella copia dei valori tempo! Error code = ",GetLastError());
return;
}
//--- riempie l'array dei prezzi Low
if(CopyLow(Symbol(),Period(),0,bars,low)==-1)
{
Print("Fallimento nel copiare i valori dei prezzi Low! Error code = ",GetLastError());
return;
}
//--- riempie l'array di prezzi High
if(CopyHigh(Symbol(),Period(),0,bars,high)==-1)
{
Print("Fallimento nel copiare i valori dei prezzi High! Error code = ",GetLastError());
return;
}
//--- definisce quanto spesso il testo viene visualizzato
int scale=(int)ChartGetInteger(0,CHART_SCALE);
//--- definisce lo step
int step=1;
switch(scale)
{
case 0:
step=12;
break;
case 1:
step=6;
break;
case 2:
step=4;
break;
case 3:
step=2;
break;
}
//--- crea il testo per i valori High e Low delle barre (con i gaps)
for(int i=0;i<bars;i+=step)
{
//--- crea il testo
if(!TextCreate(0,"TextHigh_"+(string)i,0,date[i],high[i],DoubleToString(high[i],5),InpFont,InpFontSize,
InpColor,InpAngle,InpAnchor,InpBack,InpSelection,InpHidden,InpZOrder))
{
return;
}
if(!TextCreate(0,"TextLow_"+(string)i,0,date[i],low[i],DoubleToString(low[i],5),InpFont,InpFontSize,
InpColor,-InpAngle,InpAnchor,InpBack,InpSelection,InpHidden,InpZOrder))
{
return;
}
//--- controlla se l'operazione dello script è stata disabilitata per forza
if(IsStopped())
return;
//--- ridisegna il chart
ChartRedraw();
// 0.05 secondi di ritardo
Sleep(50);
}
//--- ritardo di mezzo secondo
Sleep(500);
//--- elimina il testo
for(int i=0;i<bars;i+=step)
{
if(!TextDelete(0,"TextHigh_"+(string)i))
return;
if(!TextDelete(0,"TextLow_"+(string)i))
return;
//--- ridisegna il chart
ChartRedraw();
// 0.05 secondi di ritardo
Sleep(50);
}
//---
}
|