//--- descrizione
#property description "Lo script disegna l'oggetto grafico \"Trend Line Angolata\"."
#property description "Le coordinate del punto di ancoraggio sono impostate in percentuale della grandezza della"
#property description "finestra del chart."
//--- mostra la finestra dei parametri di input durante il lancio dello script
#property script_show_inputs
//--- parametri di input dello script
input string InpName="Trend"; // Nome della linea
input int InpDate1=50; // data del 1mo punto, %
input int InpPrice1=75; // prezzo del 1mo punto, %
input int InpAngle=0; // Angolo di pendenza della linea
input color InpColor=clrRed; // Colore della Linea
input ENUM_LINE_STYLE InpStyle=STYLE_DASH; // Stile della linea
input int InpWidth=2; // Spessore linea
input bool InpBack=false; // Sottofondo linea
input bool InpSelection=true; // Evdenzia movimento
input bool InpRayLeft=false; // Continuazione della linea a sinistra
input bool InpRayRight=true; // Continuazione della linea a destra
input bool InpHidden=true; // Nascosto nella lista oggetti
input long InpZOrder=0; // Priorità per il click del mouse
//+--------------------------------------------------------------------------------+
//| Crea una trendline angolata |
//+--------------------------------------------------------------------------------+
bool TrendByAngleCreate(const long chart_ID=0, // ID del chart
const string name="TrendLine", // nome della linea
const int sub_window=0, // indice sottofinestra
datetime time=0, // orario del punto
double price=0, // prezzo del punto
const double angle=45.0, // angolo di pendenza
const color clr=clrRed, // colore della linea
const ENUM_LINE_STYLE style=STYLE_SOLID, // stile della linea
const int width=1, // spessore della linea
const bool back=false, // in sottofondo
const bool selection=true, // evidenzia movimento
const bool ray_left=false, // continuazione della linea a sinistra
const bool ray_right=false, // continuazione della linea a destra
const bool hidden=true, // nascosto nella lista oggetti
const long z_order=0) // priorità per il click del mouse
{
//-- crea il secondo punto per facilitare il trascinamento della trendline con il mouse
datetime time2=0;
double price2=0;
//--- imposta coordinate punto di ancoraggio se non sono impostate
ChangeTrendEmptyPoints(time,price,time2,price2);
//--- resetta il valore dell' errore
ResetLastError();
//--- crea una trendline usando 2 punti
if(!ObjectCreate(chart_ID,name,OBJ_TRENDBYANGLE,sub_window,time,price,time2,price2))
{
Print(__FUNCTION__,
": fallimento nel creare una trend line! Error code = ",GetLastError());
return(false);
}
//--- cambia l'angolo di pendenza della trendline; quando si cambia l'angolo, le coordinate del secondo
//--- punto delle linea vengono ridefinite automaticamente secondo i nuovi valori dell'angolo
ObjectSetDouble(chart_ID,name,OBJPROP_ANGLE,angle);
//--- imposta colore della linea
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- imposta lo stile della linea
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- larghezza della linea
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- mostra in primo piano (false) o sottofondo (true)
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- abilitare (true) o disabilitare (false) il modo di spostare la linea con freccia, con il mouse
//--- quando si crea un oggetto grafico utilizzando la funzione ObjectCreate, l'oggetto non può esser
//--- evidenziato e mosso, per default. All'interno di questo metodo, la selezione dei parametri
//--- è true per default, il che consente di evidenziare e spostare l'oggetto
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- abilita (true) o disabilita (false) la modalità di continuazione della visualizzazione della linea sulla sinistra
ObjectSetInteger(chart_ID,name,OBJPROP_RAY_LEFT,ray_left);
//--- abilita (true) o disabilita (false) la modalità di continuazione della visualizzazione della linea sulla destra
ObjectSetInteger(chart_ID,name,OBJPROP_RAY_RIGHT,ray_right);
//--- nascondi (true) o mostra (falso) il nome di oggetto grafico nella lista degli oggetti
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- imposta la priorità per ricevere l'evento di un clic del mouse nel grafico
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- esecuzione avvenuta
return(true);
}
//+--------------------------------------------------------------------------------+
//| Cambia i punti di ancoraggio delle coordinate delle trendline |
//+--------------------------------------------------------------------------------+
bool TrendPointChange(const long chart_ID=0, // ID del chart
const string name="TrendLine", // nome dellal linea
datetime time=0, // coordinate tempo, del punto di ancoraggio
double price=0) // coordinate prezzo, del punto di ancoraggio
{
//--- se il punto della posizione non è impostato, spostarlo nella barra corrente che ha il prezzo Bid
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- resetta il valore dell' errore
ResetLastError();
//--- sposta il punto di ancoraggio della trendline
if(!ObjectMove(chart_ID,name,0,time,price))
{
Print(__FUNCTION__,
": fallimento nello spostare il punto di ancoraggio! Error code = ",GetLastError());
return(false);
}
//--- esecuzione avvenuta
return(true);
}
//+--------------------------------------------------------------------------------+
//| Cambia l'angolo di pendenza della trendline |
//+--------------------------------------------------------------------------------+
bool TrendAngleChange(const long chart_ID=0, // ID del chart
const string name="TrendLine", // nome della trend line
const double angle=45) // angolo di pendenza della trendline
{
//--- resetta il valore dell' errore
ResetLastError();
//--- cambia l'angolo di pendenza della trendline
if(!ObjectSetDouble(chart_ID,name,OBJPROP_ANGLE,angle))
{
Print(__FUNCTION__,
": fallimento nel cambiare l'angolo di pendenza della linea! Error code = ",GetLastError());
return(false);
}
//--- esecuzione avvenuta
return(true);
}
//+--------------------------------------------------------------------------------+
//| Elimina la trendline |
//+--------------------------------------------------------------------------------+
bool TrendDelete(const long chart_ID=0, // ID del chart
const string name="TrendLine") // nome della linea
{
//--- resetta il valore dell' errore
ResetLastError();
//--- elimina una trendline
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": fallimento nell'eliminare una trendline! Error code = ",GetLastError());
return(false);
}
//--- esecuzione avvenuta
return(true);
}
//+--------------------------------------------------------------------------------+
//| Controlla i valori dei punti di ancoraggio della trendline ed imposta i |
//| valori di default per quelli vuoti |
//+--------------------------------------------------------------------------------+
void ChangeTrendEmptyPoints(datetime &time1,double &price1,
datetime &time2,double &price2)
{
//--- se l'orario del primo punto non è impostato, sarà sulla barra corrente
if(!time1)
time1=TimeCurrent();
//--- se il prezzo del punto non è impostato, avrà un valore Bid
if(!price1)
price1=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- imposta le coordinate del secondo punto ausiliare
//--- il secondo punto sarà 9 barre a sinistra ed avrà lo stesso prezzo
datetime second_point_time[10];
CopyTime(Symbol(),Period(),time1,10,second_point_time);
time2=second_point_time[0];
price2=price1;
}
//+--------------------------------------------------------------------------------+
//| Funzione di avvio del programma Script |
//+--------------------------------------------------------------------------------+
voidOnStart()
{
//--- imposta la correttezza dei parametri di input
if(InpDate1<0 || InpDate1>100 || InpPrice1<0 || InpPrice1>100)
{
Print("Error! Valori non corretti dei parametri di input!");
return;
}
//--- Numero di barre visibili nella finestra del chart
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- grandezza dell'array prezzo
int accuracy=1000;
//--- array per la memorizzazione dei valori di data e prezzo da essere usati
//--- per impostare e cambiare i punti delle coordinate di ancoraggio della linea
datetime date[];
double price[];
//--- allocazione della memoria
ArrayResize(date,bars);
ArrayResize(price,accuracy);
//--- riempie l'array delle date
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("Fallimento nella copia dei valori tempo! Error code = ",GetLastError());
return;
}
/--- riempie l'array dei prezzi
//--- trova i valori più alti e più bassi del chart
double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- definisce un cambio di step del prezzo e riempie l'array
double step=(max_price-min_price)/accuracy;
for(int i=0;i<accuracy;i++)
price[i]=min_price+i*step;
//--- definisce i punti per disegnare la linea
int d1=InpDate1*(bars-1)/100;
int p1=InpPrice1*(accuracy-1)/100;
//--- crea una trend line
if(!TrendByAngleCreate(0,InpName,0,date[d1],price[p1],InpAngle,InpColor,InpStyle,
InpWidth,InpBack,InpSelection,InpRayLeft,InpRayRight,InpHidden,InpZOrder))
{
return;
}
//--- redisegna il chart ed attende per 1 secondo
ChartRedraw();
Sleep(1000);
//--- ora, sposta e ruota la linea
//---contatore del ciclo
int v_steps=accuracy/2;
//--- sposta il punto di ancoraggio e cambia l'angolo di pendenza della linea
for(int i=0;i<v_steps;i++)
{
//--- usa il seguente valore
if(p1>1)
p1-=1;
//--- sposta il punto
if(!TrendPointChange(0,InpName,date[d1],price[p1]))
return;
if(!TrendAngleChange(0,InpName,18*(i+1)))
return;
//--- controlla se l'operazione dello script è stata disabilitata per forza
if(IsStopped())
return;
//--- ridisegna il chart
ChartRedraw();
}
//--- 1 secondo di ritardo
Sleep(1000);
//--- elimina dal chart
TrendDelete(0,InpName);
ChartRedraw();
//--- 1 secondo di ritardo
Sleep(1000);
//---
}
|
