//--- descrizione
#property description "Lo script disegna il segno di \"Freccia Su\"."
#property description "Le coordinate del punto di ancoraggio sono impostate in"
#property description "percentuale della grandezza della finestra chart."
//--- mostra la finestra dei parametri di input durante il lancio dello script
#property script_show_inputs
//--- parametri di input dello script
input string InpName="ArrowUp"; // Nome del segno
input int InpDate=25; // Anchor point date in %
input int InpPrice=25; // Anchor point price in %
input ENUM_ARROW_ANCHOR InpAnchor=ANCHOR_TOP; // Tipo di ancoraggio
input color InpColor=clrRed; // Colore del segno
input ENUM_LINE_STYLE InpStyle=STYLE_DOT; // Stile del bordo della linea
input int InpWidth=5; // Grandezza del segno
input bool InpBack=false; // Segno di sottofondo
input bool InpSelection=false; // Evidenzia di movimento
input bool InpHidden=true; // Nascosta nella lista oggetti
input long InpZOrder=0; // Priorità per il click del mouse
//+--------------------------------------------------------------------------------+
//| Crea il segno di Freccia Su |
//+--------------------------------------------------------------------------------+
bool ArrowUpCreate(const long chart_ID=0, // ID del chart
const string name="ArrowUp", // nome del segno
const int sub_window=0, // indice sottofinestra
datetime time=0, // punto di ancoraggio tempo
double price=0, // prezzo punto di ancoraggio
const ENUM_ARROW_ANCHOR anchor=ANCHOR_BOTTOM, // tipo di ancoraggio
const color clr=clrRed, // colore del segno
const ENUM_LINE_STYLE style=STYLE_SOLID, // stile del bordo della linea
const int width=3, // grandezza del segno
const bool back=false, // in sottofondo
const bool selection=true, // evidenzia del movimento
const bool hidden=true, // nascosto nella lista oggetti
const long z_order=0) // priorità per il click del mouse
{
//--- imposta coordinate punto di ancoraggio se non sono impostate
ChangeArrowEmptyPoint(time,price);
//--- resetta il valore dell' errore
ResetLastError();
//--- crea il segno
if(!ObjectCreate(chart_ID,name,OBJ_ARROW_UP,sub_window,time,price))
{
Print(__FUNCTION__,
": fallimento nella creazione del segno \"Freccia Su\"! Error code = ",GetLastError());
return(false);
}
//--- imposta il tipo di ancora
ObjectSetInteger(chart_ID,name,OBJPROP_ANCHOR,anchor);
//--- imposta il colore del segno
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- imposta lo stile del bordo linea
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- imposta la grandezza del segno
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- mostra in primo piano (false) o sottofondo (true)
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- abilita (true) o disabilita (false) la modalità di spostare il segno con il mouse
//--- quando si crea un oggetto grafico utilizzando la funzione ObjectCreate, l'oggetto non può esser
//--- evidenziato e mosso, per default. All'interno di questo metodo, la selezione dei parametri
//--- è true per default, il che consente di evidenziare e spostare l'oggetto
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- nascondi (true) o mostra (falso) il nome di oggetto grafico nella lista degli oggetti
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- imposta la priorità per ricevere l'evento di un clic del mouse nel grafico
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- esecuzione avvenuta
return(true);
}
//+--------------------------------------------------------------------------------+
//| Sposta il punto di ancoraggio |
//+--------------------------------------------------------------------------------+
bool ArrowUpMove(const long chart_ID=0, // ID del chart
const string name="ArrowUp", // nome oggetto
datetime time=0, // coordinate del punto di ancoraggio tempo
double price=0) // anchor point price coordinate
{
//--- se il punto della posizione non è impostato, spostarlo nella barra corrente che ha il prezzo Bid
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- resetta il valore dell' errore
ResetLastError();
//--- sposta il punto di ancoraggio
if(!ObjectMove(chart_ID,name,0,time,price))
{
Print(__FUNCTION__,
": fallimento nello spostare il punto di ancoraggio! Error code = ",GetLastError());
return(false);
}
//--- esecuzione avvenuta
return(true);
}
//+--------------------------------------------------------------------------------+
//| Cambia il tipo di segno di ancoraggio Freccia Giu |
//+--------------------------------------------------------------------------------+
bool ArrowUpAnchorChange(const long chart_ID=0, // ID del chart
const string name="ArrowUp", // nome oggetto
const ENUM_ARROW_ANCHOR anchor=ANCHOR_TOP) // tipo di ancoraggio
{
//--- resetta il valore dell' errore
ResetLastError();
//--- cambia la posizione del punto di ancoraggio
if(!ObjectSetInteger(chart_ID,name,OBJPROP_ANCHOR,anchor))
{
Print(__FUNCTION__,
": fallimento nel cambiare il tipo di ancora! Error code = ",GetLastError());
return(false);
}
//--- esecuzione avvenuta
return(true);
}
//+--------------------------------------------------------------------------------+
//| Elimina il segno di Freccia Su |
//+--------------------------------------------------------------------------------+
bool ArrowUpDelete(const long chart_ID=0, // ID del chart
const string name="ArrowUp") // nome del segno
{
//--- resetta il valore dell' errore
ResetLastError();
//--- elimina il segno
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": fallimento nell'eliminazione del segno \"Freccia Su\"! Error code = ",GetLastError());
return(false);
}
//--- esecuzione avvenuta
return(true);
}
//+--------------------------------------------------------------------------------+
//| Controlla i valori di punto di ancoraggio ed imposta i valori di default |
//| per quelli vuoti |
//+--------------------------------------------------------------------------------+
void ChangeArrowEmptyPoint(datetime &time,double &price)
{
//--- se il tempo del punto non è impostato, sarà sulla barra corrente
if(!time)
time=TimeCurrent();
//--- se il prezzo del punto non è impostato, avrà un valore Bid
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
}
//+--------------------------------------------------------------------------------+
//| Funzione di avvio del programma Script |
//+--------------------------------------------------------------------------------+
voidOnStart()
{
//--- imposta la correttezza dei parametri di input
if(InpDate<0 || InpDate>100 || InpPrice<0 || InpPrice>100)
{
Print("Error! Valori non corretti dei parametri di input!");
return;
}
//--- Numero di barre visibili nella finestra del chart
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- grandezza dell'array prezzo
int accuracy=1000;
//--- array per la memorizzazione dei valori di data e prezzo da essere usati
//--- per impostare e cambiare le coordinate del segno di ancoraggio
datetime date[];
double price[];
//--- allocazione della memoria
ArrayResize(date,bars);
ArrayResize(price,accuracy);
//--- riempie l'array delle date
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("Fallimento nella copia dei valori tempo! Error code = ",GetLastError());
return;
}
/--- riempie l'array dei prezzi
//--- trova i valori più alti e più bassi del chart
double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- definisce un cambio di step del prezzo e riempie l'array
double step=(max_price-min_price)/accuracy;
for(int i=0;i<accuracy;i++)
price[i]=min_price+i*step;
//--- definisce i punti per disegnare il segno
int d=InpDate*(bars-1)/100;
int p=InpPrice*(accuracy-1)/100;
//--- crea il segno di Freccia Su sul chart
if(!ArrowUpCreate(0,InpName,0,date[d],price[p],InpAnchor,InpColor,
InpStyle,InpWidth,InpBack,InpSelection,InpHidden,InpZOrder))
{
return;
}
//--- redisegna il chart ed attende per 1 secondo
ChartRedraw();
Sleep(1000);
//--- ora, sposta il punto di ancoraggio e modificare la sua posizione rispetto al segno
//---contatore del ciclo
int v_steps=accuracy/2;
//--- sposta il punto di ancoraggio
for(int i=0;i<v_steps;i++)
{
//--- usa il seguente valore
if(p<accuracy-1)
p+=1;
//--- sposta il punto
if(!ArrowUpMove(0,InpName,date[d],price[p]))
return;
//--- controlla se l'operazione dello script è stata disabilitata per forza
if(IsStopped())
return;
//--- ridisegna il chart
ChartRedraw();
}
//--- 1 secondo di ritardo
Sleep(1000);
//--- cambia la locazione del punto di ancoraggio relativa al segno
ArrowUpAnchorChange(0,InpName,ANCHOR_BOTTOM);
//--- redisegna il chart
ChartRedraw();
//--- 1 secondo di ritardo
Sleep(1000);
//--- elimina il segno dal chart
ArrowUpDelete(0,InpName);
ChartRedraw();
//--- 1 secondo di ritardo
Sleep(1000);
//---
}
|
