DRAW_ARROW

Стиль DRAW_ARROW рисует на графике заданным цветом стрелки (символы  из набора Wingdings) по значению индикаторного буфера. Толщину и цвет символов можно задавать так же, как и для стиля DRAW_LINEдирективами компилятора или динамически с помощью функции PlotIndexSetInteger(). Динамическое изменение свойств графического построения позволяет изменять вид индикатора в зависимости от  текущей ситуации.

Код символа для вывода на график задается с помощью свойства PLOT_ARROW.

//--- зададим код символа из шрифта Wingdings для отрисовки в PLOT_ARROW
   PlotIndexSetInteger(0,PLOT_ARROW,code);

По умолчанию значение PLOT_ARROW=159 (кружок).

Каждая стрелка фактически представляет собой символ, который имеет высоту и точку привязки, и может закрывать собою некоторую важную информацию на графике (например, цену закрытия на баре). Поэтому можно дополнительно  указать вертикальное смещение в пикселях, которое не зависит от масштаба графика. На это указанное количество пикселей стрелки будут визуально смещены по вертикали, хотя сами значения индикатора останутся те же самые:

//--- зададим cмещение стрелок по вертикали в пикселях
   PlotIndexSetInteger(0,PLOT_ARROW_SHIFT,shift);

Отрицательное значение PLOT_ARROW_SHIFT означает смещение стрелок вверх, положительное значение смещает стрелки вниз.

Стиль DRAW_ARROW можно использовать как в отдельном подокне графика, так и в главном окне. Пустые значения не отрисовываются и не отображаются в "Окне данных", все значения в индикаторных буферах нужно устанавливать явным образом. Инициализация буферов пустым значением не производится.

//--- установим пустое значение
   PlotIndexSetDouble(индекс_построения_DRAW_ARROW,PLOT_EMPTY_VALUE,0);

Количество требуемых буферов для построения DRAW_ARROW — 1.

Пример индикатора, рисующего стрелки на каждом баре, у которого цена закрытия Close больше цены закрытия предыдущего бара.  Цвет, толщина, смещение и код символа всех стрелок меняются случайным образом каждые N тиков.

Пример стиля DRAW_ARROW

В примере первоначально для графического построения plot1 со стилем DRAW_ARROW свойства, цвет и размер задаются с помощью директивы компилятора #property, а затем в функции OnCalculate() свойства задаются случайным образом. Параметр N вынесен во внешние параметры индикатора для возможности ручной установки (закладка "Параметры" в окне свойств индикатора).

//+------------------------------------------------------------------+
//|                                                   DRAW_ARROW.mq5 |
//|                        Copyright 2011, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
 
#property description "Индикатор для демонстрации DRAW_ARROW"
#property description "Рисует на графике стрелки, задаваемые символами Unicode"
#property description "Цвет, размер, смещение и код символа стрелки меняется случайным образом"
#property description "через каждые N тиков"
#property description "Параметр code задает базовое значение: код=159 (кружок)"
 
#property indicator_chart_window
#property indicator_buffers 1
#property indicator_plots   1
//--- plot Arrows
#property indicator_label1  "Arrows"
#property indicator_type1   DRAW_ARROW
#property indicator_color1  clrGreen
#property indicator_width1  1
//--- input параметры
input int      N=5;         // кол-во тиков для изменения 
input ushort   code=159;    // код символа для отрисовки в DRAW_ARROW
//--- индикаторный буфер для построения 
double         ArrowsBuffer[];
//--- массив для хранения цветов
color colors[]={clrRed,clrBlue,clrGreen};
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- indicator buffers mapping
   SetIndexBuffer(0,ArrowsBuffer,INDICATOR_DATA);
//--- зададим код символа для отрисовки в PLOT_ARROW
   PlotIndexSetInteger(0,PLOT_ARROW,code);
//--- зададим cмещение стрелок по вертикали в пикселях 
   PlotIndexSetInteger(0,PLOT_ARROW_SHIFT,5);
//--- установим в качестве пустого значения 0
   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0);
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
   static int ticks=0;
//--- считаем тики для изменения цвета, размера, смешения и кода стрелки
   ticks++;
//--- если накопилось критическое число тиков
   if(ticks>=N)
     {
      //--- меняем свойства линии
      ChangeLineAppearance();
      //--- сбрасываем счетчик тиков в ноль
      ticks=0;
     }
 
//--- блок расчета значений индикатора
   int start=1;
   if(prev_calculated>0) start=prev_calculated-1;
//--- цикл расчета
   for(int i=1;i<rates_total;i++)
     {
      //--- если текущая цена Close больше предыдущей, ставим стрелку
      if(close[i]>close[i-1])
         ArrowsBuffer[i]=close[i];
      //--- в противном случае указываем нулевое значение
      else
         ArrowsBuffer[i]=0;
     }
//--- return value of prev_calculated for next call
   return(rates_total);
  }
//+------------------------------------------------------------------+
//| Изменяет внешний вид символов в индикаторе                       |
//+------------------------------------------------------------------+
void ChangeLineAppearance()
  {
//--- строка для формирования информации о свойствах индикатора
   string comm="";
//--- блок изменения цвета cтрелки
   int number=MathRand(); // получим случайное число
//--- делитель числа равен размеру массива colors[]
   int size=ArraySize(colors);
//--- получим индекс для выбора нового цвета как остаток от целочисленного деления
   int color_index=number%size;
//--- установим цвет как свойство PLOT_LINE_COLOR
   PlotIndexSetInteger(0,PLOT_LINE_COLOR,colors[color_index]);
//--- запишем цвет линии
   comm=comm+"\r\n"+(string)colors[color_index];
 
//--- блок изменения размера стрелок
   number=MathRand();
//--- получим толщину как остаток от целочисленного деления
   int width=number%5;   // размер задается от 0 до 4
//--- установим цвет как свойство PLOT_LINE_WIDTH
   PlotIndexSetInteger(0,PLOT_LINE_WIDTH,width);
//--- запишем размер стрелок
   comm=comm+"\r\nWidth="+IntegerToString(width);
 
//--- блок изменения кода стрелки (PLOT_ARROW)
   number=MathRand();
//--- получим остаток от целочисленного деления для вычисления нового кода стрелки (от 0 до 19)
   int code_add=number%20;
//--- установим новый код символа как сумму code+code_add
   PlotIndexSetInteger(0,PLOT_ARROW,code+code_add);
//--- запишем код символа PLOT_ARROW
   comm="\r\n"+"PLOT_ARROW="+IntegerToString(code+code_add)+comm;
 
//--- блок изменения смещения стрелок по вертикали в пикселях
   number=MathRand();
//--- получим смещение как остаток от целочисленного деления
   int shift=20-number%41;
//--- установим новое смещение от -20 до 20
   PlotIndexSetInteger(0,PLOT_ARROW_SHIFT,shift);
//--- запишем смещение PLOT_ARROW_SHIFT
   comm="\r\n"+"PLOT_ARROW_SHIFT="+IntegerToString(shift)+comm;
 
//--- выведем информацию на график через комментарий
   Comment(comm);
  }