Técnicas do Assistente MQL5 que você deve conhecer (Parte 46): Ichimoku

Introdução

O Ichimoku Kinko Hyo, que muitas vezes é chamado de Nuvem de Ichimoku, é um sistema de análise técnica abrangente, projetado para fornecer uma visão holística das tendências de mercado; níveis de suporte e resistência; bem como do momentum. Desenvolvido no final da década de 1930 e refinado ao longo das três décadas seguintes, Ichimoku Kinko Hyo se traduz do japonês como “gráfico de equilíbrio em um olhar” ou “gráfico de balanço de relance”; nomes que enfatizam seu design para oferecer uma única e detalhada perspectiva sobre o mercado.

Este indicador, que serve como um sistema, consiste em cinco linhas (ou buffers) e uma área sombreada geralmente chamada de Kumo (que em japonês significa Nuvem). Cada um dos buffers constituintes tem o objetivo de capturar aspectos particulares do comportamento do preço, e eles são: Tenkan-sen (também chamada de Linha de Conversão, serve como um indicador de momentum de curto prazo); Kijun-sen (também chamada de linha-base e atua como indicador de tendência de médio prazo); Senkou Span A (ou Faixa de Liderança A) e Senkou Span B (ou Faixa de Liderança B), que juntas formam a Kumo, projetando níveis de suporte e resistência no futuro; e, por fim, a Chikou Span (ou Faixa de Retardo), que funciona como uma linha que plota o preço de fechamento, deslocada para trás, oferecendo assim uma visão da ação histórica do preço em relação aos níveis atuais.

Abaixo estão as fórmulas para cada um desses 5 buffers:

Onde:

• H 9 É a máxima dos últimos 9 períodos.
• L 9 É a mínima dos últimos 9 períodos.

Isso se destina a refletir a tendência de curto prazo, calculando a média entre a máxima e a mínima dos últimos 9 períodos.

Onde:

• H 26 É a máxima dos últimos 26 períodos.
• L 26 É a mínima dos últimos 26 períodos.

Isso representa a tendência de médio prazo, usando um intervalo de 26 períodos para suavizar as flutuações de preço.

Onde:

• Tenkan-sen É a Linha de Conversão conforme definida acima.
• Kijun-sen É a linha-base conforme definida acima.

Onde este buffer é calculado como a média do Tenkan-sen e do Kijun-sen e é projetado 26 períodos no futuro.

Onde:

• H 52 É a máxima dos últimos 52 períodos.
• L 52 É a mínima dos últimos 52 períodos.

Onde este é a média entre a máxima e a mínima dos últimos 52 períodos, projetada 26 períodos no futuro. Isso forma o limite superior ou inferior da nuvem, dependendo de sua posição relativa à Span A.

Onde:

• Close t−26 É o preço de fechamento atual deslocado 26 períodos para trás.

Onde isso oferece contexto histórico ao plotar o preço de fechamento de hoje 26 períodos atrás da data atual.

A Kumo (ou nuvem) é formada pela área entre Senkou Span A e Senkou Span B, e serve como uma zona de suporte e resistência futura. Frequentemente, uma nuvem mais espessa indica suporte/resistência mais fortes, enquanto uma nuvem mais fina implica que pode ser facilmente rompida, sugerindo níveis mais fracos. A cor da nuvem é outro recurso-chave do Ichimoku já que, tipicamente, quando Senkou Span A está acima da Senkou Span B, a nuvem é altista (normalmente sombreada em verde), e quando Senkou Span B está acima da Senkou Span A, a nuvem é baixista (frequentemente sombreada em vermelho).

Vamos agora revisar os vários padrões do Ichimoku, como temos feito com outros indicadores nestes artigos. Vamos revisar 11 padrões do Ichimoku e, como nos artigos anteriores, começaremos analisando um padrão por vez, onde usamos o inteiro de entrada ‘Signal_Ichimoku_PatternsUsed’ para definir quais conjuntos de padrões são observados pelo Expert Advisor e quais padrões são ignorados. Este inteiro de entrada é inicialmente usado para selecionar apenas um dos 11 padrões de cada vez, e uma vez que todos os padrões tenham sido testados de forma independente, então otimizamos para uma combinação ideal desses padrões que nos forneceria os resultados mais ideais.

Como temos 11 padrões, este inteiro de entrada não deve receber um valor maior que 2¹¹ menos 1 (2047), já que este inteiro é capaz de capturar todas as combinações possíveis de padrões. Estamos realizando nossos testes no par GBP JPY no período de uma hora para o ano de 2022. Todos os resultados de teste apresentados aqui são apenas execuções de alguns dos resultados razoáveis obtidos a partir da otimização do Expert Advisor sobre sua curta janela de teste de 2022 com GBP JPY. Nenhum forward walk ou validação cruzada foi feito, e o código anexado destina-se a ser montado em um Expert Advisor usando o wizard do MQL5, para o qual existem orientações aqui e aqui para novos leitores.

Crossover Tenkan-Sen e Kijun-Sen

Este é, sem dúvida, o sinal mais comum ou popular entre os padrões do Ichimoku. Em essência, quase se traduz em um cruzamento simples de médias móveis (para períodos rápido e lento) e, dado seus parâmetros de entrada estoicos para os períodos de média, muitos consideram este e o indicador em geral não sensível o suficiente às condições de mercado em mudança. Ainda assim, um sinal altista é quando o Tenkan-sen cruza acima do Kijun-sen e um padrão baixista é o oposto, quando o Tenkan-sen cruza abaixo do Kijun-sen. Implementamos isso em MQL5 da seguinte forma:

//+------------------------------------------------------------------+
//| Check for Pattern 0.                                             |
//+------------------------------------------------------------------+
bool CSignalIchimoku::IsPattern_0(ENUM_POSITION_TYPE T)
{  if(T == POSITION_TYPE_BUY && Tankensen(X()+1) < Kijunsen(X()+1) && Tankensen(X()) > Kijunsen(X()))
   {  return(true);
   }
   else if(T == POSITION_TYPE_SELL && Tankensen(X()+1) > Kijunsen(X()+1) && Tankensen(X()) < Kijunsen(X()))
   {  return(true);
   }
   return(false);
}

Os testes realizados para GBP JPY no período de 1 hora em 2022 nos apresentam os seguintes resultados:

Este crossover, no entanto, é suscetível ao Ruído de Mercado, uma vez que o cruzamento pode reagir fortemente a pequenas flutuações, particularmente em prazos menores. Essa sensibilidade excessiva pode resultar em sinais falsos, onde cruzamentos ocorrem sem uma mudança significativa de tendência, levando a posições abertas que sofrem whipsaws frequentes em mercados laterais ou consolidados.

Isso significa que o padrão-0 pode ter eficácia limitada em Mercados Laterais, já que o método de crossover é mais adequado para mercados em tendência; em mercados laterais, os cruzamentos frequentes podem enganar os traders, levando a entradas e saídas sem direção ou consistência. Sem uma tendência clara, portanto, cruzamentos entre Tenkan-sen e Kijun-sen podem resultar em aumento de custos de transação e potenciais perdas decorrentes de negociações improdutivas.

Preço vs. Kijun-Sen (Linha-base)

Nosso padrão 1, muito parecido com o padrão-0, também se assemelha a um cruzamento de preço e médias móveis, se considerarmos o padrão 0 acima como um cruzamento puro de médias móveis. O Kijun-sen observa um período um pouco mais longo que o Tenkan-sen, portanto, qualquer cruzamento de preço que ele registrar é frequentemente significativo. Para um sinal altista, o preço cruza-o de baixo para fechar acima dele, e para um sinal baixista, faz o oposto, cruzando de cima para fechar abaixo. Implementamos isso em MQL5 da seguinte forma:

//+------------------------------------------------------------------+
//| Check for Pattern 1.                                             |
//+------------------------------------------------------------------+
bool CSignalIchimoku::IsPattern_1(ENUM_POSITION_TYPE T)
{  if(T == POSITION_TYPE_BUY && Close(X()+1) < Kijunsen(X()+1) && Close(X()) > Kijunsen(X()))
   {  return(true);
   }
   else if(T == POSITION_TYPE_SELL && Close(X()+1) > Kijunsen(X()+1) && Close(X()) < Kijunsen(X()))
   {  return(true);
   }
   return(false);
}

Execuções de teste com configurações semelhantes às anteriores, após uma breve otimização, com o parâmetro de entrada para padrões usados atribuído a 2, nos dão os seguintes resultados:

Embora o padrão-1 mostre alguma promessa a partir desta execução de teste acima, ele apresenta algumas armadilhas das quais os traders devem estar atentos. Primeiramente, o Kijun-sen reflete o preço médio ao longo de 26 períodos, mas não fornece nenhuma orientação sobre o momentum da tendência ou a força da tendência. Isso geralmente significa que traders que dependem apenas desse sinal podem perder indícios de enfraquecimento do momentum, o que pode resultar em perdas em posições abertas caso a tendência reverta ou entre em consolidação.

Além disso, este padrão não fornece pistas sobre sinais de saída ou, mais importante, alvos de preço. Embora o Kijun-sen possa ser útil para marcar tendências predominantes, sua falta de utilidade em definir não apenas níveis de take profit, mas até mesmo níveis de stop loss, pode ser uma preocupação para traders que optam por depender apenas desse padrão.

Kumo (Nuvem) Breakout

Assim como o crossover que consideramos no padrão-0, a nuvem, Kumo, é um indicador importante e fonte de padrões dentro do Ichimoku. Estendendo-se entre as duas spans Senkou, sua importância decorre principalmente de sua associação com suporte e resistência. Um sinal altista aqui é definido como um breakout quando o preço atravessa e consegue fechar acima da nuvem. Um sinal baixista seria o inverso, quando o preço cai através da nuvem e permanece lá após o fechamento. Mostramos isso em código da seguinte forma:

//+------------------------------------------------------------------+
//| Check for Pattern 2.                                             |
//+------------------------------------------------------------------+
bool CSignalIchimoku::IsPattern_2(ENUM_POSITION_TYPE T)
{  if(T == POSITION_TYPE_BUY && 
      ((Close(X()+1) < SenkouSpanA(X()+1) && Close(X()) > SenkouSpanA(X()) && SenkouSpanA(X()) > SenkouSpanB(X()))
      ||
      (Close(X()+1) < SenkouSpanB(X()+1) && Close(X()) > SenkouSpanB(X()) && SenkouSpanB(X()) > SenkouSpanA(X())))
      )
   {  return(true);
   }
   else if(T == POSITION_TYPE_SELL &&
      ((Close(X()+1) > SenkouSpanA(X()+1) && Close(X()) < SenkouSpanA(X()) && SenkouSpanA(X()) < SenkouSpanB(X()))
      ||
      (Close(X()+1) > SenkouSpanB(X()+1) && Close(X()) < SenkouSpanB(X()) && SenkouSpanB(X()) < SenkouSpanA(X())))
      )
   {  return(true);
   }
   return(false);
}

Testes com configurações semelhantes às anteriores, mas com foco no padrão 2, atribuindo ao parâmetro de entrada o valor 4, nos dão os seguintes resultados:

Embora o padrão-2 também ofereça resultados interessantes, como podemos ver acima, ele é muito sensível aos prazos. Isso é particularmente importante porque, em prazos menores, os breakouts são mais suscetíveis ao ruído de mercado e às flutuações temporárias de preço, o que pode levar a sinais falsos frequentes. Por outro lado, e infelizmente, em prazos maiores, muitas vezes o sinal de breakout atrasa e acaba perdendo o ponto de entrada ideal.

O padrão-2, além disso, precisa depender do contexto da tendência para confirmação. Isso porque, para que um breakout da Kumo seja confiável, ele deve estar alinhado com a tendência mais ampla indicada por outros componentes do Ichimoku, como a Linha de Retardo, bem como as posições relativas da linha-base e da Linha de Conversão. E isso leva a outra fraqueza que pode atravessar todos os indicadores, mas que ainda vale a pena mencionar. Ignorar os Fundamentos do Mercado. Traders que dependem apenas do breakout da Kumo podem perder um contexto crucial de mercado.

Kumo (Nuvem) Twist

O twist da nuvem é o nosso padrão-3, e decorre da mudança de cor da nuvem ou da troca de posição entre a Senkou Span A e a Senkou Span B. Sendo também médias móveis de fato, isso faz com que este seja mais um crossover, embora com um efeito defasado. Um sinal altista, portanto, ocorre quando a Senkou Span A (o buffer de período “mais curto”) cruza a Senkou Span B de baixo para fechar acima dela. Isso também é conhecido como bullish Kumo twist, que sinaliza uma potencial tendência de alta futura. Da mesma forma, um sinal baixista seria quando cruza de cima para fechar abaixo, o que também é chamado de bearish Kumo twist. Realizamos isso em código da seguinte forma:

//+------------------------------------------------------------------+
//| Check for Pattern 3.                                             |
//+------------------------------------------------------------------+
bool CSignalIchimoku::IsPattern_3(ENUM_POSITION_TYPE T)
{  if(T == POSITION_TYPE_BUY && SenkouSpanA(X()+1) < SenkouSpanB(X()+1) && SenkouSpanA(X()) > SenkouSpanB(X()))
   {  return(true);
   }
   else if(T == POSITION_TYPE_SELL && SenkouSpanA(X()+1) > SenkouSpanB(X()+1) && SenkouSpanA(X()) < SenkouSpanB(X()))
   {  return(true);
   }
   return(false);
}

Testando no GBP JPY para o ano de 2022 no período de 1 hora, como acima, nos apresenta os seguintes resultados:

O padrão-3, no entanto, tem suas armadilhas, sendo a principal delas a má interpretação da espessura da nuvem. Para muitos traders, o Kumo-twist é frequentemente associado à espessura da nuvem, com a espessura da nuvem sendo interpretada como sinal de tendências mais fortes. A avaliação dessa espessura, porém, exige experiência e contexto adequado de mercado, pois muitas vezes um twist de nuvem pode ser facilmente revertido, especialmente em mercados instáveis.

Este padrão, como outros que vimos acima, fornece pouco em termos de indicação da força ou do momentum da tendência. Isso torna difícil determinar se uma reversão terá sustentação. Isso apresenta riscos de entrar em negociações em declínio. Isso reforça novamente a importância de depender do contexto mais amplo do Ichimoku, em que o twist da Kumo deve, idealmente, ser confirmado por outros elementos do Ichimoku, como o cruzamento Tenkan-sen e Kijun-sen ou o Chikou Span. Confiar unicamente no twist sem essas confirmações pode levar a sinais falsos. Traders que não consideram o sistema completo do Ichimoku podem interpretar mal os twists, e é por isso que estamos apresentando esses padrões não individualmente, mas como um conjunto do qual os traders podem escolher o que é mais adequado para seus setups.

Chikou Span (Linha de Retardo) Confirmação

O Chikou Span é um buffer defasado e, embora usá-lo em um gráfico para trading manual possa ser simples, ao lê-lo em código é necessário garantir que o indexamento esteja devidamente ajustado. Teríamos um sinal altista se o Chikou Span cruzar acima da ação do preço, o que confirmaria o momentum altista e reforçaria a compra. Por outro lado, um sinal baixista ocorreria se o Chikou Span cruzar abaixo da ação do preço, sinalizando momentum baixista e confirmando o sinal de venda. Codificamos isso da seguinte forma:

//+------------------------------------------------------------------+
//| Check for Pattern 4.                                             |
//+------------------------------------------------------------------+
bool CSignalIchimoku::IsPattern_4(ENUM_POSITION_TYPE T)
{  if(T == POSITION_TYPE_BUY && ChikouSpan(X()+1) <= Tankensen(X()+1) && ChikouSpan(X()) > Tankensen(X()))
   {  return(true);
   }
   else if(T == POSITION_TYPE_SELL && ChikouSpan(X()+1) >= Tankensen(X()+1) && ChikouSpan(X()) < Tankensen(X()))
   {  return(true);
   }
   return(false);
}

Testando com as mesmas configurações que os outros padrões, obtemos os seguintes resultados:

A dependência excessiva, ignorando outros sinais importantes, é uma armadilha para o padrão-4. Isso merece ser mencionado novamente, como nos outros padrões acima, mas o Chikou Span é idealmente um sinal de confirmação, como o título do padrão sugere, então combiná-lo com o breakout da Kumo ou com o cruzamento Tenkan-sen e Kijun-sen seria adequado. Focar apenas nele pode resultar em uma compreensão incompleta da dinâmica de mercado. Isso também se relaciona a outras fraquezas já mencionadas: relevância limitada em mercados movidos por fundamentos, bem como o risco de não considerar o contexto mais amplo e fatores do mercado.

Kumo como Suporte e Resistência

Além de atuar como um limiar de rompimento, a Kumo pode servir como uma forma de suporte ou resistência dinâmicos, que podem definir um padrão separado do padrão-2 acima, que chamamos de padrão-5. A estratégia de negociação, portanto, apresentará um bounce altista formado se o preço recuar até a nuvem mas não conseguir rompê-la, sendo a nuvem um suporte, o que pode ser tomado como ponto de entrada para operações de compra. A rejeição baixista ocorreria se o preço avançar até a nuvem mas não conseguir romper acima dela, com a nuvem atuando como resistência, sinalizando assim uma potencial oportunidade de venda. A codificação do padrão-5 é a seguinte:

//+------------------------------------------------------------------+
//| Check for Pattern 5.                                             |
//+------------------------------------------------------------------+
bool CSignalIchimoku::IsPattern_5(ENUM_POSITION_TYPE T)
{  if(T == POSITION_TYPE_BUY && 
      ((Close(X()+2) > SenkouSpanA(X()+2) && Close(X()+1) < SenkouSpanA(X()+1) && Close(X()) > SenkouSpanA(X()) && SenkouSpanA(X()) > SenkouSpanB(X()))
      ||
      (Close(X()+2) > SenkouSpanA(X()+2) && Close(X()+1) < SenkouSpanB(X()+1) && Close(X()) > SenkouSpanB(X()) && SenkouSpanB(X()) > SenkouSpanA(X())))
      )
   {  return(true);
   }
   else if(T == POSITION_TYPE_SELL &&
      ((Close(X()+2) < SenkouSpanA(X()+2) && Close(X()+1) > SenkouSpanA(X()+1) && Close(X()) < SenkouSpanA(X()) && SenkouSpanA(X()) < SenkouSpanB(X()))
      ||
      (Close(X()+2) < SenkouSpanA(X()+2) && Close(X()+1) > SenkouSpanB(X()+1) && Close(X()) < SenkouSpanB(X()) && SenkouSpanB(X()) < SenkouSpanA(X())))
      )
   {  return(true);
   }
   return(false);
}

Testes com o parâmetro de entrada para padrões usados atribuído ao valor 32, o que garante que testamos apenas este padrão e nenhum dos outros 10, nos dão os seguintes resultados:

O padrão-5, em que a Kumo atua como suporte/resistência, sofre de reação atrasada na identificação de reversões de tendência. Isso ocorre porque a Kumo fica atrás da ação de preço atual devido ao seu cálculo (deslocamento de 26 períodos para frente), o que resulta em sinais atrasados em comparação com indicadores alternativos de suporte/resistência em tempo real. Esses atrasos podem levar os traders a entrar tarde, reduzindo assim sua eficácia como métrica de suporte/resistência, especialmente em mercados de ritmo acelerado.

Além disso, o padrão-5 apresenta desafios na identificação precisa de seus níveis. Diferente de linhas tradicionais de suporte e resistência, a nuvem Kumo é uma zona, e não um nível de preço específico. Isso dificulta ligeiramente o processo de identificar pontos precisos de entrada e saída. Essa ambiguidade pode dificultar o gerenciamento das operações, já que definir stop-loss ou take-profit precisos dentro da nuvem pode ser desafiador.

Por fim, este padrão pode ser pouco confiável em mercados fortemente direcionais, já que os preços rompem facilmente a Kumo com pouca hesitação. Isso o torna menos confiável como indicador de suporte ou resistência e mais como um buffer de preço. Isso pode levar a oportunidades perdidas se os traders dependerem apenas dele para decisões de negociação.

Crossovers Fortes (Acima ou Abaixo da Kumo)

Nosso padrão-6 revisita o padrão fundamental do Ichimoku, o padrão-0, adicionando um filtro que considera a posição relativa da Kumo ao cruzamento Tenkan-sen e Kijun-sen. Esses dois podem cruzar a qualquer momento; no entanto, argumenta-se que ao emparelhar cada crossover com uma determinada posição da Kumo, obtemos um sinal ainda mais forte. O sinal altista seria marcado se o cruzamento altista Tenkan-sen/Kijun-sen ocorrer acima da nuvem, o que, como já enfatizado, indicaria um forte sinal de compra. O forte sinal baixista seria indicado se o cruzamento baixista Tenkan-sen/Kijun-sen ocorrer abaixo da nuvem. Este sinal implica que qualquer crossover que aconteça dentro da nuvem é menos forte devido à indecisão no mercado. Codificamos o padrão-6 da seguinte forma:

//+------------------------------------------------------------------+
//| Check for Pattern 6.                                             |
//+------------------------------------------------------------------+
bool CSignalIchimoku::IsPattern_6(ENUM_POSITION_TYPE T)
{  if(T == POSITION_TYPE_BUY  && Tankensen(X()+1) < Kijunsen(X()+1) && Tankensen(X()) > Kijunsen(X()) &&
      ((Tankensen(X()) > SenkouSpanA(X()) && SenkouSpanA(X()) > SenkouSpanB(X()))
      ||
      (Tankensen(X()) > SenkouSpanB(X()) && SenkouSpanB(X()) > SenkouSpanA(X())))
      )
   {  return(true);
   }
   else if(T == POSITION_TYPE_SELL && Tankensen(X()+1) > Kijunsen(X()+1) && Tankensen(X()) < Kijunsen(X()) &&
      ((Tankensen(X()) < SenkouSpanA(X()) && SenkouSpanA(X()) < SenkouSpanB(X()))
      ||
      (Tankensen(X()) < SenkouSpanB(X()) && SenkouSpanB(X()) < SenkouSpanA(X())))
      )
   {  return(true);
   }
   return(false);
}

Testando com configurações semelhantes às anteriores, com o parâmetro de entrada para padrões usados atribuído ao valor 64, obtemos os seguintes resultados:

Apesar do relatório acima do padrão-6, os crossovers da Kumo tendem a atrasar bastante. Um crossover forte acima ou abaixo da Kumo geralmente ocorre após uma mudança significativa de tendência já ter acontecido, e isso pode causar atrasos potenciais em entradas ou saídas. Traders que dependem apenas dos crossovers da Kumo para suas entradas podem acabar entrando tarde, perdendo as partes iniciais e mais lucrativas da tendência.

Há também vulnerabilidade a reversões em mercados voláteis. Isso porque, em mercados altamente voláteis ou movidos por notícias, um crossover forte pode rapidamente reverter de direção, prendendo traders que entraram apenas com base nesse crossover. Essas reversões súbitas podem levar a perdas significativas, especialmente se os traders não confirmarem a tendência com outros indicadores.

Por fim, e isso pode ser tomado como um tema para o Ichimoku, a frequente ação de preço em whipsaw em mercados laterais tende a produzir muitos sinais falsos, à medida que os preços oscilam em torno da Kumo sem direção clara.

Força da Tendência via Espessura da Nuvem

Outro padrão dentro do Ichimoku que pode ser usado para orientar decisões de compra e venda é a espessura da Kumo. A premissa por trás disso é que uma Kumo fina indica suporte ou resistência fracos, o que pode levar a breakouts ou reversões, enquanto uma Kumo espessa indica suporte ou resistência fortes e pode sinalizar a continuação da tendência atual. Para aplicar isso, definimos nosso sinal altista como uma tendência altista ao longo de um período de cerca de 26 barras, que também seja marcada por um aumento da espessura da nuvem. Por outro lado, o sinal baixista será uma tendência de baixa em um período semelhante, também marcada pelo espessamento das nuvens ao longo desse período. Implementamos isto da seguinte forma:

//+------------------------------------------------------------------+
//| Check for Pattern 7.                                             |
//+------------------------------------------------------------------+
bool CSignalIchimoku::IsPattern_7(ENUM_POSITION_TYPE T)
{  if(T == POSITION_TYPE_BUY && Close(X()) > Close(X()+26) && fabs(SenkouSpanB(X()) - SenkouSpanA(X())) > fabs(SenkouSpanB(X()+26) - SenkouSpanA(X()+26)))
   {  return(true);
   }
   else if(T == POSITION_TYPE_SELL && Close(X()) < Close(X()+26) && fabs(SenkouSpanB(X()) - SenkouSpanA(X())) > fabs(SenkouSpanB(X()+26) - SenkouSpanA(X()+26)))
   {  return(true);
   }
   return(false);
}

Testes executados com o parâmetro de entrada para padrões usados atribuído a 128 nos dão o seguinte:

A espessura da nuvem é vulnerável a sinais falsos em mercados de baixa volatilidade ou laterais. Isso porque a nuvem pode permanecer espessa devido à ação de preço histórica, apesar de tendências fracas predominantes. Isso pode resultar em sinais falsos, já que a espessura da nuvem nem sempre se correlaciona com a força da tendência. A má interpretação disso tende a levar a negociações desnecessárias.

Além disso, abundam os riscos de saídas tardias de operações durante reversões de tendência, porque a espessura da nuvem pode dar uma falsa sensação de segurança, dada sua natureza defasada. Um foco excessivo na espessura da nuvem pode mascarar sinais de alerta precoce, especialmente se outros sinais do Ichimoku, como o movimento do Chikou Span, estiverem em oposição à tendência, indicando possíveis reversões.

Por fim, a subjetividade em definir nuvens “espessas” versus “finas” significa que os traders precisam chegar, de forma independente, a um meio adequado de medir isso que seja respaldado por bons resultados de testes históricos próprios com dados de qualidade e não necessariamente depender de definições de terceiros. Isso é fundamental porque traders com definições diferentes de espessura da nuvem podem interpretar as mesmas condições de mercado de maneiras conflitantes, levando à falta de clareza nos sinais de negociação.

Recuo de Preço a partir do Kijun-sen (Linha-base)

O padrão-8 concentra-se no Kijun-sen, a média de 26 períodos. Por abranger 26 períodos e não 9 como o Tenkan-sen, qualquer ação de preço envolvendo-o torna-se mais significativa, pois não ocorre com frequência, dado o período de média mais longo. Obtemos sinais observando movimentos de recuo do preço Um recuo altista ocorre quando o preço toca o Kijun-sen por cima e recua para cima, sinalizando que a tendência ainda está intacta, apresentando uma potencial entrada de compra. O recuo baixista, por sua vez, ocorre quando o preço toca o Kijun-sen por baixo e recua para baixo, sinalizando a continuidade de uma tendência de queda e uma potencial oportunidade de venda. Implementamos isto da seguinte forma em nossa classe de sinal personalizada:

//+------------------------------------------------------------------+
//| Check for Pattern 8.                                             |
//+------------------------------------------------------------------+
bool CSignalIchimoku::IsPattern_8(ENUM_POSITION_TYPE T)
{  if(T == POSITION_TYPE_BUY && Close(X()+2) >= Kijunsen(X()+1) && Close(X()+1) <= Kijunsen(X()+1) && Close(X()) > Kijunsen(X()))
   {  return(true);
   }
   else if(T == POSITION_TYPE_SELL && Close(X()+2) <= Kijunsen(X()+1) && Close(X()+1) >= Kijunsen(X()+1) && Close(X()) < Kijunsen(X()))
   {  return(true);
   }
   return(false);
}

Se executarmos testes para esse padrão específico atribuindo ao parâmetro de entrada para padrões usados o valor 256, obteremos os seguintes resultados:

Embora o relatório do padrão-8 acima seja ligeiramente promissor, os traders precisam estar atentos à sua inadequação inerente em tendências fortes quando há um breakout, pois isso não produzirá o recuo desejado. Além disso, como sinal de padrão, ele carece de confirmação de que a força do recuo do preço constitui uma tendência principal, motivo pelo qual é uma boa ideia combiná-lo com um dos padrões de crossover, como o padrão-0 acima. Por fim, a dependência do contexto de prazos é outro tema comum nos padrões do Ichimoku e, portanto, os traders devem garantir que este padrão não seja lido com muita frequência em prazos menores, já que um sinal em prazo maior terá mais peso.

Acordo entre Preço e Chikou Span

O padrão-9, que é o nosso 10^{<código omitido>}, considera a ação de preço e o defasado Chikou Span. O Chikou-span, por ser preços de fechamento defasados, exige outro buffer atual além dos preços brutos para que possamos extrair sinais significativos. Portanto, usamos o buffer Tenkan-sen para representar nossa ação de preço atual e buscamos momentos em que ele concorda com o Chikou Span para lermos os sinais. Um sinal altista ocorre se tanto o preço quanto o Chikou Span estiverem acima da nuvem, pois acredita-se que isso fortaleça um sinal de tendência altista. Por outro lado, o sinal baixista ocorreria se tanto o preço quanto o Chikou Span estivessem abaixo da nuvem, confirmando um sinal de baixa. Implementamos isto da seguinte forma:

//+------------------------------------------------------------------+
//| Check for Pattern 9.                                             |
//+------------------------------------------------------------------+
bool CSignalIchimoku::IsPattern_9(ENUM_POSITION_TYPE T)
{  if(T == POSITION_TYPE_BUY  && 
      ((Close(X()) > SenkouSpanA(X()) && ChikouSpan(X()) > SenkouSpanA(X()) && SenkouSpanA(X()) > SenkouSpanB(X()))
      ||
      (Close(X()) > SenkouSpanB(X()) && ChikouSpan(X()) > SenkouSpanB(X()) && SenkouSpanB(X()) > SenkouSpanA(X())))
      )
   {  return(true);
   }
   else if(T == POSITION_TYPE_SELL &&  
      ((Close(X()) < SenkouSpanA(X()) && ChikouSpan(X()) < SenkouSpanA(X()) && SenkouSpanA(X()) < SenkouSpanB(X()))
      ||
      (Close(X()) < SenkouSpanB(X()) && ChikouSpan(X()) < SenkouSpanB(X()) && SenkouSpanB(X()) < SenkouSpanA(X())))
      )
   {  return(true);
   }
   return(false);
}

Uma execução de teste a partir de algumas entradas otimizadas, com o parâmetro de entrada para padrões usados atribuído a 512, nos fornece o seguinte relatório:

Apesar dos resultados animadores acima, os traders precisam estar atentos a inconsistências do padrão-9 em diferentes prazos, a não negligenciar o contexto de mercado ao usar este padrão e à vulnerabilidade a reversões de tendência.

Reentrada na Tendência com base em Tenkan-sen e Kijun-sen

Nosso 11^{<código omitido>} padrão, o padrão-10, combina o crossover que vimos no padrão-0, como um atraso, com o teste da ação de preço na linha Tenkan-sen. Implementamos isto da seguinte forma:

//+------------------------------------------------------------------+
//| Check for Pattern 10.                                             |
//+------------------------------------------------------------------+
bool CSignalIchimoku::IsPattern_10(ENUM_POSITION_TYPE T)
{  if(T == POSITION_TYPE_BUY && Tankensen(X()+3) < Kijunsen(X()+3) && Tankensen(X()+2) > Kijunsen(X()+2) && Tankensen(X()+1) >= Close(X()+1) && Tankensen(X()) < Close(X()))
   {  return(true);
   }
   else if(T == POSITION_TYPE_SELL && Tankensen(X()+3) > Kijunsen(X()+3) && Tankensen(X()+2) < Kijunsen(X()+2) && Tankensen(X()+1) <= Close(X()+1) && Tankensen(X()) > Close(X()))
   {  return(true);
   }
   return(false);
}

A estratégia de negociação é: após um crossover altista Tenkan-sen/Kijun-sen, o preço pode retestar o Kijun-sen, no limite inferior, e então recuar e retomar o movimento ascendente, fornecendo um ponto de reentrada para compradores. Da mesma forma, após um cruzamento invertido com o Tenkan-sen abaixo do Kijun-sen, o preço pode retestar o Kijun-sen por baixo, recuar a partir dele e então retomar sua descida. Testamos apenas esse padrão atribuindo ao parâmetro de entrada de padrões usados o valor 1024 e, em uma das execuções otimizadas favoráveis, nosso relatório é o seguinte:

O padrão-10 tem potencial; entretanto, os traders precisam ficar atentos a sinais falsos em mercados laterais, considerar adequadamente o mercado e o contexto mais amplo ao executar operações e evitar o risco de overtrading, dado o grande número de sinais que esse padrão tende a gerar.

Combinando todos os padrões

É sempre melhor operar com múltiplos padrões somente se as ponderações relativas dos padrões forem atribuídas a partir do próprio conhecimento de sua importância relativa, o que deve vir da experiência. O perigo de otimizar pesos individuais de padrões quando todos são usados é que eles tenderão a encerrar as operações uns dos outros, e assim não seria fácil inferir o desempenho de cada um com base nos pesos atribuídos. Ainda assim, os resultados são apresentados abaixo apenas para ilustrar a diferença de desempenho que se pode obter combinando múltiplos sinais, em vez de usar apenas padrões isolados.

Conclusão

Em conclusão, embora o Ichimoku Kinko Hyo ofereça uma visão abrangente com seus componentes multifacetados e padrões diversos, sua aplicação prática é sutil e exige um entendimento profundo da dinâmica de mercado. Os traders que utilizam a Nuvem de Ichimoku devem estar vigilantes quanto a suas limitações, incluindo potenciais indicadores defasados, suscetibilidade ao ruído de mercado e dependência de sinais adicionais de confirmação para evitar falsos positivos.

Além disso, os diversos padrões do sistema ressaltam a necessidade de combinar múltiplos elementos dentro do Ichimoku, juntamente com técnicas de análise complementares, para aprimorar a precisão na tomada de decisão e minimizar o risco.

Como demonstrado, nenhum padrão isolado garante sucesso; assim, uma abordagem robusta envolve alavancar o conjunto de padrões em alinhamento com contextos e fundamentos de mercado mais amplos. Ao fazer isso, os traders podem aproveitar melhor o poder do Ichimoku Kinko Hyo como uma ferramenta equilibrada em seu arsenal de negociação, navegando estrategicamente nas tendências de mercado para alcançar estratégias de trading informadas e disciplinadas.