DRAW_ARROW

O estilo DRAW_ARROW desenha setas de cor específica (símbolos do conjunto Wingdings) baseado no valor do buffer do indicador. A largura e a cor dos símbolos pode ser especificado semelhante ao modelo DRAW_LINE - usando diretivas de compilador ou dinamicamente usando a função PlotIndexSetInteger(). Mudanças dinâmicas das propriedades de plotagem permitem alterar o visual de um indicador baseado na situação atual.

O código de símbolo é definido usando a propriedade PLOT_ARROW.

//--- Definir o código símbolo a partir das fontes Wingdings para desenhar em PLOT_ARROW
   PlotIndexSetInteger(0,PLOT_ARROW,code);

O valor padrão do PLOT_ARROW=159 (um círculo).

Cada seta é na verdade um símbolo que tem a altura e o ponto de ancoragem e pode abranger algumas informações importantes num gráfico (por exemplo, o preço de fechamento da barra). Assim, podemos adicionalmente especificar o deslocamento vertical em pixels, o qual não depende da escala do gráfico. As setas serão deslocadas para baixo pelo número especificado de pixels, embora os valores do indicador permanecerão os mesmos:

//--- Definir o deslocamento vertical das setas em pixels
   PlotIndexSetInteger(0,PLOT_ARROW_SHIFT,shift);

Um valor negativo de PLOT_ARROW_SHIFT significa a mudança de setas para cima, valores positivos deslocam a seta para baixo.

O estilo DRAW_ARROW pode ser usado numa sub-janela separada de um gráfico e em sua janela principal. Valores vazios não são desenhados e não aparecem na "Janela de Dados", todos os valores nos buffers do indicador devem ser definidos explicitamente. Buffers não são inicializados com o valor zero.

//--- Definir um valor vazio
   PlotIndexSetDouble(index_of_plot_DRAW_ARROW,PLOT_EMPTY_VALUE,0);

O número de buffers necessários para plotagem DRAW_ARROW é 1.

Um exemplo de indicador que desenha as setas em cada uma das barras com o preço mais alto do que o preço final da barra anterior. A cor, a largura, deslocamento e símbolo de código de todas setas são alterados aleatoriamente a cada N ticks.

Um exemplo do estilo DRAW_ARROW

No exemplo, para plot1 com o estilo DRAW_ARROW, as propriedades, a cor e o tamanho são especificados usando a diretiva de compilador #property, e depois na função OnCalculate() as propriedades são definidas aleatoriamente. O parâmetro N é definido nos parâmetros externos do indicador para a possibilidade de configuração manual (o guia Parâmetros na janela Propriedades do indicador).

//+------------------------------------------------------------------+
//|                                                   DRAW_ARROW.mq5 |
//|                         Copyright 2000-2024, MetaQuotes Ltd. |
//|                                              https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
 
#property description "Um indicador para demonstrar DRAW_ARROW"
#property description "Desenha setas definidas pelos caracteres Unicode, sobre um gráfico"
#property description "A cor, o tamanho, deslocamento e código símbolo da seta, são alterados de forma aleatória"
#property description "depois de cada N ticks"
#property description "O parâmetro de código define o valor da base: código = 159 (um círculo)"
 
#property indicator_chart_window
#property indicator_buffers 1
#property indicator_plots   1
//--- Plotagem de Setas
#property indicator_label1  "Setas"
#property indicator_type1   DRAW_ARROW
#property indicator_color1  clrGreen
#property indicator_width1  1
//--- parâmetros de entrada
input int      N=5;         // Número de ticks para mudar
input ushort   code=159;    // Código símbolo para desenhar em DRAW_ARROW
//--- Um buffer do indicador para plotar
double         ArrowsBuffer[];
//--- Um array para armazenar as cores
color colors[]={clrRed,clrBlue,clrGreen};
//+------------------------------------------------------------------+
//| Função de inicialização do indicador customizado                 |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- mapeamento de buffers do indicador
   SetIndexBuffer(0,ArrowsBuffer,INDICATOR_DATA);
//--- Definir o código símbolo para desenho em PLOT_ARROW
   PlotIndexSetInteger(0,PLOT_ARROW,code);
//--- Definir o deslocamento vertical das setas em pixels
   PlotIndexSetInteger(0,PLOT_ARROW_SHIFT,5);
//--- Definir como um valor vazio 0
   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0);
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Função de iteração do indicador customizado                      |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
   static int ticks=0;
//--- Calcular ticks para mudar a cor, tamanho, deslocamento e código da seta
   ticks++;
//--- Se um número crítico de ticks tem sido acumulado
   if(ticks>=N)
     {
      //--- Alterar as propriedades da linha
      ChangeLineAppearance();
      //--- Redefinir o contador de ticks para zero
      ticks=0;
     }
 
//--- Bloco para cálculo dos valores do indicador
   int start=1;
   if(prev_calculated>0) start=prev_calculated-1;
//--- Calculando loop
   for(int i=1;i<rates_total;i++)
     {
      //--- Se o preço atual fechado é mais alto do que o anterior, desenhar uma seta
      if(close[i]>close[i-1])
         ArrowsBuffer[i]=close[i];
      //--- Otherwise specify the zero value
      else
         ArrowsBuffer[i]=0;
     }
//--- valor retorno de prev_calculated para a próxima chamada
   return(rates_total);
  }
//+------------------------------------------------------------------+
//| Alterar a aparência dos símbolos no indicador                    |
//+------------------------------------------------------------------+
void ChangeLineAppearance()
  {
//--- Uma string para formar as informações sobre as propriedades do indicador
   string comm="";
//--- Um bloco para alterar a cor da seta
   int number=MathRand(); // Obter um número aleatório
//--- O divisor é igual ao tamanho do array colors[]
   int size=ArraySize(colors);
//--- Obter o índice para selecionar uma nova cor como o restante da divisão inteira
   int color_index=number%size;
//--- Definir a cor com a propriedade PLOT_LINE_COLOR
   PlotIndexSetInteger(0,PLOT_LINE_COLOR,colors[color_index]);
//--- Escrever a cor da linha
   comm=comm+"\r\n"+(string)colors[color_index];
 
//--- Um bloco para mudar o tamanho das setas
   number=MathRand();
//--- Obter a largura do restante da divisão inteira
   int width=number%5;   // O tamanho é definido a partir de 0 até 4
//--- Definir a cor com a propriedade PLOT_LINE_WIDTH
   PlotIndexSetInteger(0,PLOT_LINE_WIDTH,width);
//--- Escrever a cor da linha
   comm=comm+"\r\nWidth="+IntegerToString(width);
 
//--- Um bloco para mudar o código das setas (PLOT_ARROW)
   number=MathRand();
//--- Obter o restante da divisão de número inteiro para calcular um novo código da seta(a partir de 0 até 19)
   int code_add=number%20;
//--- Definir o novo símbolo de código como o resultado de code+code_add
   PlotIndexSetInteger(0,PLOT_ARROW,code+code_add);
//--- Escreva o código de símbolo PLOT_ARROW
   comm="\r\n"+"PLOT_ARROW="+IntegerToString(code+code_add)+comm;
 
//--- Um bloco de mudança do deslocamento vertical das setas em pixels
   number=MathRand();
//--- Obter o deslocamento como o restante da divisão inteira
   int shift=20-number%41;
//--- Definir o deslocamento novo de -20 a 20
   PlotIndexSetInteger(0,PLOT_ARROW_SHIFT,shift);
//--- Escrever o deslocamento PLOT_ARROW_SHIFT
   comm="\r\n"+"PLOT_ARROW_SHIFT="+IntegerToString(shift)+comm;
 
//--- Mostrar a informação no gráfico usando um comentário
   Comment(comm);
  }