Справочник MQL5Графические объектыObjectSetString

ObjectSetString

Задает значение соответствующего свойства объекта. Свойство объекта должно быть типа string. Существует 2 варианта функции.

Установка значения свойства, не имеющего модификатора

bool  ObjectSetString(
   long                            chart_id,          // идентификатор графика
   string                          name,              // имя
   ENUM_OBJECT_PROPERTY_STRING     prop_id,           // свойство
   string                          prop_value         // значение
   );

Установка значения свойства с указанием модификатора

bool  ObjectSetString(
   long                            chart_id,          // идентификатор графика
   string                          name,              // имя
   ENUM_OBJECT_PROPERTY_STRING     prop_id,           // свойство
   int                             prop_modifier,     // модификатор
   string                          prop_value         // значение
   );

Параметры

chart_id

[in] Идентификатор графика. 0 означает текущий график.

name

[in] Имя объекта.

prop_id

[in] Идентификатор свойства объекта. Значение может быть одним из значений перечисления ENUM_OBJECT_PROPERTY_STRING.

prop_modifier

[in] Модификатор указанного свойства. Означает номер уровня в инструментах Фибоначчи и в графическом объекте Вилы Эндрюса. Нумерация уровней начинается с нуля.

prop_value

[in] Значение свойства.

Возвращаемое значение

Возвращает true только в том случае, если команда на изменение свойств графического объекта успешно отправлена графику, иначе возвращает false. Чтобы получить дополнительную информацию об ошибке, необходимо вызвать функцию GetLastError().

Примечание

Функция использует асинхронный вызов – это означает, что функция не дожидается выполнения команды, успешно поставленной в очередь указанного графика, а сразу же возвращает управление.

Для проверки результата выполнения на чужом графике можно использовать функцию, запрашивающую указанное свойство объекта. Но при этом следует иметь в виду, что такие функции ставятся в конец очереди команд чужого графика и дожидаются результата выполнения, то есть могут быть затратными по времени. Нужно иметь это обстоятельство в виду, если ведется работа с большим количеством объектов на графике.

При переименовании графического объекта одновременно формируются два события, которые можно обработать в эксперте или индикаторе функцией OnChartEvent():

событие удаления объекта со старым именем;
событие создания графического объекта с новым именем.

Пример:

#property copyright "Copyright 2025, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"

#define   OBJ_NAME   "TestObjectSetString"   // Имя объекта

//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- идентификатор текущего графика и его символ, флаг отображения описания объектов
   long   chart_id= ChartID();
   string symbol  = ChartSymbol(chart_id);
   bool   descript= ChartGetInteger(chart_id, CHART_SHOW_OBJECT_DESCR);

//--- установим отображение описания объектов на графике
   ChartSetInteger(chart_id, CHART_SHOW_OBJECT_DESCR, true);

//--- получим текущую цену Bid
   double bid=0;;
   ResetLastError();
   if(!SymbolInfoDouble(symbol, SYMBOL_BID, bid))
     {
      Print("SymbolInfoDouble() failed. Error ", GetLastError());
      return;
     }

//--- создаём графический объект "Горизонтальная Линия" на текущей цене Bid
   if(!ObjectCreate(chart_id, OBJ_NAME, OBJ_HLINE, 0, 0, bid))
     {
      Print("ObjectCreate() failed. Error ", GetLastError());
      return;
     }
//--- вписываем в описание объекта его имя+"Description"
   if(!ObjectSetString(chart_id, OBJ_NAME, OBJPROP_TEXT, "Bid: "+DoubleToString(bid, (int)SymbolInfoInteger(symbol, SYMBOL_DIGITS))))
     {
      Print("ObjectSetString() failed. Error ", GetLastError());
      return;
     }
//--- обновляем график для немедленного отображения изменений
   ChartRedraw(chart_id);

//--- получаем описание объекта
   string string_var="";
   if(!ObjectGetString(chart_id, OBJ_NAME, OBJPROP_TEXT, 0, string_var))
     {
      Print("ObjectGetInteger() failed. Error ", GetLastError());
      return;
     }
//--- получаем имя объекта
   string obj_name=ObjectGetString(chart_id, OBJ_NAME, OBJPROP_NAME);

//--- получаем тип объекта
   ENUM_OBJECT object_type=(ENUM_OBJECT)ObjectGetInteger(chart_id, OBJ_NAME, OBJPROP_TYPE);

//--- выводим в журнал тип объекта, его имя и описание
   PrintFormat("The %s object named \"%s\" has the description \"%s\"",EnumToString(object_type), obj_name, string_var);

//--- подождём две секунды и удалим созданный объект
   Sleep(2000);
   ObjectDelete(chart_id, OBJ_NAME);

//--- вернём изначальный флаг отображения описания объектов для графика
   ChartSetInteger(chart_id, CHART_SHOW_OBJECT_DESCR, descript);
   ChartRedraw(chart_id);
   /*
   результат:
   The OBJ_HLINE object named "TestObjectSetString" has the description "Bid: 0.62096"
   */
  }

ObjectSetInteger

ObjectGetDouble