MQL5-Assistenten-Techniken, die Sie kennen sollten (Teil 46): Ichimoku

Einführung

Ichimoku Kinko Hyo, oft als Ichimoku-Wolke bezeichnet, ist ein umfassendes technisches Analysesystem, das einen ganzheitlichen Überblick über Markttrends, Unterstützungs- und Widerstandsniveaus sowie das Momentum bietet. Ichimoku Kinko Hyo wurde in den späten 1930er Jahren entwickelt und in den darauffolgenden drei Jahrzehnten verfeinert. Aus dem Japanischen übersetzt bedeutet Ichimoku Kinko Hyo „Chart des Gleichgewichts auf einen Blick“; Namen, die sein Design unterstreichen, um eine einzige, detaillierte Perspektive auf den Markt zu bieten.

Dieser Indikator, der als System dient, besteht aus fünf Linien (oder Puffern) und einem schattierten Bereich, der gewöhnlich Kumo (japanisch für Wolke) genannt wird. Jeder der Puffer soll bestimmte Aspekte des Kursverhaltens erfassen. Es handelt sich dabei um den Tenkan-sen (auch Konversionslinie genannt und dient als kurzfristiger Momentum-Indikator), den Kijun-sen (auch Basislinie genannt und dient als mittelfristiger Trendindikator), Senkou-Spanne A (oder Führender Spanne A) und Senkou-Spanne B (oder Führender Spanne B), die zusammen den Kumo bilden und Unterstützungs- und Widerstandsniveaus in die Zukunft projizieren; und schließlich der Chikou Spanne (oder Nachlaufender Span), der als eine Linie funktioniert, die den Schlusskurs darstellt, rückwärts verschoben, und so einen Blick auf die historische Kursentwicklung im Verhältnis zu den aktuellen Niveaus bietet.

Nachstehend finden Sie die Formeln für jeden dieser 5 Puffer:

wobei:

• H 9 ​ Ist der höchste Stand in den letzten 9 Balken.
• L 9 ist der tiefste Stand der letzten 9 Balken.

Er soll den kurzfristigen Trend widerspiegeln, indem er den höchsten Höchststand und den niedrigsten Tiefststand der letzten 9 Zeiträume mittelt.

wobei:

• H 26 ist der höchste Stand in den letzten 26 Balken.
• L 26 ist der niedrigste Stand in den letzten 26 Balken.

Dies stellt den mittelfristigen Trend dar, wobei eine Spanne von 26 Balken zur Glättung der Kursschwankungen verwendet wird.

wobei:

• Tenkan-sen Ist die oben definierte Konversionslinie.
• Kijun-sen Ist die Basislinie wie oben definiert.

Dieser Puffer wird als Durchschnitt des Tenkan-sen und des Kijun-sen berechnet und 26 Balken in die Zukunft projiziert.

wobei:

• H 52 Ist das höchste Hoch der letzten 52 Balken.
• L 52 ist der tiefste Tief der letzten 52 Balken.

Dabei handelt es sich um den Durchschnitt des höchsten Höchst- und tiefsten Tiefstpreises über 52 Balken, der 26 Balken in die Zukunft projiziert wird. Diese bildet die obere oder untere Grenze der Wolke, je nach ihrer Position im Verhältnis zu Spanne A.

wobei:

• Close t-26 ist der aktuelle Schlusskurs, der um 26 Balken zurückverlegt wurde.

Das bietet einen historischen Kontext, indem der aktuelle Schlusskurs 26 Balken nach dem aktuellen Zeitpunkt anzeigt wird.

Der Kumo (oder die Wolke) wird durch den Bereich zwischen Senkou-Spanne A und Senkou-Spanne B gebildet und dient als Zone zukünftiger Unterstützung und Widerstand. Eine dickere Wolke deutet oft auf eine stärkere Unterstützung/Widerstand hin, während eine dünnere Wolke bedeutet, dass sie leicht durchbrochen werden kann, was auf schwächere Werte hindeutet. Die Farbe der Wolke ist ein weiteres wichtiges Merkmal des Ichimoku, denn wenn die Senkou-Spanne A über der Senkou-Spanne B liegt, zeigt die Wolke in der Regel einen Aufwärtstrend (und wird in der Regel grün schattiert), und wenn die Senkou-Spanne B über der Senkou-Spanne A liegt, zeigt die Wolke einen Abwärtstrend (und wird oft rot schattiert).

Gehen wir nun auf die verschiedenen Muster des Ichimoku ein, wie wir es auch bei anderen Indikatoren in diesen Artikeln getan haben. Wir werden 11 Muster für den Ichimoku überprüfen und wie in den vergangenen Artikeln beginnen wir damit, ein Muster nach dem anderen zu betrachten, wobei wir den Input-Integer „Signal_Ichimoku_PatternsUsed“ verwenden, um zu definieren, welche Muster vom Expert Advisor betrachtet und welche ignoriert werden. Mit dieser Eingabezahl wird zunächst jeweils nur eines der 11 Muster ausgewählt, und nachdem alle Muster unabhängig voneinander getestet wurden, wird eine ideale Kombination dieser Muster gesucht, die die besten Ergebnisse liefert.

Da wir 11 Muster haben, sollte dieser Eingabe-Ganzzahl kein Wert größer als 2¹¹ minus 1 (2047) zugewiesen werden, da diese Ganzzahl in der Lage ist, alle möglichen Musterkombinationen zu erfassen. Wir führen unsere Tests für das Paar GBP JPY auf dem Ein-Stunden-Zeitrahmen für das Jahr 2022 durch. Alle hier vorgestellten Testergebnisse sind lediglich Auszüge aus einigen der fairen Ergebnisse, die durch die Optimierung des Expert Advisors über das kurze Testfenster von 2022 mit GBP JPY erzielt wurden. Es wurden keine Vorwärtstests oder Kreuz-Validierungen durchgeführt, und der beigefügte Code soll mit Hilfe des MQL5-Assistenten in einen Expert Advisor eingebaut werden, für den es hier und hier Richtlinien für neue Leser gibt.

Überkreuzen von Tenkan-Sen und Kijun-Sen

Dies ist wohl das häufigste oder beliebteste Signal unter den Ichimoku-Mustern. Im Wesentlichen handelt es sich um einen einfachen gleitenden Durchschnitt (für schnelle und langsame Periodenlängen), und angesichts der stoischen Eingabeparameter für die Mittelungszeiträume sind viele der Meinung, dass er und dieser Indikator im Allgemeinen nicht empfindlich genug auf wechselnde Marktbedingungen reagieren. Ein Aufwärtssignal liegt jedoch vor, wenn der Tenkan-sen über den Kijun-sen kreuzt, während ein Abwärtsmuster vorliegt, wenn der Tenkan-sen unter den Kijun-sen kreuzt. Wir setzen dies in MQL5 wie folgt um:

//+------------------------------------------------------------------+
//| Check for Pattern 0.                                             |
//+------------------------------------------------------------------+
bool CSignalIchimoku::IsPattern_0(ENUM_POSITION_TYPE T)
{  if(T == POSITION_TYPE_BUY && Tankensen(X()+1) < Kijunsen(X()+1) && Tankensen(X()) > Kijunsen(X()))
   {  return(true);
   }
   else if(T == POSITION_TYPE_SELL && Tankensen(X()+1) > Kijunsen(X()+1) && Tankensen(X()) < Kijunsen(X()))
   {  return(true);
   }
   return(false);
}

Die Testläufe für GBP JPY auf der 1-Stunden-Linie im Jahr 2022 zeigen folgende Ergebnisse:

Dieses Kreuzen ist jedoch anfällig für das Rauschen im Markt, da er auf geringfügige Schwankungen stark reagieren kann, insbesondere bei niedrigeren Zeitrahmen. Diese Überempfindlichkeit kann dann zu Fehlsignalen führen, bei denen es zu Überkreuzungen kommt, ohne dass sich ein signifikanter Trendwechsel vollzieht, was dazu führt, dass eröffnete Positionen in unruhigen oder sich konsolidierenden Märkten häufig „Whipsaws“ (Schaukelbewegungen) erleben.

Dies bedeutet, dass Pattern_0 (Muster 0) in schwankungsbehafteten Märkten nur begrenzt wirksam sein kann, da die Kreuzungsmethode am besten für trendbestimmte Märkte geeignet ist. In schwankungsbehafteten oder seitwärts tendierenden Märkten kann häufiges Kreuzen Händler in die Irre führen und zu Ein- und Ausstiegen führen, denen es an Richtung oder Konsistenz fehlt. Ohne einen eindeutigen Trend können daher Überkreuzungen zwischen Tenkan-sen und Kijun-sen zu erhöhten Transaktionskosten und potenziellen Verlusten durch den Abschluss unproduktiver Handelsgeschäften führen.

Das Signal von Preis vs. Kijun-Sen (Basislinie)

Unser Muster Pattern_0 ist ähnlich wie Pattern_0 ein Kreuzen von Preis und gleitenden Durchschnitten, wenn wir das obige Muster Pattern_0 als einfaches Kreuzen der gleitenden Durchschnitte betrachten würden. Der Kijun-sen betrachtet einen etwas längeren Zeitraum als der Tenkan-sen, sodass die von ihm registrierten Kursübergänge oft von Bedeutung sind. Bei einem Aufwärtssignal kreuzt der Preis von unten nach oben, um darüber zu schließen, und bei einem Abwärtssignal kreuzt er umgekehrt von oben nach unten. Wir implementieren dies wie folgt in MQL5:

//+------------------------------------------------------------------+
//| Check for Pattern 1.                                             |
//+------------------------------------------------------------------+
bool CSignalIchimoku::IsPattern_1(ENUM_POSITION_TYPE T)
{  if(T == POSITION_TYPE_BUY && Close(X()+1) < Kijunsen(X()+1) && Close(X()) > Kijunsen(X()))
   {  return(true);
   }
   else if(T == POSITION_TYPE_SELL && Close(X()+1) > Kijunsen(X()+1) && Close(X()) < Kijunsen(X()))
   {  return(true);
   }
   return(false);
}

Testläufe mit ähnlichen Einstellungen wie oben nach einem kurzen Optimierungslauf, wobei die Eingabe für die verwendeten Muster auf 2 gesetzt wurde, ergeben folgende Ergebnisse:

Auch wenn das Muster 1 in diesem Testlauf vielversprechend ist, birgt es einige Fallstricke, die Händler beachten sollten. Erstens spiegelt der Kijun-sen den Durchschnittspreis über 26 Balken wider, gibt aber keine Hinweise auf die Trenddynamik oder Trendstärke. Dies bedeutet in der Regel, dass Händler, die sich ausschließlich auf dieses Signal verlassen, Hinweise auf eine nachlassende Dynamik übersehen könnten, was zu Verlusten bei offenen Positionen führen könnte, sollte der Trend umkehren oder in eine Konsolidierung übergehen.

Darüber hinaus liefert dieses Muster keine Hinweise auf Ausstiegssignale oder, was noch wichtiger ist, auf Kursziele. Der Kijun-sen kann zwar „findig“ sein, wenn es darum geht, vorherrschende Trends zu markieren, aber er hilft nicht, wenn es darum geht, Take-Profit- oder sogar Stop-Loss-Niveaus zu definieren, was für Händler, die sich nur auf dieses Muster verlassen, ein Problem darstellen kann.

Kumo (Wolke) Ausbruch

Ähnlich wie das Kreuzen, das wir in Pattern_0 betrachtet haben, ist die Wolke, Kumo, ein wichtiger Indikator und eine Quelle für Muster innerhalb des Ichimoku. Er erstreckt sich zwischen den beiden Senkou-Spanne und ist vor allem deshalb so wichtig, weil er mit Unterstützung und Widerstand in Verbindung gebracht wird. Ein zinsbullisches Signal wird hier als Ausbruch definiert, wenn der Kurs die Wolke durchbricht und über ihr schließen kann. Ein rückläufiges Signal wäre das Gegenteil, wenn der Kurs durch die Wolke fällt und dort nach einem Schlusskurs verbleibt. Wir zeigen dies im Code wie folgt:

//+------------------------------------------------------------------+
//| Check for Pattern 2.                                             |
//+------------------------------------------------------------------+
bool CSignalIchimoku::IsPattern_2(ENUM_POSITION_TYPE T)
{  if(T == POSITION_TYPE_BUY && 
      ((Close(X()+1) < SenkouSpanA(X()+1) && Close(X()) > SenkouSpanA(X()) && SenkouSpanA(X()) > SenkouSpanB(X()))
      ||
      (Close(X()+1) < SenkouSpanB(X()+1) && Close(X()) > SenkouSpanB(X()) && SenkouSpanB(X()) > SenkouSpanA(X())))
      )
   {  return(true);
   }
   else if(T == POSITION_TYPE_SELL &&
      ((Close(X()+1) > SenkouSpanA(X()+1) && Close(X()) < SenkouSpanA(X()) && SenkouSpanA(X()) < SenkouSpanB(X()))
      ||
      (Close(X()+1) > SenkouSpanB(X()+1) && Close(X()) < SenkouSpanB(X()) && SenkouSpanB(X()) < SenkouSpanA(X())))
      )
   {  return(true);
   }
   return(false);
}

Testläufe mit ähnlichen Einstellungen wie oben, aber mit Schwerpunkt auf Muster 2, indem die verwendeten Muster der Eingabe 4 zugewiesen werden, führen zu folgenden Ergebnissen:

Pattern_2 bietet zwar auch interessante Berichtsergebnisse, wie wir oben sehen können, ist aber sehr empfindlich gegenüber Zeitrahmen. Dies ist besonders wichtig, weil Ausbrüche bei kürzeren Zeitrahmen anfälliger für Marktstörungen und vorübergehende Kursschwankungen sind, was zu häufigen Fehlsignalen führen kann. Umgekehrt kommt es bei den größeren Zeitrahmen leider oft vor, dass das Ausbruchssignal verzögert wird und der ideale Einstiegspunkt verpasst wird.

Pattern_2 muss außerdem vom Kontext eines Trends abhängen, um bestätigt zu werden. Denn damit ein Kumo-Ausbruch zuverlässig ist, sollte er mit dem breiteren Trend übereinstimmen, wie er von anderen Ichimoku-Komponenten, z. B. der nachlaufenden Linie (Lagging Line), sowie den relativen Positionen der Basislinie (baseline) und der Umkehrlinie (Conversion Line) angezeigt wird. Dies führt zu einem weiteren Schwachpunkt, der sich zwar durch alle Indikatoren zieht, aber dennoch erwähnenswert ist. Übersehen von Grundlagen des Marktes Händler, die sich ausschließlich auf den Kumo-Durchbruch verlassen, könnten wichtige Marktzusammenhänge übersehen.

Kumo Twist (Umkehr der Wolke)

Die Wolkenumkehr (Kumo Twist) ist unser Muster 3 und entsteht dadurch, dass die Wolke die Farbe wechselt oder Senkou-Spanne A und Senkou-Spanne B die Plätze tauschen. Da diese beiden auch als gleitende Durchschnitte fungieren, handelt es sich um eine weitere Überkreuzung, wenn auch mit einem verzögerten Effekt. Ein Aufwärtssignal liegt also vor, wenn die Senkou-Spanne A (der „kürzere“ Balkenpuffer) die Senkou-Spanne B von unten nach oben kreuzt und über ihr schließt. Dies wird auch als aufwärts Kumo Twist bezeichnet, die einen potenziellen künftigen Aufwärtstrend signalisiert. Ein Abwärtssignal liegt vor, wenn er von oben nach unten kreuzt, was auch als abwärts Kumo-Umkehr bezeichnet wird. So setzen wir dies im Code um:

//+------------------------------------------------------------------+
//| Check for Pattern 3.                                             |
//+------------------------------------------------------------------+
bool CSignalIchimoku::IsPattern_3(ENUM_POSITION_TYPE T)
{  if(T == POSITION_TYPE_BUY && SenkouSpanA(X()+1) < SenkouSpanB(X()+1) && SenkouSpanA(X()) > SenkouSpanB(X()))
   {  return(true);
   }
   else if(T == POSITION_TYPE_SELL && SenkouSpanA(X()+1) > SenkouSpanB(X()+1) && SenkouSpanA(X()) < SenkouSpanB(X()))
   {  return(true);
   }
   return(false);
}

Ein Test auf GBP JPY für das Jahr 2022 auf der 1-Stunden-Linie wie oben zeigt uns folgende Ergebnisse:

Pattern_3 hat jedoch seine Tücken, und die wichtigste davon ist die Fehlinterpretation der Wolkendicke. Für viele Händler ist die Kumo-Umkehr oft mit der Wolkendicke verbunden, wobei die Wolkendicke auf stärkere Trends hindeutet. Die Beurteilung dieser Stärke erfordert jedoch Erfahrung und einen angemessenen Marktkontext, da eine Wolkenumkehr oft leicht wieder rückgängig gemacht werden kann, insbesondere wenn es um unruhige Märkte geht.

Dieses Muster, wie auch andere, die wir oben gesehen haben, gibt wenig Aufschluss über Trendstärke oder Dynamik. Dies macht es schwierig zu bestimmen, ob eine Umkehr von Dauer sein wird. Dies birgt das Risiko, in schwindende oder auslaufende Handelsgeschäfte einzusteigen. Dies unterstreicht noch einmal, wie wichtig es ist, sich auf einen breiteren Ichimoku-Kontext zu verlassen, da die Kumo-Umkehr idealerweise durch andere Ichimoku-Elemente wie das Kreuzen von Tenkan-sen und Kijun-sen oder die Chikou-Spanne bestätigt werden sollte. Verlässt man sich allein auf die Umkehr ohne diese Bestätigungen, kann dies zu falschen Signalen führen. Händler, die nicht das komplette Ichimoku-System berücksichtigen, könnten die Drehungen falsch interpretieren. Deshalb stellen wir diese Muster nicht einzeln vor, sondern als Ensemble, aus dem Händler das auswählen können, was für ihre Setups am besten geeignet ist.

Bestätigung durch die Chikou-Spanne (nachlaufende Linie)

die Chikou-Spanne ist ein nachlaufender Puffer, und während die Verwendung in einem Chart beim manuellen Handel einfach sein kann, muss man beim Einlesen in den Code sicherstellen, dass die Indizierung richtig versetzt ist. Wir würden ein Aufwärtssignal erhalten, wenn die Chikou-Spanne oberhalb des Kurses kreuzt, was ein Aufwärtsmomentum bestätigen und die Kaufempfehlung verstärken würde. Auf der anderen Seite wäre es ein Abwärtssignal, wenn die Chikou-Spanne unter dem Kursverlauf kreuzt und damit ein Abwärtsmomentum und eine Bestätigung des Verkaufssignals signalisiert. Wir kodieren dies wie folgt:

//+------------------------------------------------------------------+
//| Check for Pattern 4.                                             |
//+------------------------------------------------------------------+
bool CSignalIchimoku::IsPattern_4(ENUM_POSITION_TYPE T)
{  if(T == POSITION_TYPE_BUY && ChikouSpan(X()+1) <= Tankensen(X()+1) && ChikouSpan(X()) > Tankensen(X()))
   {  return(true);
   }
   else if(T == POSITION_TYPE_SELL && ChikouSpan(X()+1) >= Tankensen(X()+1) && ChikouSpan(X()) < Tankensen(X()))
   {  return(true);
   }
   return(false);
}

Ein Test mit den gleichen Einstellungen wie bei den anderen Mustern führt zu folgenden Ergebnissen:

Die Gefahr, dass man sich zu sehr darauf verlässt und andere wichtige Signale ignoriert, ist eine Falle für Pattern_4. Wie bei den anderen oben genannten Mustern ist auch hier zu beachten, dass die Chikou-Spanne im Idealfall ein Bestätigungssignal ist, wie der Titel des Musters andeutet, sodass eine Kombination mit dem Kumo-Durchbruch oder dem Kreuzen von Tenkan-sen und Kijun-sen geeignet wäre. Wenn man sich nur darauf konzentriert, kann dies zu einem unvollständigen Verständnis der Marktdynamik führen. Dies wirkt sich auch auf andere bereits erwähnte Schwächen aus, die auf fundamental getriebenen Märkten nur von begrenzter Relevanz sind, sowie auf das Risiko, dass der breitere Marktkontext und andere Faktoren nicht berücksichtigt werden.

Kumo als Unterstützung und Widerstand

Der Kumo kann nicht nur als Durchbruchsschwelle dienen, sondern auch als eine Art dynamische Unterstützung oder Widerstand, der ein von Pattern_2 getrenntes Muster definieren kann, das wir als Pattern_5 bezeichnen. Die Handelsstrategie geht daher von einem Aufwärts-Rückprall aus, wenn der Kurs auf die Wolke zurückfällt, diese aber nicht durchbricht, wobei die Wolke als Unterstützung dient, die als Einstiegspunkt zum Kaufen genutzt werden kann. Der Abwärts-Rückprall wird registriert, wenn der Kurs in die Wolke hinein steigt, aber nicht darüber ausbricht, wobei die Wolke als Widerstand wirkt und somit eine potenzielle Verkaufsmöglichkeit signalisiert. Die Codierung von Pattern_5 lautet wie folgt:

//+------------------------------------------------------------------+
//| Check for Pattern 5.                                             |
//+------------------------------------------------------------------+
bool CSignalIchimoku::IsPattern_5(ENUM_POSITION_TYPE T)
{  if(T == POSITION_TYPE_BUY && 
      ((Close(X()+2) > SenkouSpanA(X()+2) && Close(X()+1) < SenkouSpanA(X()+1) && Close(X()) > SenkouSpanA(X()) && SenkouSpanA(X()) > SenkouSpanB(X()))
      ||
      (Close(X()+2) > SenkouSpanA(X()+2) && Close(X()+1) < SenkouSpanB(X()+1) && Close(X()) > SenkouSpanB(X()) && SenkouSpanB(X()) > SenkouSpanA(X())))
      )
   {  return(true);
   }
   else if(T == POSITION_TYPE_SELL &&
      ((Close(X()+2) < SenkouSpanA(X()+2) && Close(X()+1) > SenkouSpanA(X()+1) && Close(X()) < SenkouSpanA(X()) && SenkouSpanA(X()) < SenkouSpanB(X()))
      ||
      (Close(X()+2) < SenkouSpanA(X()+2) && Close(X()+1) > SenkouSpanB(X()+1) && Close(X()) < SenkouSpanB(X()) && SenkouSpanB(X()) < SenkouSpanA(X())))
      )
   {  return(true);
   }
   return(false);
}

Testläufe, bei denen der Eingabe für die verwendeten Muster der Wert 32 zugewiesen wird, was sicherstellt, dass nur dieses Muster und keines der anderen 10 Muster getestet wird, führen zu den folgenden Ergebnissen:

Muster 5, bei dem Kumo als Unterstützung/Widerstand fungiert, leidet unter einer verzögerten Reaktion bei der Erkennung von einer Trendumkehr. Dies liegt daran, dass Kumo aufgrund seiner Berechnung (von 26 nach vorne verschobenen Balken) dem aktuellen Kursgeschehen hinterherhinkt, was im Vergleich zu alternativen Echtzeit-Unterstützungs-/Widerstandsindikatoren zu verzögerten Signalen führt. Diese Verzögerungen können dazu führen, dass Händler zu spät einsteigen, was die Effektivität des Indikators als Unterstützung/Widerstand verringert, insbesondere auf schnelllebigen Märkten.

Auch bei Muster 5 ist es schwierig, die Werte genau zu bestimmen. Im Gegensatz zu traditionellen Unterstützungs- und Widerstandslinien ist die Kumo-Wolke eher eine Zone als ein bestimmtes Kursniveau. Dies erschwert die Ermittlung der genauen Ein- und Ausstiegspunkte ein wenig. Diese Mehrdeutigkeit könnte das Handelsmanagement erschweren, da die Festlegung genauer Stop-Loss- oder Take-Profit-Levels innerhalb der Cloud schwierig sein kann.

Schließlich kann dieses Muster in Märkten mit starkem Trend unzuverlässig sein, da die Kurse den Kumo leicht und ohne großes Zögern durchbrechen. Dies macht ihn weniger zu einem zuverlässigen Indikator für Unterstützung oder Widerstand als vielmehr zu einem Preispuffer. Dies könnte zu verpassten Gelegenheiten führen, wenn sich Händler bei ihren Handelsentscheidungen ausschließlich auf diese Daten verlassen.

Ein Starkes Kreuzen (über oder unter Kumo)

Unser Pattern_6 greift das alles entscheidende und verankernde Muster des Ichimoku, Pattern_0, wieder auf, indem es einen Filter hinzufügt, der die relative Position des Kumo zum sich kreuzenden Tenkan-sen und Kijun-sen berücksichtigt. Diese beiden können sich jederzeit überkreuzen; es wird jedoch argumentiert, dass die Kopplung jeder Überkreuzung mit einer bestimmten Kumo-Positionierung ein noch stärkeres Signal ergibt. Das Aufwärtssignal hierfür wäre gekennzeichnet, wenn das Aufwärtskreuzen von Tenkan-sen/Kijun-sen oberhalb der Wolke auftritt, was, wie bereits betont, ein starkes Kaufsignal darstellen würde. Ein starkes Abwärtssignal würde sich ergeben, wenn das Abwärtskreuzen von Tenkan-sen/Kijun-sen unterhalb der Wolke auftritt. Dieses Signal bedeutet, dass ein Kreuzen innerhalb der Wolke aufgrund der Unentschlossenheit des Marktes weniger stark ist. Wir codieren Pattern_6 wie folgt:

//+------------------------------------------------------------------+
//| Check for Pattern 6.                                             |
//+------------------------------------------------------------------+
bool CSignalIchimoku::IsPattern_6(ENUM_POSITION_TYPE T)
{  if(T == POSITION_TYPE_BUY  && Tankensen(X()+1) < Kijunsen(X()+1) && Tankensen(X()) > Kijunsen(X()) &&
      ((Tankensen(X()) > SenkouSpanA(X()) && SenkouSpanA(X()) > SenkouSpanB(X()))
      ||
      (Tankensen(X()) > SenkouSpanB(X()) && SenkouSpanB(X()) > SenkouSpanA(X())))
      )
   {  return(true);
   }
   else if(T == POSITION_TYPE_SELL && Tankensen(X()+1) > Kijunsen(X()+1) && Tankensen(X()) < Kijunsen(X()) &&
      ((Tankensen(X()) < SenkouSpanA(X()) && SenkouSpanA(X()) < SenkouSpanB(X()))
      ||
      (Tankensen(X()) < SenkouSpanB(X()) && SenkouSpanB(X()) < SenkouSpanA(X())))
      )
   {  return(true);
   }
   return(false);
}

Ein Test mit ähnlichen Einstellungen des Strategietesters wie oben, bei dem der Eingabeparameter für die verwendeten Muster auf 64 gesetzt wurde, ergibt folgende Ergebnisse:

Trotz unseres obigen Musters-6-Berichts neigen Kumo-Kreuze dazu, sich stark zu verzögern. Ein starkes Kreuzen über oder unter Kumo tritt in der Regel auf, nachdem bereits ein signifikanter Trendwechsel stattgefunden hat, und dies kann zu möglichen Verzögerungen beim Ein- oder Ausstieg führen. Händler, die sich ausschließlich auf Kumo-Kreuze verlassen, könnten daher zu spät einsteigen und die ersten profitableren Teile des Trends verpassen.

Es besteht auch eine Anfälligkeit für Umschwünge auf volatilen Märkten. Der Grund dafür ist, dass auf sehr volatilen oder von Nachrichten bestimmten Märkten ein starkes Kreuz schnell die Richtung ändern kann und Händler, die allein aufgrund dieses Kreuzes einsteigen, in eine Falle geraten. Diese plötzlichen Umschwünge können daher zu erheblichen Verlusten führen, insbesondere wenn Händler den Trend nicht durch andere Indikatoren bestätigen können.

Schließlich, und dies könnte als ein Thema für den Ichimoku angesehen werden, führen häufige Kursbewegungen in Märkten, die sich in einer Bandbreite bewegen, zwangsläufig zu einer Vielzahl von Fehlsignalen, da die Kurse ohne klare Richtung um den Kumo oszillieren.

Trendstärke über die Dicke der Wolke

Ein weiteres Muster innerhalb von Ichimoku, das für Kauf- und Verkaufsentscheidungen genutzt werden kann, ist die Kumo-Dicke. Ein dünner Kumo deutet auf eine schwache Unterstützung oder einen schwachen Widerstand hin, was zu Ausbrüchen oder Umkehrungen führen kann, während ein dicker Kumo eine starke Unterstützung oder einen starken Widerstand anzeigt und die Fortsetzung des aktuellen Trends signalisieren kann. Um dies anzuwenden, definieren wir unser Aufwärtssignal als Aufwärtstrend über einen Zeitraum von etwa 26 Balken, der auch durch eine Zunahme der Wolkendicke gekennzeichnet ist. Umgekehrt wird das Abwärtssignal ein Abwärtstrend über einen ähnlichen Zeitraum sein, der auch durch sich verdichtende Wolken in diesem Zeitraum gekennzeichnet ist. Wir setzen dies wie folgt um:

//+------------------------------------------------------------------+
//| Check for Pattern 7.                                             |
//+------------------------------------------------------------------+
bool CSignalIchimoku::IsPattern_7(ENUM_POSITION_TYPE T)
{  if(T == POSITION_TYPE_BUY && Close(X()) > Close(X()+26) && fabs(SenkouSpanB(X()) - SenkouSpanA(X())) > fabs(SenkouSpanB(X()+26) - SenkouSpanA(X()+26)))
   {  return(true);
   }
   else if(T == POSITION_TYPE_SELL && Close(X()) < Close(X()+26) && fabs(SenkouSpanB(X()) - SenkouSpanA(X())) > fabs(SenkouSpanB(X()+26) - SenkouSpanA(X()+26)))
   {  return(true);
   }
   return(false);
}

Testläufe, bei denen die Eingabe für die verwendeten Muster auf 128 gesetzt wird, ergeben folgendes Ergebnis:

Die Dicke der Wolke ist anfällig für Fehlsignale bei geringer Volatilität oder bei Märkten mit Seitwärtsbewegungen. Dies liegt daran, dass die Wolke aufgrund der historischen Kursentwicklung trotz der vorherrschenden schwachen Trends dicht bleiben kann. Dies kann daher zu falschen Signalen führen, da die Dicke der Wolke nicht immer mit der Trendstärke korreliert. Eine Fehlinterpretation dieser Tatsache führt zwangsläufig zu unnötigen Handelsgeschäften.

Außerdem besteht das Risiko, bei einer Trendumkehr zu spät aus dem Handel auszusteigen, da die Wolkendichte aufgrund ihrer zeitlichen Verzögerung ein falsches Gefühl der Sicherheit vermitteln kann. Ein übermäßiger Fokus auf die Wolkendicke könnte Frühwarnsignale überdecken, insbesondere wenn andere Ichimoku-Signale, wie die Chikou-Spanne, sich gegen den Trend bewegen und auf mögliche Umkehrungen hinweisen.

Schließlich bedeutet die Subjektivität bei der Definition von „dicken“ und „dünnen“ Wolken, dass Händler unabhängig voneinander ein geeignetes Mittel zur Messung finden müssen, das durch die eigenen anständigen historischen Testergebnisse mit Qualitätsdaten gestützt wird, und sich nicht unbedingt auf die Definitionen anderer verlassen sollten. Dies ist von entscheidender Bedeutung, da Händler mit unterschiedlichen Definitionen der Wolkendicke dieselben Marktbedingungen auf widersprüchliche Weise interpretieren können, was zu einer mangelnden Klarheit der Handelssignale führt.

Kurserholung von Kijun-sen (Basiswert)

Pattern_8 konzentriert sich auf den Kijun-sen, den 26-Balken-Durchschnitt. Da er sich über 26 Balken erstreckt und nicht wie der Tenkan-sen über 9 Balken, ist jede Kursbewegung, die ihn betrifft, von größerer Bedeutung, da sie angesichts des längeren Durchschnitts nicht oft vorkommt. Wir erhalten Signale, indem wir auf eine Kurserholung achten. Ein Aufwärtsabprall liegt vor, wenn der Kurs Kijun-sen von oben berührt und nach oben abprallt. Ein Abwärtsabprall liegt hingegen vor, wenn der Kurs Kijun-sen von unten berührt und nach unten abprallt, was die Fortsetzung eines Abwärtstrends und eine potenzielle Verkaufsmöglichkeit signalisiert. Wir implementieren dies wie folgt in unserer nutzerdefinierten Signalklasse:

//+------------------------------------------------------------------+
//| Check for Pattern 8.                                             |
//+------------------------------------------------------------------+
bool CSignalIchimoku::IsPattern_8(ENUM_POSITION_TYPE T)
{  if(T == POSITION_TYPE_BUY && Close(X()+2) >= Kijunsen(X()+1) && Close(X()+1) <= Kijunsen(X()+1) && Close(X()) > Kijunsen(X()))
   {  return(true);
   }
   else if(T == POSITION_TYPE_SELL && Close(X()+2) <= Kijunsen(X()+1) && Close(X()+1) >= Kijunsen(X()+1) && Close(X()) < Kijunsen(X()))
   {  return(true);
   }
   return(false);
}

Wenn wir Testläufe für dieses spezielle Muster durchführen, indem wir den Eingabeparameter für die verwendeten Muster auf 256 setzen, erhalten wir die folgenden Ergebnisse:

Auch wenn der obige Bericht von Pattern_8 etwas vielversprechend ist, müssen sich Händler vor seiner inhärenten Unzulänglichkeit bei starken Trends in Acht nehmen, wenn es zu einem Ausbruch kommt, da dies nicht zu der gewünschten Erholung führen wird. Außerdem fehlt ihm als Signalmuster die Bestätigung, dass die Stärke der Kurserholung einen Haupttrend darstellt, weshalb es eine gute Idee ist, es mit einem der Kreuzungsmuster wie dem obigen Pattern_0 zu kombinieren. Schließlich ist die Kontextabhängigkeit von den Zeitrahmen ein weiteres gemeinsames Thema mit Ichimoku-Mustern. Händler sollten daher sicherstellen, dass dieses Muster nicht zu sehr von kleineren Zeitrahmen abgelesen wird, da ein Signal mit einem größeren Zeitrahmen mehr Gewicht hat.

Übereinstimmung von Preis und Chikou-Spanne

Muster 9, unser zehntes Muster, berücksichtigt die Kursentwicklung und die nachlaufende Chikou-Spanne. Da die Chikou-Spanne den Schlusskursen hinterherhinkt, ist neben den Rohpreisen ein weiterer aktueller Puffer erforderlich, um aussagekräftige Signale zu erhalten. Wir verwenden daher den Tenkan-sen-Puffer, um unsere aktuelle Kursbewegung darzustellen, und suchen nach Zeitpunkten, an denen er mit der Chikou-Spanne übereinstimmt, um Signale abzulesen. Ein Aufwärtssignal liegt vor, wenn sowohl der Kurs als auch die Chikou-Spanne oberhalb der Wolke liegen, da dies als Verstärkung eines Aufwärtstrends gilt. Umgekehrt wäre ein Abwärtssignal, wenn sowohl der Kurs als auch die Chikou-Spanne unter der Wolke liegen würden, was ein Abwärtssignal bestätigen würde. Wir setzen dies wie folgt um:

//+------------------------------------------------------------------+
//| Check for Pattern 9.                                             |
//+------------------------------------------------------------------+
bool CSignalIchimoku::IsPattern_9(ENUM_POSITION_TYPE T)
{  if(T == POSITION_TYPE_BUY  && 
      ((Close(X()) > SenkouSpanA(X()) && ChikouSpan(X()) > SenkouSpanA(X()) && SenkouSpanA(X()) > SenkouSpanB(X()))
      ||
      (Close(X()) > SenkouSpanB(X()) && ChikouSpan(X()) > SenkouSpanB(X()) && SenkouSpanB(X()) > SenkouSpanA(X())))
      )
   {  return(true);
   }
   else if(T == POSITION_TYPE_SELL &&  
      ((Close(X()) < SenkouSpanA(X()) && ChikouSpan(X()) < SenkouSpanA(X()) && SenkouSpanA(X()) < SenkouSpanB(X()))
      ||
      (Close(X()) < SenkouSpanB(X()) && ChikouSpan(X()) < SenkouSpanB(X()) && SenkouSpanB(X()) < SenkouSpanA(X())))
      )
   {  return(true);
   }
   return(false);
}

Ein Testlauf mit einigen der optimierten Eingaben, bei dem die Eingabeparameter für die verwendeten Muster auf 512 gesetzt wurden, ergibt folgendes Ergebnis:

Trotz unserer rosigen Ergebnisse oben müssen Händler auf Unstimmigkeiten bei Muster 9 über verschiedene Zeitrahmen hinweg achten, den Marktkontext nicht vernachlässigen, wenn sie dieses Muster verwenden, und die Anfälligkeit für Trendumkehrungen beachten.

Wiedereinstieg des Trends auf Basis von Tenkan-sen und Kijun-sen

Unser elftes Muster, Pattern_10, kombiniert die Kreuzung, die wir in Pattern_0 gesehen haben, als Verzögerung mit dem Testen der Tenkan-Sen-Linie durch die Kursbewegung. Wir setzen dies wie folgt um:

//+------------------------------------------------------------------+
//| Check for Pattern 10.                                             |
//+------------------------------------------------------------------+
bool CSignalIchimoku::IsPattern_10(ENUM_POSITION_TYPE T)
{  if(T == POSITION_TYPE_BUY && Tankensen(X()+3) < Kijunsen(X()+3) && Tankensen(X()+2) > Kijunsen(X()+2) && Tankensen(X()+1) >= Close(X()+1) && Tankensen(X()) < Close(X()))
   {  return(true);
   }
   else if(T == POSITION_TYPE_SELL && Tankensen(X()+3) > Kijunsen(X()+3) && Tankensen(X()+2) < Kijunsen(X()+2) && Tankensen(X()+1) <= Close(X()+1) && Tankensen(X()) > Close(X()))
   {  return(true);
   }
   return(false);
}

Die Handelsstrategie besteht darin, dass der Kurs nach einem Aufwärtskreuz von Tenkan-sen/Kijun-sen den Kijun-sen an der unteren Grenze erneut testen könnte, um dann abzuprallen und die Aufwärtsbewegung fortzusetzen, was einen Wiedereinstiegspunkt für Käufer darstellen würde. In ähnlicher Weise kann der Kurs nach einem Kursrutsch, bei dem der Tenkan-Sen unter dem Kijun-Sen liegt, den Kijun-Sen erneut von unten testen, von ihm abprallen und dann seinen Abstieg fortsetzen. Wir testen genau dieses Muster, indem wir dem Eingabeparameter der verwendeten Muster den Wert 1024 zuweisen, und in einem der günstigen optimierten Läufe lautet unser Bericht wie folgt:

Das Muster 10 hat Potenzial, aber Händler müssen auf falsche Signale in Seitwärtsmärkten achten, den breiteren Markt und den Kontext bei der Ausführung von Handelsgeschäften angemessen berücksichtigen und das Risiko eines übermäßigen Handels angesichts der vielen Signale, die dieses Muster zwangsläufig erzeugt, vermeiden.

Kombinieren aller Muster

Es ist immer besser, mit mehreren Mustern zu handeln, wenn die relative Gewichtung der Muster auf der Grundlage des eigenen Wissens über ihre relative Bedeutung erfolgt, das aus der Erfahrung stammen sollte. Die Gefahr bei der Optimierung einzelner Mustergewichte besteht darin, dass sie dazu neigen, die Handelsgeschäfte der anderen zu schließen, sodass es nicht einfach wäre, anhand der zugewiesenen Gewichte auf die Leistung der einzelnen Muster zu schließen. Nichtsdestotrotz werden die Ergebnisse im Folgenden nur dargestellt, um den Leistungsunterschied zu verdeutlichen, der sich aus der Kombination mehrerer Signale ergibt, anstatt nur einzelne Muster zu verwenden.

Schlussfolgerung

Zusammenfassend lässt sich sagen, dass der Ichimoku Kinko Hyo mit seinen vielfältigen Komponenten und unterschiedlichen Mustern zwar einen umfassenden Überblick bietet, seine praktische Anwendung jedoch nuanciert bleibt und ein tiefes Verständnis der Marktdynamik erfordert. Händler, die die Ichimoku-Wolke verwenden, müssen sich über ihre Grenzen im Klaren sein, einschließlich potenzieller nachlaufender Indikatoren, der Anfälligkeit für Marktstörungen und der Abhängigkeit von zusätzlichen Bestätigungssignalen, um falsch positive Ergebnisse zu vermeiden.

Darüber hinaus unterstreichen die verschiedenen Muster des Systems die Notwendigkeit, mehrere Elemente innerhalb von Ichimoku mit ergänzenden Analysetechniken zu kombinieren, um die Entscheidungsgenauigkeit zu erhöhen und das Risiko zu minimieren.

Wie gezeigt, ist kein einzelnes Muster ein Garant für Erfolg. Ein solider Ansatz besteht daher darin, die Gesamtheit der Muster in Übereinstimmung mit dem breiteren Marktkontext und den Fundamentaldaten zu nutzen. Auf diese Weise können Händler die Macht des Ichimoku Kinko Hyo als ausgewogenes Instrument in ihrem Handelsarsenal besser nutzen und Markttrends strategisch steuern, um informierte und disziplinierte Handelsstrategien zu erreichen.