DokümantasyonBölümler
MQL5 ReferansıDizgi FonksiyonlarıStringSplit 

StringSplit

Belirtilen ayracı kullanarak, belirtilen bir dizgiden alt-dizgiler elde eder ve bu alt-dizgilerin sayısına dönüş yapar.

int  StringSplit(
   const string   string_value,       // aranacak dizgi
   const ushort   separator,          // alt-dizgileri ayırmak için kullanılan ayraç
   string         & result[]          // bulunan alt-dizgilerin alınması için referans ile geçirilen bir dizi
   );

Parametreler

string_value

[in]  Alt dizginin içinde bulunması istenilen dizgi (dizgi değişmez).

pos

[in]  Ayırıcı karakterin kodu. Kodu almak için StringGetCharacter() fonksiyonunu kullanabilirsiniz.

result[]

[out]  Elde edilen alt-dizgilerin yerleştirildiği (dizgilerden oluşan) bir dizi.

Dönüş değeri

result[] dizisindeki alt-dizgilerin sayısı. Ayraç, geçirilen dizgi içerisinde bulunamazsa, sadece kaynak dizgisi dizi içine geçirilir.

string_value değeri NULL veya boş ise, fonksiyon sıfır dönüşü yapar. Hata durumunda ise -1 dönüşü yapar. Hata kodu almak için GetLastError() fonksiyonunu kullanın.

Örnek:

string to_split="_life_is_good_"; // Alt-dizgilere ayrılacak dizgi
   string sep="_";                // Karakter şeklinde bir ayraç
   ushort u_sep;                  // Ayırıcı karakterin kodu
   string result[];               // Dizgilerin geçirileceği dizi
   //--- Ayraç kodunu al
   u_sep=StringGetCharacter(sep,0);
   //--- Dizgiyi alt-dizgilere böl
   int k=StringSplit(to_split,u_sep,result);
   //--- Bir yorum göster 
   PrintFormat("Alınan dizgi: %d. Kullanılan ayraç: '%s', ayraç kodu: %d",k,sep,u_sep);
   //--- Şimdi, alınan tüm dizgileri çıktıla
   if(k>0)
     {
      for(int i=0;i<k;i++)
        {
         PrintFormat("result[%d]=\"%s\"",i,result[i]);
        }
     }

Ayrıca Bakınız

StringReplace(), StringSubstr(), StringConcatenate()