#property copyright "Copyright 2025, MetaQuotes Ltd."
#property link "https://www.mql5.com"
#property version "1.00"
#define COORD_X 200
#define COORD_Y 100
#define OBJ_NAME "TestTextGetSizeBitmapLabel"
#define RES_NAME "TestTextGetSizeResource"
#define COLOR_NULL 0x00FFFFFF
//+------------------------------------------------------------------+
//| Script program start function |
//+------------------------------------------------------------------+
void OnStart()
{
//--- идентификатор текущего графика
long chart_id= ChartID();
string font_names[] ={"Arial", "Tahoma", "Calibri"};
uint flags_array[]={0, FONT_ITALIC, FONT_UNDERLINE, FONT_STRIKEOUT};
uint fw_array[]={FW_DONTCARE, FW_THIN, FW_EXTRALIGHT, FW_ULTRALIGHT, FW_LIGHT,
FW_NORMAL, FW_REGULAR, FW_MEDIUM, FW_SEMIBOLD, FW_DEMIBOLD,
FW_BOLD, FW_EXTRABOLD, FW_ULTRABOLD, FW_HEAVY, FW_BLACK};
//--- запретим отрисовку любых атрибутов ценового графика
ChartSetInteger(chart_id, CHART_SHOW, false);
//--- объявляем параметры графического ресурса
uint rc_width =(int)ChartGetInteger(chart_id, CHART_WIDTH_IN_PIXELS);
uint rc_height=(int)ChartGetInteger(chart_id, CHART_HEIGHT_IN_PIXELS);
uint rc_data[];
uint rc_size=rc_width*rc_height;
//--- создаём графический ресурс для вывода текста
if(!CreateResource(chart_id, rc_data, rc_width, rc_height))
return;
//--- цикл по именам шрифтов
for(int i=0; i<(int)font_names.Size(); i++)
{
//--- цикл по флагам шрифта
for(int j=0; j<(int)flags_array.Size(); j++)
{
//--- рисуем текст с полученным из массива шрифтом и флагом начертания
DrawText(font_names[i], flags_array[j], rc_data, rc_width, rc_height);
Sleep(800);
ArrayInitialize(rc_data, COLOR_NULL);
}
Sleep(800);
ArrayInitialize(rc_data, COLOR_NULL);
}
//--- после вывода всех текстов с разными размерами и начертаниями шрифта,
//--- покажем текст с разными флагами толщины шрифта
for(int i=0; i<(int)fw_array.Size(); i++)
{
//--- устанавливаем размер и название шрифта для вывода текста с флагами толщины
string font_name="Tahoma";
int size=-140;
TextSetFont(font_name, size, fw_array[i]);
//--- создаём рисуемую строку текста, выводим её в массив пикселей ресурса и обновляем ресурс
string text=StringFormat("Text%d: Font name: \"%s%s\", size: %d (%d)", i+1, font_name, FlagWidthDescription(fw_array[i]), size, size/-10);
TextOut(text, COORD_X, COORD_Y, ANCHOR_LEFT_UPPER, rc_data, rc_width, rc_height, ColorToARGB(clrDodgerBlue), COLOR_FORMAT_ARGB_NORMALIZE);
Update(RES_NAME, rc_data, rc_width, rc_height, true);
//--- подождём секунду
Sleep(1000);
ArrayInitialize(rc_data, COLOR_NULL);
}
//--- подождём пять секунд, затем освободим ресурс и удалим графический объект
Sleep(5000);
ResourceFree(RES_NAME);
ObjectDelete(chart_id, OBJ_NAME);
//--- разрешим отрисовку любых атрибутов ценового графика
ChartSetInteger(chart_id, CHART_SHOW, true);
ChartRedraw(chart_id);
/*
в результате работы скрипта на график будут выведены текстовые сообщения
разными шрифтами с разными размерами и флагами начертания и ширины текста
*/
}
//+------------------------------------------------------------------+
//| Выводит на график пять строк текста разных |
//| размеров с указанным шрифтом и флагами |
//+------------------------------------------------------------------+
void DrawText(const string font_name, uint flags, uint &pixels_array[], uint res_width, uint res_height)
{
//--- выведем пять строк текста с разными размерами шрифта
for(int i=0; i<5; i++)
{
//--- рассчитываем размер шрифта и устанавливаем шрифт для вывода текста методами рисования
int size=-140+10*i;
TextSetFont(font_name, size, flags);
//--- создаём рисуемую строку текста, выводим её в массив пикселей ресурса и обновляем ресурс
string text=StringFormat("Text%d: Font name: \"%s%s\", size: %d (%d)", i+1, font_name, FlagDescription(flags), size, size/-10);
TextOut(text, COORD_X, COORD_Y+22*i, ANCHOR_LEFT_UPPER, pixels_array, res_width, res_height, ColorToARGB(clrDodgerBlue), COLOR_FORMAT_ARGB_NORMALIZE);
Update(RES_NAME, pixels_array, res_width, res_height, true);
//--- подождём немного
Sleep(800);
}
}
//+------------------------------------------------------------------+
//| Возвращает описание флагов начертания шрифта |
//+------------------------------------------------------------------+
string FlagDescription(const uint flag)
{
switch(flag)
{
case FONT_ITALIC : return(" Italic");
case FONT_UNDERLINE : return(" Underline");
case FONT_STRIKEOUT : return(" Strikeout");
}
return("");
}
//+------------------------------------------------------------------+
//| Возвращает описание флагов толщины шрифта |
//+------------------------------------------------------------------+
string FlagWidthDescription(const uint flag)
{
switch(flag)
{
case FW_DONTCARE : return(" Dontcare");
case FW_THIN : return(" Thin");
case FW_EXTRALIGHT: return(" Extralight");
case FW_ULTRALIGHT: return(" Ultralight");
case FW_LIGHT : return(" Light");
case FW_NORMAL : return(" Normal");
case FW_REGULAR : return(" Regular");
case FW_MEDIUM : return(" Medium");
case FW_SEMIBOLD : return(" Semibold");
case FW_DEMIBOLD : return(" Demibold");
case FW_BOLD : return(" Bold");
case FW_EXTRABOLD : return(" Extrabold");
case FW_ULTRABOLD : return(" Ultrabold");
case FW_HEAVY : return(" Heavy");
case FW_BLACK : return(" Black");
}
return("");
}
//+------------------------------------------------------------------+
//| Создаёт графический ресурс на весь график |
//+------------------------------------------------------------------+
bool CreateResource(const long chart_id, uint &pixel_data[], const uint width, const uint height)
{
//--- устанавливаем размер массива пикселей
ResetLastError();
uint size=width*height;
if(ArrayResize(pixel_data, size)!=size)
{
PrintFormat("%s: ArrayResize() failed. Error code %d",__FUNCTION__, GetLastError());
return(false);
}
//--- заполняем массив пикселей прозрачным цветом и на его основе создаём графический ресурс
ArrayInitialize(pixel_data, COLOR_NULL);
if(!ResourceCreate(RES_NAME, pixel_data, width, height, 0, 0, 0, COLOR_FORMAT_ARGB_NORMALIZE))
{
PrintFormat("%s: ResourceCreate() failed. Error code ",__FUNCTION__, GetLastError());
return(false);
}
//--- создаём объект "Графическая метка" на координатах верхнего левого угла графика
if(!ObjectCreate(0, OBJ_NAME, OBJ_BITMAP_LABEL, 0, 0, 0))
{
PrintFormat("%s: ObjectCreate() failed. Error code %d",__FUNCTION__, GetLastError());
return(false);
}
//--- устанавливаем созданному объекту-рисунку ширину и высоту, равные ширине и высоте графического ресурса.
//--- устанавливаем точку привязки объекта по его центру.
if(!ObjectSetInteger(chart_id, OBJ_NAME, OBJPROP_XSIZE, width))
{
PrintFormat("%s: ObjectSetInteger() failed. Error code %d",__FUNCTION__, GetLastError());
return(false);
}
if(!ObjectSetInteger(chart_id, OBJ_NAME, OBJPROP_YSIZE, height))
{
PrintFormat("%s: ObjectSetInteger() failed. Error code %d",__FUNCTION__, GetLastError());
return(false);
}
//--- указываем для объекта-рисунка в качестве файла изображения ранее созданный графический ресурс
//--- в этом случае для указания имени используемого графического ресурса нужно перед его именем дописать "::"
if(!ObjectSetString(chart_id, OBJ_NAME, OBJPROP_BMPFILE, "::"+RES_NAME))
{
PrintFormat("%s: ObjectSetString() failed. Error code %d",__FUNCTION__, GetLastError());
return(false);
}
//--- всё успешно
return(true);
}
//+------------------------------------------------------------------+
//| Обновляет данные графического ресурса |
//+------------------------------------------------------------------+
void Update(const string res_name, const uint &pixel_data[], const uint width, const uint height, const bool redraw)
{
//--- если переданы нулевые размеры - уходим
if(width==0 || height==0)
return;
//--- обновляем ресурсные данные и перерисовываем график
if(ResourceCreate(res_name, pixel_data, width, height, 0, 0, 0, COLOR_FORMAT_ARGB_NORMALIZE) && redraw)
ChartRedraw();
}
|