Возможности Мастера MQL5, которые вам нужно знать (Часть 46): Ишимоку

Введение

Ichimoku Kinko Hyo, который часто называют облако Ишимоку (Ichimoku Cloud) - это всеобъемлющая система технического анализа, призванная обеспечить целостное представление о рыночных трендах, уровнях поддержки и сопротивления, а также импульсе. Разработанный в конце 1930-х годов и совершенствовавшийся в течение последующих трех десятилетий, Ichimoku Kinko Hyo переводится с японского как "мгновенный взгляд на баланс". Это название подчеркивают его предназначение — предлагать единую, подробную перспективу рынка.

Индикатор состоит из пяти линий (или буферов) и затененной области, обычно называемой Кумо (облако). Каждый из буферов предназначен для отражения определенных аспектов поведения цены. Это Tenkan-sen (Conversion Line или индикатор краткосрочного импульса); Kijun-sen (базовая линия или индикатор среднесрочного тренда); Senkou Span A (или Leading Span A) и Senkou Span B (или Leading Span B), которые вместе образуют Кумо, проецируя уровни поддержки и сопротивления в будущее; и, наконец, Chikou Span (или Lagging Span), который работает как линия, отображающая цену закрытия, смещенную назад, тем самым предлагая взгляд на поведение цены в истории по отношению к текущим уровням.

Ниже приведены формулы для каждого из этих 5 буферов:

где:

• H 9 ​- самый высокий максимум за последние 9 периодов.
• L 9 - самый низкий минимум за последние 9 периодов.

Эти значения призваны отразить краткосрочную тенденцию путем усреднения самого высокого максимума и самого низкого минимума за последние 9 периодов.

где:

• H 26 - самый высокий максимум за последние 26 периодов.
• L 26 - самый низкий минимум за последние 26 периодов.

Эти значения отражают среднесрочную тенденцию, использующую 26-периодный диапазон для сглаживания колебаний цен.

где:

• Tenkan-sen — это линия преобразования.
• Kijun-sen — базовая линия.

Буфер рассчитывается как среднее значение Tenkan-sen и Kijun-sen и прогнозируется на 26 периодов вперед.

где:

• H 52 - самый высокий максимум за последние 52 периода.
• L 52 - самый низкий минимум за последние 52 периода.

Среднее значение самой высокой максимальной и самой низкой минимальной цены за 52 периода, спроецированное на 26 периодов вперед. Оно формирует верхнюю или нижнюю границу облака в зависимости от его положения относительно диапазона А (Span A).

где:

• Close t−26 - текущая цена закрытия, сдвинутая на 26 периодов назад.

Представляет исторический контекст путем построения графика сегодняшней цены закрытия на 26 периодов позже текущей даты.

Кумо (или облако) образовано областью между Senkou Span A и Senkou Span B и служит зоной будущей поддержки и сопротивления. Часто более толстое облако указывает на более сильную поддержку/сопротивление, в то время как более тонкое облако подразумевает, что его можно легко пробить, что говорит о более слабых уровнях. Цвет облака — еще одна ключевая характеристика Ишимоку, поскольку обычно, когда Senkou Span A находится выше Senkou Span B, облако является бычьим (и обычно окрашено в зеленый цвет), а когда Senkou Span B находится выше Senkou Span A, облако является медвежьим (и часто окрашено в красный цвет).

Давайте теперь рассмотрим различные модели Ишимоку, как мы это делали с другими индикаторами в этих статьях. Мы рассмотрим 11 паттернов для Ишимоку и, как и в предыдущих статьях, начнем с рассмотрения одного паттерна за раз, используя входное целое число Signal_Ichimoku_PatternsUsed, чтобы определить, какой набор паттернов будет просматриваться советником, а какие паттерны будут игнорироваться. Это входное целое число изначально используется для выбора только одного из 11 паттернов за раз, и после того, как все паттерны будут независимо протестированы, мы оптимизируем их для идеальной комбинации, которая обеспечит нам наилучшие результаты.

Поскольку у нас есть 11 паттернов, этому входному целому числу не следует присваивать значение больше 2¹¹ минус 1 (2047), поскольку это целое число способно охватить все возможные комбинации паттернов. Мы проводим наши тесты на паре GBPJPY H1 за 2022 год. Все представленные здесь результаты тестирования являются всего лишь прогонами некоторых результатов, полученных при оптимизации советника в течение короткого тестового периода 2022 года на паре GBPJPY. Никаких прямых или перекрестных проверок не проводилось, а прилагаемый код предназначен для сборки с помощью Мастера MQL5. Новички могут узнать подробности здесь и здесь.

Пересечение Tenkan-Sen и Kijun-Sen

Это, пожалуй, самый распространенный и популярный сигнал среди паттернов Ишимоку. По сути, речь идет о простом пересечении скользящей средней (для быстрых и медленных периодов), и, учитывая его статические входные параметры для периодов усреднения, многие считают его и этот индикатор в целом недостаточно чувствительным к меняющимся рыночным условиям. Тем не менее, бычий сигнал возникает, когда Tenkan-sen пересекает Kijun-sen снизу вверх, а медвежий сигнал - когда Tenkan-sen пересекает Kijun-sen сверху вниз. Реализуем это в MQL5 следующим образом:

//+------------------------------------------------------------------+
//| Check for Pattern 0.                                             |
//+------------------------------------------------------------------+
bool CSignalIchimoku::IsPattern_0(ENUM_POSITION_TYPE T)
{  if(T == POSITION_TYPE_BUY && Tankensen(X()+1) < Kijunsen(X()+1) && Tankensen(X()) > Kijunsen(X()))
   {  return(true);
   }
   else if(T == POSITION_TYPE_SELL && Tankensen(X()+1) > Kijunsen(X()+1) && Tankensen(X()) < Kijunsen(X()))
   {  return(true);
   }
   return(false);
}

Тестовые прогоны по GBPJPY H1 в 2022 году дали следующие результаты:

Однако это пересечение подвержено влиянию рыночного шума, поскольку оно может сильно реагировать на незначительные колебания, особенно на меньших таймфреймах. Эта чрезмерная чувствительность может привести к ложным сигналам, при которых пересечения происходят без существенного изменения тренда, что приводит к тому, что открытые позиции часто испытывают резкие колебания на нестабильных или консолидирующихся рынках.

Это означает, что паттерн 0 может иметь ограниченную эффективность на рынках с ограниченным диапазоном, поскольку метод пересечения лучше всего подходит для трендовых рынков. На рынках с ограниченным диапазоном или флетовых рынках частые пересечения могут ввести трейдеров в заблуждение, что приводит к входам и выходам, которым не хватает направления или последовательности. Таким образом, без четкого тренда пересечения между Tenkan-sen и Kijun-sen могут привести к увеличению транзакционных издержек и потенциальным убыткам от входа в непродуктивные сделки.

Цена vs сигнал Kijun-Sen (базовая линия)

Паттерн 1 во многом похож на паттерн 0. Он также основан на пересечении цены и скользящих средних, которое рассматривается как чистое пересечение скользящих средних. Kijun-sen охватывает немного более длительный период, чем Tenkan-sen, поэтому любые ценовые пересечения, которые он регистрирует, часто имеют важное значение. При бычьем сигнале цена пересекает линию снизу вверх и закрывается выше нее, а при медвежьем сигнале происходит пересечение сверху вниз. В MQL5 паттерн реализуется следующим образом:

//+------------------------------------------------------------------+
//| Check for Pattern 1.                                             |
//+------------------------------------------------------------------+
bool CSignalIchimoku::IsPattern_1(ENUM_POSITION_TYPE T)
{  if(T == POSITION_TYPE_BUY && Close(X()+1) < Kijunsen(X()+1) && Close(X()) > Kijunsen(X()))
   {  return(true);
   }
   else if(T == POSITION_TYPE_SELL && Close(X()+1) > Kijunsen(X()+1) && Close(X()) < Kijunsen(X()))
   {  return(true);
   }
   return(false);
}

Тестовые прогоны с настройками, аналогичными указанным выше, после короткого прогона оптимизации дают нам следующие результаты (при этом входной параметр для используемых паттернов был установлен на 2):

Несмотря на то, что паттерн 1 демонстрирует некоторые перспективы в ходе этого тестового прогона, он таит в себе некоторые подводные камни, о которых трейдерам следует помнить. Во-первых, Kijun-sen отражает среднюю цену за 26 периодов, но не дает никаких указаний относительно динамики тренда или его силы. Обычно это означает, что трейдеры, полагающиеся исключительно на этот сигнал, могут пропустить признаки ослабления импульса, что может привести к потерям по открытым позициям, если тренд развернется или перейдет в фазу консолидации.

Более того, эта модель не дает подсказок относительно сигналов выхода или, что еще важнее, целевых цен. Хотя Kijun-sen может быть полезен для обозначения преобладающих трендов, его бесполезность для определения стоп-уровней делает его неподходящим для применения без дополнительных инструментов.

Прорыв Кумо (облака)

Подобно пересечению, которое мы рассматривали в паттерне 0, Кумо является основным индикатором и источником паттернов в Ишимоку. Находясь между двумя Senkou span, его важность в первую очередь обусловлена его связью с уровнями поддержки и сопротивления. Бычий сигнал здесь определяется как прорыв, когда цена пробивает облако и может закрыться выше него. Медвежий сигнал возникает, если цена опустится ниже облака и останется там после закрытия. В коде это будет реализовано так:

//+------------------------------------------------------------------+
//| Check for Pattern 2.                                             |
//+------------------------------------------------------------------+
bool CSignalIchimoku::IsPattern_2(ENUM_POSITION_TYPE T)
{  if(T == POSITION_TYPE_BUY && 
      ((Close(X()+1) < SenkouSpanA(X()+1) && Close(X()) > SenkouSpanA(X()) && SenkouSpanA(X()) > SenkouSpanB(X()))
      ||
      (Close(X()+1) < SenkouSpanB(X()+1) && Close(X()) > SenkouSpanB(X()) && SenkouSpanB(X()) > SenkouSpanA(X())))
      )
   {  return(true);
   }
   else if(T == POSITION_TYPE_SELL &&
      ((Close(X()+1) > SenkouSpanA(X()+1) && Close(X()) < SenkouSpanA(X()) && SenkouSpanA(X()) < SenkouSpanB(X()))
      ||
      (Close(X()+1) > SenkouSpanB(X()+1) && Close(X()) < SenkouSpanB(X()) && SenkouSpanB(X()) < SenkouSpanA(X())))
      )
   {  return(true);
   }
   return(false);
}

Тестовые запуски с настройками, аналогичными приведенным выше, но с фокусом на паттерне 2, дают нам следующие результаты (количество используемых паттернов устанавливается равным 4):

Хотя паттерн 2 также предлагает интересные результаты отчетов, как мы видим выше, он очень чувствителен к тайифреймам. Это особенно важно, поскольку на более коротких временных интервалах прорывы более восприимчивы к рыночному шуму и временным колебаниям цен, что может приводить к частым ложным сигналам. И наоборот, к сожалению, на больших таймфреймах часто бывают случаи, когда сигнал прорыва запаздывает и в итоге не достигает идеальной точки входа.

Кроме того, для подтверждения паттерна 2 необходимо учитывать контекст тренда. Чтобы прорыв Кумо был надежным, он должен соответствовать более широкой тенденции, на которую указывают другие компоненты Ишимоку, такие как Lagging Line (запаздывающая линия), а также относительное положение базовой линии и линии Conversion. И это приводит к еще одному слабому, которое так или иначе характерно для всех индикаторов. Игнорирование фундаментальных данных рынка. Трейдеры, полагающиеся исключительно на прорыв Кумо, могут упустить важный рыночный контекст.

Поворот Кумо

Паттерн возникает из-за изменения цвета облака или обмена местами между Senkou span A и Senkou span B. Поскольку эти две величины также фактически являются скользящими средними, мы снова имеем дело с пересечением, хотя и с запаздывающим эффектом. Таким образом, бычий сигнал возникает, когда Senkou span A ("более короткий" период буфера) пересекает Senkou span B снизу вверх и закрывается выше него. Это также известно как бычий поворот Кумо, который сигнализирует о потенциальном будущем восходящем тренде. Аналогично, медвежий сигнал возникает, когда Senkou span A пересекает Senkou span B сверху вниз. Вот как мы реализуем их в коде:

//+------------------------------------------------------------------+
//| Check for Pattern 3.                                             |
//+------------------------------------------------------------------+
bool CSignalIchimoku::IsPattern_3(ENUM_POSITION_TYPE T)
{  if(T == POSITION_TYPE_BUY && SenkouSpanA(X()+1) < SenkouSpanB(X()+1) && SenkouSpanA(X()) > SenkouSpanB(X()))
   {  return(true);
   }
   else if(T == POSITION_TYPE_SELL && SenkouSpanA(X()+1) > SenkouSpanB(X()+1) && SenkouSpanA(X()) < SenkouSpanB(X()))
   {  return(true);
   }
   return(false);
}

Тестирование на GBPJPY H1 за 2022 дало нам следующие результаты:

Однако у паттерна 3 есть свои недостатки, и главный из них — неправильное толкование толщины облаков. Для многих трейдеров поворот Кумо часто ассоциируется с толщиной облаков, а толщина облаков указывает на более сильные тренды. Однако оценка этой толщины требует опыта и надлежащего рыночного контекста, поскольку довольно часто поворот облака может оказаться ложным, особенно при работе с нестабильными рынками.

Этот паттерн, как и другие, рассмотренные выше, мало что говорит о силе или динамике тренда. Это затрудняет определение того, будет ли разворот иметь устойчивую силу. Это создает риски входа в затухающие тренды. Это еще раз подчеркивает зависимость от более широкого контекста Ишимоку, поскольку в идеале поворот Кумо должно подтверждаться другими элементами Ишимоку, такими как пересечение Tenkan-sen и Kijun-sen или Chikou Span. Полагаться исключительно на поворот без этих подтверждений может привести к ложным сигналам. Трейдеры, которые не рассматривают всю систему Ишимоку, могут неправильно истолковать повороты, поэтому мы представляем эти паттерны не по отдельности, а как совокупность, из которой трейдеры могут выбрать то, что наиболее для них подходит.

Подтверждение Chikou Span (Lagging Line)

Chikou span - это запаздывающий буфер, и хотя его использование вне графика при ручной торговле может быть простым, при реализации его в коде необходимо убедиться, что индексация правильно смещена. Бычий сигнал возникает, если Chikou Span пересекает цену снизу вверх. Медвежий сигнал возникает, если Chikou Span пересекает цену сверху вниз. Реализация в коде:

//+------------------------------------------------------------------+
//| Check for Pattern 4.                                             |
//+------------------------------------------------------------------+
bool CSignalIchimoku::IsPattern_4(ENUM_POSITION_TYPE T)
{  if(T == POSITION_TYPE_BUY && ChikouSpan(X()+1) <= Tankensen(X()+1) && ChikouSpan(X()) > Tankensen(X()))
   {  return(true);
   }
   else if(T == POSITION_TYPE_SELL && ChikouSpan(X()+1) >= Tankensen(X()+1) && ChikouSpan(X()) < Tankensen(X()))
   {  return(true);
   }
   return(false);
}

Тестирование с теми же настройками, что и с другими паттернами, дает нам следующие результаты:

Потенциальная чрезмерная зависимость от сигналов паттерна при игнорировании других ключевых сигналов является слабым местом паттерна 4. Об этом стоит упомянуть еще раз, как и в случае с другими паттернами выше. Chikou span является подтверждающим сигналом, который необходимо сочетать с такими сигналами, как прорыв Кумо или пересечение Tenkan-sen и Kijun-sen, будет подходящим. Использование одного лишь паттерна 4 может привести к неполному пониманию динамики рынка. Это также приводит к другим уже упомянутым слабым местам - ограниченной значимости на рынках, движимых фундаментальными причинами, а также потенциальной неспособности учесть более широкий рыночный контекст и факторы.

Кумо как поддержка и сопротивление

Помимо того, что Кумо выступает в качестве порогового значения прорыва, он может служить формой динамической поддержки или сопротивления. Таким образом, торговая стратегия будет включать бычий отскок, который формируется, если цена откатывается к облаку, но не может его пробить, при этом облако выступает в качестве поддержки, что можно использовать в качестве точки входа для длинных сделок. Медвежий отскок будет зафиксирован, если цена поднимется до облака, но не сможет его преодолеть, при этом облако выступит в качестве сопротивления, тем самым сигнализируя о потенциальной возможности продажи. Код паттерна 5 выглядит так:

//+------------------------------------------------------------------+
//| Check for Pattern 5.                                             |
//+------------------------------------------------------------------+
bool CSignalIchimoku::IsPattern_5(ENUM_POSITION_TYPE T)
{  if(T == POSITION_TYPE_BUY && 
      ((Close(X()+2) > SenkouSpanA(X()+2) && Close(X()+1) < SenkouSpanA(X()+1) && Close(X()) > SenkouSpanA(X()) && SenkouSpanA(X()) > SenkouSpanB(X()))
      ||
      (Close(X()+2) > SenkouSpanA(X()+2) && Close(X()+1) < SenkouSpanB(X()+1) && Close(X()) > SenkouSpanB(X()) && SenkouSpanB(X()) > SenkouSpanA(X())))
      )
   {  return(true);
   }
   else if(T == POSITION_TYPE_SELL &&
      ((Close(X()+2) < SenkouSpanA(X()+2) && Close(X()+1) > SenkouSpanA(X()+1) && Close(X()) < SenkouSpanA(X()) && SenkouSpanA(X()) < SenkouSpanB(X()))
      ||
      (Close(X()+2) < SenkouSpanA(X()+2) && Close(X()+1) > SenkouSpanB(X()+1) && Close(X()) < SenkouSpanB(X()) && SenkouSpanB(X()) < SenkouSpanA(X())))
      )
   {  return(true);
   }
   return(false);
}

Тестовые прогоны осуществлялись с количеством паттернов, равным 32, что гарантировало, что мы тестируем только этот паттерн:

Паттерн 5, где Кумо выступает в качестве поддержки/сопротивления, страдает от запоздалой реакции при определении разворотов тренда. Это связано с тем, что Кумо отстает от текущего ценового движения из-за своего расчета (26 смещенных вперед периодов), что приводит к задержке сигналов по сравнению с альтернативными индикаторами поддержки/сопротивления в реальном времени. Эти задержки могут привести к позднему входу в рынок, что снизит его эффективность как показателя поддержки/сопротивления, особенно на быстро меняющихся рынках.

Кроме того, у паттерна 5 есть сложности при определении уровней. В отличие от традиционных линий поддержки и сопротивления, Кумо представляет собой зону, а не конкретный ценовой уровень. Это несколько затрудняет процесс определения точных точек входа и выхода. Эта неоднозначность может затруднить управление сделками, поскольку установка точных уровней стоп-лосса или тейк-профита в облаке может оказаться непростой задачей.

Наконец, эта модель может быть ненадежной на рынках с выраженными трендами, поскольку цены легко прорываются через Кумо с небольшими колебаниями. Это делает его не столько индикатором поддержки или сопротивления, сколько ценовым буфером. Использование этого паттерна без других инструментов может привести к упущенным возможностям.

Сильные пересечения (выше или ниже Кумо)

Паттерн 6 во многом схож с паттерном 0, однако добавляет фильтр, который учитывает относительное положение Кумо по отношению к пересекающимся Tenkan-sen и Kijun-sen. Эти две линии могут пересекаться в любое время, однако считается, что сочетание каждого пересечения с определенным положением Кумо дает еще более сильный сигнал. Бычий сигнал будет отмечен, если бычье пересечение линий Tenkan-sen/Kijun-sen произойдет выше облака, что, как уже подчеркивалось, будет указывать на сильный сигнал на покупку. Сильный медвежий сигнал будет зафиксирован, если медвежье пересечение линий Tenkan-sen/Kijun-sen произойдет ниже облака. Этот сигнал подразумевает, что любое пересечение, происходящее внутри облака, менее сильно из-за нерешительности на рынке. Реализация паттерна 6 в коде:

//+------------------------------------------------------------------+
//| Check for Pattern 6.                                             |
//+------------------------------------------------------------------+
bool CSignalIchimoku::IsPattern_6(ENUM_POSITION_TYPE T)
{  if(T == POSITION_TYPE_BUY  && Tankensen(X()+1) < Kijunsen(X()+1) && Tankensen(X()) > Kijunsen(X()) &&
      ((Tankensen(X()) > SenkouSpanA(X()) && SenkouSpanA(X()) > SenkouSpanB(X()))
      ||
      (Tankensen(X()) > SenkouSpanB(X()) && SenkouSpanB(X()) > SenkouSpanA(X())))
      )
   {  return(true);
   }
   else if(T == POSITION_TYPE_SELL && Tankensen(X()+1) > Kijunsen(X()+1) && Tankensen(X()) < Kijunsen(X()) &&
      ((Tankensen(X()) < SenkouSpanA(X()) && SenkouSpanA(X()) < SenkouSpanB(X()))
      ||
      (Tankensen(X()) < SenkouSpanB(X()) && SenkouSpanB(X()) < SenkouSpanA(X())))
      )
   {  return(true);
   }
   return(false);
}

Тестирование с настройками тестера стратегий, аналогичными указанным выше, с входным параметром для количества используемых паттернов, равным 64, дает следующие результаты:

Несмотря на то, что мы видим в отчете, пересечения Кумо, как правило, сильно отстают. Сильное пересечение выше или ниже Кумо обычно происходит после того, как существенное изменение тренда уже произошло, и это может привести к потенциальным задержкам при входе или выходе. Поэтому трейдеры, полагающиеся исключительно на пересечения Кумо для своих входов, могут войти поздно, упустив начальные, более прибыльные части тренда.

Также существует уязвимость к разворотам на волатильных рынках. Это связано с тем, что на рынках с высокой волатильностью или новостями сильное пересечение может быстро изменить направление, заманивая в ловушку трейдеров, которые входят на основе только этого пересечения. Поэтому эти внезапные развороты могут привести к значительным потерям, особенно если трейдеры не подтверждают тренд другими индикаторами.

Наконец, и это вполне характерно для Ишимоку, частые резкие колебания цен на рынках с ограниченным диапазоном неизбежно приводят к появлению множества ложных сигналов, поскольку цены колеблются вокруг Кумо без четкого направления.

Определение силы тренда по толщине облаков

Еще один паттерн в Ишимоку, которую можно использовать для принятия решений о покупке и продаже, — это толщина Кумо. Тонкий Кумо указывает на слабую поддержку или сопротивление, что может привести к прорывам или разворотам, в то время как толстый Кумо указывает на сильную поддержку или сопротивление и может сигнализировать о продолжении текущего тренда. Бычий сигнал определяется как бычий тренд в течение примерно 26 баров, который также отмечен увеличением толщины облака. Напротив, медвежьим сигналом будет медвежий тренд в течение аналогичного периода, который также будет отмечена сгущением облака в течение этого периода. Реализация в коде:

//+------------------------------------------------------------------+
//| Check for Pattern 7.                                             |
//+------------------------------------------------------------------+
bool CSignalIchimoku::IsPattern_7(ENUM_POSITION_TYPE T)
{  if(T == POSITION_TYPE_BUY && Close(X()) > Close(X()+26) && fabs(SenkouSpanB(X()) - SenkouSpanA(X())) > fabs(SenkouSpanB(X()+26) - SenkouSpanA(X()+26)))
   {  return(true);
   }
   else if(T == POSITION_TYPE_SELL && Close(X()) < Close(X()+26) && fabs(SenkouSpanB(X()) - SenkouSpanA(X())) > fabs(SenkouSpanB(X()+26) - SenkouSpanA(X()+26)))
   {  return(true);
   }
   return(false);
}

Тестовые запуски со значением количества паттернов 128 дают нам следующее:

Толщина облаков уязвима для ложных сигналов при низкой волатильности или в боковом тренде. Это связано с тем, что облако может оставаться густым из-за исторической динамики цен, несмотря на преобладающие слабые тренды. Следовательно, это может привести к ложным сигналам, поскольку толщина облака не всегда может коррелировать с силой тренда. Неправильная интерпретация неизбежно приведет к ненужным сделкам.

Кроме того, риски позднего выхода из сделок во время разворотов тренда действительно велики, поскольку толщина облака может создать ложное чувство безопасности, учитывая его запаздывающую природу. Излишняя концентрация внимания на толщине облаков может скрыть ранние предупреждающие сигналы, особенно если другие сигналы Ишимоку, такие как движение Chikou Span, противоречат тренду, указывая на потенциальный разворот.

Наконец, субъективность в определении "толстых" и "тонких" облаков означает, что трейдерам необходимо самостоятельно прийти к подходящему способу измерения этого показателя, который подкреплен собственными результатами тестирования на истории с качественными данными. Это ключевой момент, поскольку трейдеры с разными определениями толщины облаков могут интерпретировать одни и те же рыночные условия противоположным образом, что приводит к отсутствию ясности в торговых сигналах.

Отскок цены от Kijun-sen (базовый уровень)

Паттерн 8 фокусируется на Kijun-sen, 26-периодной скользящей средней. Поскольку периодов больше 26, а не 9, как у Tenkan-sen, любое ценовое действие, связанное с ним, становится более значимым, поскольку оно происходит нечасто, учитывая более длительный период усреднения. Мы получаем сигналы, наблюдая за отскоком цены. Бычий отскок происходит, когда цена касается Kijun-sen сверху и отскакивает вверх, тем самым сигнализируя о том, что тренд все еще сохраняется, что представляет собой потенциальную возможность для покупки. Медвежий отскок происходит, когда цена касается Kijun-sen снизу и отскакивает вниз, сигнализируя о продолжении нисходящего тренда и потенциальной возможности для продажи. Реализация в коде:

//+------------------------------------------------------------------+
//| Check for Pattern 8.                                             |
//+------------------------------------------------------------------+
bool CSignalIchimoku::IsPattern_8(ENUM_POSITION_TYPE T)
{  if(T == POSITION_TYPE_BUY && Close(X()+2) >= Kijunsen(X()+1) && Close(X()+1) <= Kijunsen(X()+1) && Close(X()) > Kijunsen(X()))
   {  return(true);
   }
   else if(T == POSITION_TYPE_SELL && Close(X()+2) <= Kijunsen(X()+1) && Close(X()+1) >= Kijunsen(X()+1) && Close(X()) < Kijunsen(X()))
   {  return(true);
   }
   return(false);
}

Если мы выполним тестовые запуски для паттерна, присвоив входному параметру используемых шаблонов значение 256, мы получим следующие результаты:

Несмотря на то, что приведенный выше отчет по паттерну 8 выглядит многообещающим, трейдерам следует опасаться возможных ошибок в условиях сильных трендов, когда происходит прорыв, который может не привести к желаемому отскоку. Кроме того, в качестве сигнала паттерна ему не хватает подтверждения того, что сила отскока цены представляет собой основную тенденцию, поэтому его лучше сочетать с одним из паттернов пересечения, например с паттерном 0 выше. Наконец, следует учитывать зависимость от таймфреймов. Это еще одна распространенная особенность паттернов Ишимоку, поэтому трейдерам следует убедиться, что этот паттерн не слишком сильно считывается с меньших таймфреймов, поскольку сигнал большего таймфрейма будет иметь больший вес.

Соответствие цены и Chikou Span

Паттерн 9 (являющийся десятым по счету) учитывает цену и запаздывающий Chikou span. Поскольку Chikou span отстает от цен закрытия, для получения значимых сигналов необходим еще один текущий буфер помимо необработанных цен. Поэтому мы используем буфер Tenkan-sen для представления нашего текущего ценового движения и ищем моменты, когда он согласуется с Chikou span для считывания сигналов. Бычий сигнал возникает, если и цена, и Chikou Span находятся выше облака, поскольку считается, что это усиливает сигнал бычьего тренда. И наоборот, медвежий сигнал возникает, если и цена, и Chikou Span находятся ниже облака. Реализация в коде:

//+------------------------------------------------------------------+
//| Check for Pattern 9.                                             |
//+------------------------------------------------------------------+
bool CSignalIchimoku::IsPattern_9(ENUM_POSITION_TYPE T)
{  if(T == POSITION_TYPE_BUY  && 
      ((Close(X()) > SenkouSpanA(X()) && ChikouSpan(X()) > SenkouSpanA(X()) && SenkouSpanA(X()) > SenkouSpanB(X()))
      ||
      (Close(X()) > SenkouSpanB(X()) && ChikouSpan(X()) > SenkouSpanB(X()) && SenkouSpanB(X()) > SenkouSpanA(X())))
      )
   {  return(true);
   }
   else if(T == POSITION_TYPE_SELL &&  
      ((Close(X()) < SenkouSpanA(X()) && ChikouSpan(X()) < SenkouSpanA(X()) && SenkouSpanA(X()) < SenkouSpanB(X()))
      ||
      (Close(X()) < SenkouSpanB(X()) && ChikouSpan(X()) < SenkouSpanB(X()) && SenkouSpanB(X()) < SenkouSpanA(X())))
      )
   {  return(true);
   }
   return(false);
}

Тестовый запуск с входным параметром для используемых паттернов, равным 512, дает нам следующий отчет:

Несмотря на радужные результаты, представленные выше, трейдерам следует опасаться несоответствий паттерна 9 на разных таймфреймах, не пренебрегать рыночным контекстом при использовании этой модели и ее уязвимостью к разворотам тренда.

Повторный вход в тренд на основе Tenkan-sen и Kijun-sen

Наш паттерн 10 (одиннадцатый по счету) объединяет пересечение, которое мы видели в паттерне 0 в качестве задержки с тестированием ценой линии Tenkan-sen. Реализация в коде:

//+------------------------------------------------------------------+
//| Check for Pattern 10.                                            |
//+------------------------------------------------------------------+
bool CSignalIchimoku::IsPattern_10(ENUM_POSITION_TYPE T)
{  if(T == POSITION_TYPE_BUY && Tankensen(X()+3) < Kijunsen(X()+3) && Tankensen(X()+2) > Kijunsen(X()+2) && Tankensen(X()+1) >= Close(X()+1) && Tankensen(X()) < Close(X()))
   {  return(true);
   }
   else if(T == POSITION_TYPE_SELL && Tankensen(X()+3) > Kijunsen(X()+3) && Tankensen(X()+2) < Kijunsen(X()+2) && Tankensen(X()+1) <= Close(X()+1) && Tankensen(X()) > Close(X()))
   {  return(true);
   }
   return(false);
}

Торговая стратегия заключается в том, что после бычьего пересечения линий Tenkan-sen/Kijun-sen цена может повторно протестировать линию Kijun-sen на нижней границе, а затем отскочить и возобновить восходящее движение, что станет точкой входа для покупателей. Аналогично, после переворота, когда Tenkan-sen находится ниже Kijun-sen, цена может повторно протестировать Kijun-sen снизу, отскочить от нее и затем возобновить снижение. Мы тестируем только этот паттерн, присваивая входному параметру используемых паттернов значение 1024, и в одном из оптимизированных прогонов наш отчет выглядит так:

У паттерна 10 есть потенциал, однако трейдерам необходимо обращать внимание на ложные сигналы на боковых рынках, должным образом учитывать более широкий рынок и контекст при совершении сделок, а также избегать риска чрезмерной торговли, учитывая множество сигналов, которые этот паттерн обязательно будет генерировать.

Объединяем все паттерны

Всегда лучше торговать по нескольким моделям. Относительные веса моделей определяются на основе собственных представлений трейдера об их важности. Такие представления нарабатываются с опытом. Опасность оптимизации весов отдельных паттернов при использовании всех одновременно заключается в том, что они будут иметь тенденцию закрывать сделки друг друга, и поэтому будет непросто сделать вывод об эффективности каждого из них на основе назначенных весов. Тем не менее, результаты ниже демонстрируют разницу в производительности, при объединении нескольких сигналов и при использовании одного паттерна.

Заключение

В заключение следует отметить, что хотя Ichimoku Kinko Hyo предлагает всеобъемлющий обзор с его многогранными компонентами и разнообразными моделями, его практическое применение остается неоднозначным и требует глубокого понимания динамики рынка. Трейдеры, использующие облако Ишимоку, должны быть бдительны в отношении его ограничений, включая потенциальное запаздывание индикаторов, восприимчивость к рыночному шуму и зависимость от дополнительных подтверждающих сигналов, чтобы избежать ложных срабатываний.

Более того, разнообразные закономерности системы подчеркивают необходимость объединения множества элементов в рамках Ишимоку, а также дополнительных методов анализа для повышения точности принятия решений и минимизации риска.

Как было показано, ни один паттерн в отдельности не гарантирует успеха. Таким образом, надежный подход подразумевает использование совокупности паттернов в соответствии с более широким рыночным контекстом и фундаментальными факторами. Таким образом трейдеры могут эффективнее использовать потенциал Ichimoku Kinko Hyo как сбалансированного инструмента в своем торговом арсенале, стратегически ориентируясь в рыночных трендах для создания обоснованных и дисциплинированных торговых стратегий.