#property copyright "Copyright 2025, MetaQuotes Ltd."
#property link "https://www.mql5.com"
#property version "1.00"
#define OBJ_NAME "TestObjectGetTimeByValue" // имя графического объекта
#define STEP 100 // шаг цены
//+------------------------------------------------------------------+
//| Script program start function |
//+------------------------------------------------------------------+
void OnStart()
{
//--- идентификатор, символ
long chart_id=ChartID();
string chart_symbol=ChartSymbol(chart_id);
//--- получаем значение Point символа графика
double point=SymbolInfoDouble(chart_symbol, SYMBOL_POINT);
if(point==0)
{
PrintFormat("Failed to get the Point value of the \"%s\" symbol. Error %d", chart_symbol, GetLastError());
return;
}
//--- строим равноудалённый канал от High левого видимого бара до Low правого
if(!CreateChannel(chart_id))
return;
//--- максимум и минимум графика, значение Digits символа графика
double chart_max=ChartGetDouble(chart_id, CHART_PRICE_MAX);
double chart_min=ChartGetDouble(chart_id, CHART_PRICE_MIN);
int digits=(int)SymbolInfoInteger(chart_symbol, SYMBOL_DIGITS);
//--- пока рассчитанная цена price больше наименьшего значения цены графика,
//--- идём в цикле по ценам графика с шагом STEP и получаем значение времени
//--- для рассчитанного значения цены price каждой линии равноудалённого канала.
//--- полученное время для каждой линии выводим в журнал
int index=0;
double price=chart_max;
do
{
price=chart_max-STEP*index*point;
datetime time0=ObjectGetTimeByValue(chart_id, OBJ_NAME, price, 0);
datetime time1=ObjectGetTimeByValue(chart_id, OBJ_NAME, price, 1);
string time0_str=(time0>0 ? TimeToString(time0) : "No value at this price");
string time1_str=(time1>0 ? TimeToString(time1) : "No value at this price");
string idx=StringFormat("%02d", index);
PrintFormat("[%s] For price %.*f the time value at line 0: %s, at line 1: %s", idx, digits, price, time0_str, time1_str);
index++;
}
while(!IsStopped() && price>=chart_min);
//--- подождём 5 секунд и почистим за собой
Sleep(5000);
ObjectDelete(chart_id, OBJ_NAME);
ChartRedraw(chart_id);
/*
результат:
[00] For price 1.26110 the time value at line 0: No value at this price, at line 1: No value at this price
[01] For price 1.26010 the time value at line 0: 2024.12.30 17:00, at line 1: No value at this price
[02] For price 1.25910 the time value at line 0: 2024.12.30 22:30, at line 1: No value at this price
[03] For price 1.25810 the time value at line 0: 2024.12.31 04:00, at line 1: 2024.12.30 16:30
[04] For price 1.25710 the time value at line 0: 2024.12.31 10:00, at line 1: 2024.12.30 22:00
[05] For price 1.25610 the time value at line 0: 2024.12.31 15:30, at line 1: 2024.12.31 03:30
[06] For price 1.25510 the time value at line 0: 2024.12.31 21:00, at line 1: 2024.12.31 09:00
[07] For price 1.25410 the time value at line 0: 2025.01.02 03:30, at line 1: 2024.12.31 14:30
[08] For price 1.25310 the time value at line 0: No value at this price, at line 1: 2024.12.31 20:30
[09] For price 1.25210 the time value at line 0: No value at this price, at line 1: 2025.01.02 03:00
[10] For price 1.25110 the time value at line 0: No value at this price, at line 1: No value at this price
[11] For price 1.25010 the time value at line 0: No value at this price, at line 1: No value at this price
[12] For price 1.24910 the time value at line 0: No value at this price, at line 1: No value at this price
[13] For price 1.24810 the time value at line 0: No value at this price, at line 1: No value at this price
*/
}
//+------------------------------------------------------------------+
//| Строит равноудалённый канал от High левого бара до Low правого |
//+------------------------------------------------------------------+
bool CreateChannel(const long chart_id=0)
{
long bar1 =0, bar2 =0, visible=0;
datetime time1 =0, time2 =0;
double price1=0, price2=0;
//--- получаем первый видимый слева бар графика
ResetLastError();
if(!ChartGetInteger(chart_id, CHART_FIRST_VISIBLE_BAR, 0, bar1))
{
PrintFormat("%s: ChartGetInteger() failed. Error %d",__FUNCTION__, GetLastError());
return(false);
}
//--- количество видимых баров на графике
if(!ChartGetInteger(chart_id, CHART_VISIBLE_BARS, 0, visible))
{
PrintFormat("%s: ChartGetInteger() failed. Error %d",__FUNCTION__, GetLastError());
return(false);
}
//--- корректируем полученные значения и рассчитываем индекс первого видимого справа бара
bar1-=1;
visible-=2;
bar2=bar1-visible;
//--- символ графика
string symbol=ChartSymbol(chart_id);
//--- получаем время первого видимого слева бара графика
ResetLastError();
datetime time_array[1];
if(CopyTime(symbol, PERIOD_CURRENT, (int)bar1, 1, time_array)!=1)
{
PrintFormat("%s: CopyTime() failed. Error %d",__FUNCTION__, GetLastError());
return(false);
}
time1=time_array[0];
//--- получаем время первого видимого справа бара графика
if(CopyTime(symbol, PERIOD_CURRENT, (int)bar2, 1, time_array)!=1)
{
PrintFormat("%s: CopyTime() failed. Error %d",__FUNCTION__, GetLastError());
return(false);
}
time2=time_array[0];
//--- получаем цену High первого видимого слева бара графика
double price_array[];
if(CopyHigh(symbol, PERIOD_CURRENT, (int)bar1, 1, price_array)!=1)
{
PrintFormat("%s: CopyHigh() failed. Error %d",__FUNCTION__, GetLastError());
return(false);
}
price1=price_array[0];
//--- получаем цену Low первого видимого справа бара графика
if(CopyLow(symbol, PERIOD_CURRENT, (int)bar2, 1, price_array)!=1)
{
PrintFormat("%s: CopyLow() failed. Error %d",__FUNCTION__, GetLastError());
return(false);
}
price2=price_array[0];
//--- рассчитываем диапазон цен графика в пунктах
//--- для равноудалённого канала дистанция второй линии будет 1/3 от диапазона цен
double range=price1-price2;
double distance=range*0.3;
//--- на рассчитанных координатах создаём графический объект-равноудалённый канал
if(!ObjectCreate(chart_id, OBJ_NAME, OBJ_CHANNEL, 0, time1, price1, time2, price2, time1, price1-distance))
{
PrintFormat("%s: ObjectCreate() failed. Error %d",__FUNCTION__, GetLastError());
return(false);
}
//--- обновим график и вернём true
ChartRedraw(chart_id);
return(true);
}
|