문서화섹션
MQL5 リファレンス配列関数ArrayPrint 

ArrayPrint

단순 유형 또는 단순 구조의 배열을 저널로 인쇄.

void  ArrayPrint(
   const void&   array[],             // 인쇄된 배열
   uint          digits=_Digits,      // 소수 자릿수
   const string  separator=NULL,      // 구조 필드 값의 분리자
   ulong         start=0,             // 첫 번째 인쇄 요소 인덱스
   ulong         count=WHOLE_ARRAY,   // 인쇄된 요소의 수
   ulong         flags=ARRAYPRINT_HEADER|ARRAYPRINT_INDEX|ARRAYPRINT_LIMIT|ARRAYPRINT_ALIGN    
   );

매개변수

array[]

[in]  단순 유형 또는 단순 구조의 배열.

digits=_Digits

[in]  실수 유형의 소수 자릿수. 기본값은 _Digits입니다.

separator=NULL

[in]  구조 요소 필드 값의 분리자. 기본값 NULL은 빈 줄을 의미합니다. 이 경우 공백이 분리자로 사용됩니다.

start=0

[in]  첫 번째 인쇄된 배열 요소의 인덱스. 기본적으로 영점 인덱스에서 인쇄됩니다.

count=WHOLE_ARRAY

[in]  인쇄할 배열의 요소 수. 기본적으로 전체 배열이 표시됩니다 (count=WHOLE_ARRAY).

flags=ARRAYPRINT_HEADER|ARRAYPRINT_INDEX|ARRAYPRINT_LIMIT|ARRAYPRINT_ALIGN

[in]  플래그 조합이 출력 모드를 설정 기본적으로 모든 플래그가 활성화됩니다:

    • ARRAYPRINT_HEADER – 구조 배열에 대한 헤더 인쇄
    • ARRAYPRINT_INDEX – 인덱스를 좌측에 인쇄
    • ARRAYPRINT_LIMIT – 첫 100개 및 마지막 100개 배열 요소만 인쇄. 큰 배열의 일부만 인쇄하려는 경우에 사용.
    • ARRAYPRINT_ALIGN – 인쇄된 값의 정렬을 활성화하며, 숫자는 우측에 정렬되고 선은 좌측에 정렬됩니다.
    • ARRAYPRINT_DATE – 일시를 인쇄할 때 dd.mm.yyyy 서식에서 날짜를 인쇄합니다
    • ARRAYPRINT_MINUTES – 일시를 인쇄할 때 HH:MM 서식에서 시간을 인쇄합니다
    • ARRAYPRINT_SECONDS – 일시를 인쇄할 때 HH:MM:SS 서식에서 시간을 인쇄합니다

반환 값

아니오

참고

ArrayPrint()는 일부 구조 배열 필드를 저널로 인쇄하지 않으며, 배열 및 개체 포인터 필드는 건너뜁니다. 이 열들은 더 편리한 프리젠테이션을 위해 인쇄되는 것이 아닙니다. 모든 구조 필드를 인쇄해야 하는 경우 원하는 형식의 대략 인쇄 기능을 직접 작성해야 합니다.

예:

//--- 마지막 막대 10개 값을 인쇄
   MqlRates rates[];
   if(CopyRates(_Symbol,_Period,1,10,rates))
     {
      ArrayPrint(rates);
      Print("Check\n[time]\t[open]\t[high]\t[low]\t[close]\t[tick_volume]\t[spread]\t[real_volume]");
      for(int i=0;i<10;i++)
        {
         PrintFormat("[%d]\t%s\t%G\t%G\t%G\t%G\t%G\t%G\t%I64d\t",i,
         TimeToString(rates[i].time,TIME_DATE|TIME_MINUTES|TIME_SECONDS),
         rates[i].open,rates[i].high,rates[i].low,rates[i].close,
         rates[i].tick_volume,rates[i].spread,rates[i].real_volume);
        }
     }
   else
      PrintFormat("CopyRates failed, error code=%d",GetLastError());
//--- 인쇄의 예
/*
                    [time]  [open]  [high]   [low] [close] [tick_volume] [spread] [real_volume]
   [0] 2016.11.09 04:00:00 1.11242 1.12314 1.11187 1.12295         18110       10   17300175000
   [1] 2016.11.09 05:00:00 1.12296 1.12825 1.11930 1.12747         17829        9   15632176000
   [2] 2016.11.09 06:00:00 1.12747 1.12991 1.12586 1.12744         13458       10    9593492000
   [3] 2016.11.09 07:00:00 1.12743 1.12763 1.11988 1.12194         15362        9   12352245000
   [4] 2016.11.09 08:00:00 1.12194 1.12262 1.11058 1.11172         16833        9   12961333000
   [5] 2016.11.09 09:00:00 1.11173 1.11348 1.10803 1.11052         15933        8   10720384000
   [6] 2016.11.09 10:00:00 1.11052 1.11065 1.10289 1.10528         11888        9    8084811000
   [7] 2016.11.09 11:00:00 1.10512 1.11041 1.10472 1.10915          7284       10    5087113000
   [8] 2016.11.09 12:00:00 1.10915 1.11079 1.10892 1.10904          8710        9    6769629000
   [9] 2016.11.09 13:00:00 1.10904 1.10913 1.10223 1.10263          8956        7    7192138000
  확인
   [time] [open] [high] [low] [close] [tick_volume] [spread] [real_volume]
   [0] 2016.11.09 04:00:00 1.11242 1.12314 1.11187 1.12295 18110 10 17300175000 
   [1] 2016.11.09 05:00:00 1.12296 1.12825 1.1193 1.12747 17829 9 15632176000 
   [2] 2016.11.09 06:00:00 1.12747 1.12991 1.12586 1.12744 13458 10 9593492000 
   [3] 2016.11.09 07:00:00 1.12743 1.12763 1.11988 1.12194 15362 9 12352245000 
   [4] 2016.11.09 08:00:00 1.12194 1.12262 1.11058 1.11172 16833 9 12961333000 
   [5] 2016.11.09 09:00:00 1.11173 1.11348 1.10803 1.11052 15933 8 10720384000 
   [6] 2016.11.09 10:00:00 1.11052 1.11065 1.10289 1.10528 11888 9 8084811000 
   [7] 2016.11.09 11:00:00 1.10512 1.11041 1.10472 1.10915 7284 10 5087113000 
   [8] 2016.11.09 12:00:00 1.10915 1.11079 1.10892 1.10904 8710 9 6769629000 
   [9] 2016.11.09 13:00:00 1.10904 1.10913 1.10223 1.10263 8956 7 7192138000 
*/

추가 참조

FileSave, FileLoad