Скачать MetaTrader 5

ArrayPrint

Выводит в журнал массив простого типа или простой структуры.

void  ArrayPrint(
   const void&   array[],             // выводимый массив
   uint          digits=_Digits,      // количество десятичных знаков после запятой
   const string  separator=NULL,      // разделитель между значениями полей структуры
   ulong         start=0,             // индекс первого выводимого элемента
   ulong         count=WHOLE_ARRAY,   // количество выводимых элементов
   ulong         flags=ARRAYPRINT_HEADER|ARRAYPRINT_INDEX|ARRAYPRINT_LIMIT|ARRAYPRINT_ALIGN    
   );

Параметры

array[]

[in]  Массив простого типа или простой структуры.

digits=_Digits

[in]  Количество знаков после запятой для вещественных типов. По умолчанию равно _Digits.

separator=NULL

[in]  Разделитель между значениями полей элемента структуры. Значение по умолчанию NULL означает пустую строку, в этом случае разделителем является пробел.

start=0

[in]  Индекс первого выводимого элемента массива.  По умолчанию выводится с нулевого индекса.

count=WHOLE_ARRAY

[in]  Количество элементов массива, которые нужно вывести. По умолчанию выводится весь массив (count=WHOLE_ARRAY).

flags=ARRAYPRINT_HEADER|ARRAYPRINT_INDEX|ARRAYPRINT_LIMIT|ARRAYPRINT_ALIGN

[in]  Комбинация флагов, задающая режим вывода. По умолчанию включены все флаги:

    • ARRAYPRINT_HEADER – вывод заголовков для массива структур
    • ARRAYPRINT_INDEX – вывод слева номера индекса
    • ARRAYPRINT_LIMIT – вывод только 100 первых и 100 последних элементов массива. Используется, если нужно вывести только часть большого массива.
    • ARRAYPRINT_ALIGN – включить выравнивание выводимых значений – числа будут выравниваться вправо, строки влево.
    • ARRAYPRINT_DATE – при выводе datetime выводить дату в формате dd.mm.yyyy
    • ARRAYPRINT_MINUTES – при выводе datetime выводить время в формате HH:MM
    • ARRAYPRINT_SECONDS – при выводе datetime выводить время в формате HH:MM:SS

Возвращаемое значение

Нет

Примечание

ArrayPrint() выводит в журнал не все поля массива структур – поля-массивы и поля-указатели объектов пропускаются. Эти столбцы просто не будут выведены на печать для поддержания простого и удобного представления. Если вам нужен вывод всех полей такой структуры, то вам необходимо написать собственную функцию массового вывода с желаемым форматированием.

Пример:

//--- выводит значения 10 последних баров
   MqlRates rates[];
   if(CopyRates(_Symbol,_Period,1,10,rates))
     {
      ArrayPrint(rates);
      Print("Проверка\n[time]\t[open]\t[high]\t[low]\t[close]\t[tick_volume]\t[spread]\t[real_volume]");
      for(int i=0;i<10;i++)
        {
         PrintFormat("[%d]\t%s\t%G\t%G\t%G\t%G\t%G\t%G\t%I64d\t",i,
         TimeToString(rates[i].time,TIME_DATE|TIME_MINUTES|TIME_SECONDS),
         rates[i].open,rates[i].high,rates[i].low,rates[i].close,
         rates[i].tick_volume,rates[i].spread,rates[i].real_volume);
        }
     }
   else
      PrintFormat("CopyRates failed, error code=%d",GetLastError());
//--- пример вывода
/*
                    [time]  [open]  [high]   [low] [close] [tick_volume] [spread] [real_volume]
   [0] 2016.11.09 04:00:00 1.11242 1.12314 1.11187 1.12295         18110       10   17300175000
   [1] 2016.11.09 05:00:00 1.12296 1.12825 1.11930 1.12747         17829        9   15632176000
   [2] 2016.11.09 06:00:00 1.12747 1.12991 1.12586 1.12744         13458       10    9593492000
   [3] 2016.11.09 07:00:00 1.12743 1.12763 1.11988 1.12194         15362        9   12352245000
   [4] 2016.11.09 08:00:00 1.12194 1.12262 1.11058 1.11172         16833        9   12961333000
   [5] 2016.11.09 09:00:00 1.11173 1.11348 1.10803 1.11052         15933        8   10720384000
   [6] 2016.11.09 10:00:00 1.11052 1.11065 1.10289 1.10528         11888        9    8084811000
   [7] 2016.11.09 11:00:00 1.10512 1.11041 1.10472 1.10915          7284       10    5087113000
   [8] 2016.11.09 12:00:00 1.10915 1.11079 1.10892 1.10904          8710        9    6769629000
   [9] 2016.11.09 13:00:00 1.10904 1.10913 1.10223 1.10263          8956        7    7192138000
   Проверка
   [time] [open] [high] [low] [close] [tick_volume] [spread] [real_volume]
   [0] 2016.11.09 04:00:00 1.11242 1.12314 1.11187 1.12295 18110 10 17300175000 
   [1] 2016.11.09 05:00:00 1.12296 1.12825 1.1193 1.12747 17829 9 15632176000 
   [2] 2016.11.09 06:00:00 1.12747 1.12991 1.12586 1.12744 13458 10 9593492000 
   [3] 2016.11.09 07:00:00 1.12743 1.12763 1.11988 1.12194 15362 9 12352245000 
   [4] 2016.11.09 08:00:00 1.12194 1.12262 1.11058 1.11172 16833 9 12961333000 
   [5] 2016.11.09 09:00:00 1.11173 1.11348 1.10803 1.11052 15933 8 10720384000 
   [6] 2016.11.09 10:00:00 1.11052 1.11065 1.10289 1.10528 11888 9 8084811000 
   [7] 2016.11.09 11:00:00 1.10512 1.11041 1.10472 1.10915 7284 10 5087113000 
   [8] 2016.11.09 12:00:00 1.10915 1.11079 1.10892 1.10904 8710 9 6769629000 
   [9] 2016.11.09 13:00:00 1.10904 1.10913 1.10223 1.10263 8956 7 7192138000 
*/

Смотри также

FileSave, FileLoad


Обновлено: 2016.12.12