DRAW_CANDLES

O estilo DRAW_CANDLES desenha candlesticks sobre os valores dos quatro buffers do indicador, que contêm Open (abertura), High (alta), Low (baixa) e Close (fechamento) de preços. É usado para a criação de indicadores personalizados como uma seqüência de candlesticks, incluindo os inseridos numa sub-janela separada de um gráfico e noutros instrumentos financeiros.

A cor dos candlesticks pode ser definida usando as diretivas de compilador ou dinamicamente usando a função PlotIndexSetInteger(). Mudanças dinâmicas das propriedades de plotagem permitem "avivar" os indicadores, de modo que suas mudanças de aparência dependem da situação corrente.

O indicador é desenhado apenas para as barras, para o qual os valores não vazios de todos quatro buffers do indicador são definidos. Para especificar o valor que deve ser considerado como "vazio", defina este valor na propriedade PLOT_EMPTY_VALUE:

//--- O valor 0 (vazio) não vai participar no desenho
   PlotIndexSetDouble(index_of_plot_DRAW_CANDLES,PLOT_EMPTY_VALUE,0);

Sempre preencher explicitamente os valores dos buffers do indicador, definir um valor vazio num buffer para ignorar barras.

O número de buffers necessários para plotagem de DRAW_CANDLES é 4. Todos os buffers para a plotagem devem ir um após o outro na ordem dada: Open (abertura do preço), High (alta do preço), Low (baixa do preço) e Close (fechamento do preço). Nenhum dos buffers podem conter apenas valores vazios, uma vez que, neste caso, nada é plotado.

Para o estilo DRAW_CANDLES, é possível definir de uma a três cores, dependendo de isso é alterada a aparência das velas. Se for definida apenas uma cor, todas as velas no gráfico serão pintadas completamente com essa cor.

//--- velas semelhantes pintadas numa cor
#property indicator_label1  "One color candles"
#property indicator_type1   DRAW_CANDLES
//--- como é indicada apenas uma cor, todas as velas terão uma cor
#property indicator_color1  clrGreen  

Si nós especificarmos duas cores separadas por uma vírgula, os contornos das velas serão desenhados com a primeira cor e o corpo com a segunda.

//--- a cor das velas é diferente da cor das sombras
#property indicator_label1  "Two color candles"
#property indicator_type1   DRAW_CANDLES
//--- sombras e contornos das velas de cor verde e corpo branco
#property indicator_color1  clrGreen,clrWhite 

Para exibir de maneira diferente as velas crescentes e decrescentes, é indispensável definir, separando por vírgulas, três cores. Neste caso, o contorno da vela será traçado usando a primeira cor, enquanto a cor da velas de alta e baixa serão definidas pela segunda e terceira cor.

//--- a cor das velas é diferente da cor das sombras
#property indicator_label1  "One color candles"
#property indicator_type1   DRAW_CANDLES
//--- sombras e contorno de cor verde, corpo da vela de alta de cor branca, corpo da vela de baixa de cor vermelha
#property indicator_color1  clrGreen,clrWhite,clrRed

Assim, usando o estilo DRAW_CANDLES, é possível criar variantes personalizadas das velas. Também é possível alterar dinamicamente todas as cores -no processo de trabalho do indicador- mediante a função PlotIndexSetInteger(índice_de_construção_DRAW_CANDLES, PLOT_LINE_COLOR, número_de_modificador, cor), aqui o número_de_modificador pode ter os seguintes valores:

  • 0 — cor do contorno e sombras
  • 1— cor do corpo da vela de alta
  • 2 — cor do corpo da vela de baixa

//--- definimos a cor do contorno e sombras
PlotIndexSetInteger(0,PLOT_LINE_COLOR,0,clrBlue);
//--- definimos a cor do corpo para velas de alta
PlotIndexSetInteger(0,PLOT_LINE_COLOR,1,clrGreen);
//--- definimos a cor do corpo para velas de baixa
PlotIndexSetInteger(0,PLOT_LINE_COLOR,2,clrRed);

Um exemplo de indicador que desenha candlesticks para um instrumento financeiro selecionado em uma janela separada. A cor dos candlesticks muda aleatoriamente a cada N ticks. O parâmetro N é definido nos parâmetro externos do indicador para a possibilidade de configuração manual (na guia Parâmetros na janela Propriedades do indicador).

Um exemplo do estilo DRAW_CANDLES

Por favor, note que para plot1, a cor é definida usando a diretiva de compilador #property, e então, na função OnCalculate() a cor é definida aleatoriamente a partir de uma lista preparada anteriormente.

//+------------------------------------------------------------------+
//|                                                 DRAW_CANDLES.mq5 |
//|                         Copyright 2000-2024, MetaQuotes Ltd. |
//|                                              https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
 
#property description "Um indicador para demonstrar DRAW_CANDLES."
#property description "ele desenha candlesticks de um símbolo selecionado numa janela separada"
#property description " "
#property description "A cor e a largura dos candlesticks, bem como o símbolo são alterados"
#property description "aleatoriamente a cada N ticks"
 
#property indicator_separate_window
#property indicator_buffers 4
#property indicator_plots   1
//--- plotar Barras
#property indicator_label1  "DRAW_CANDLES1"
#property indicator_type1   DRAW_CANDLES
#property indicator_color1  clrGreen
#property indicator_style1  STYLE_SOLID
#property indicator_width1  1
 
//--- parâmetros de entrada
input int      N=5;              // O número de ticks para alterar o tipo
input int      bars=500;         // O número de barras para mostrar
input bool     messages=false;   // Mostrar mensagens no log "Expert Advisors" 
//--- buffers do Indicador
double         Candle1Buffer1[];
double         Candle1Buffer2[];
double         Candle1Buffer3[];
double         Candle1Buffer4[];
//--- Nome do símbolo
string symbol;
//--- Um array para armazenar as cores
color colors[]={clrRed,clrBlue,clrGreen,clrPurple,clrBrown,clrIndianRed};
//+------------------------------------------------------------------+
//| Função de inicialização do indicador customizado                 |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- Se as barras são muito pequenas - concluir o trabalho antes do tempo
   if(bars<50)
     {
      Comment("Por favor, especifique um número maior de barras! A operação do indicador foi terminada");
      return(INIT_PARAMETERS_INCORRECT);
     }
//--- mapeamento de buffers do indicador
   SetIndexBuffer(0,Candle1Buffer1,INDICATOR_DATA);
   SetIndexBuffer(1,Candle1Buffer2,INDICATOR_DATA);
   SetIndexBuffer(2,Candle1Buffer3,INDICATOR_DATA);
   SetIndexBuffer(3,Candle1Buffer4,INDICATOR_DATA);
//--- Um valor vazio
   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0);
//--- O nome do símbolo, para o qual as barras são desenhadas
   symbol=_Symbol;
//--- Definir a exibição do símbolo
   PlotIndexSetString(0,PLOT_LABEL,symbol+" Open;"+symbol+" High;"+symbol+" Low;"+symbol+" Close");
   IndicatorSetString(INDICATOR_SHORTNAME,"DRAW_CANDLES("+symbol+")");
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Função de iteração do indicador customizado                      |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
   static int ticks=INT_MAX-100;
//--- Calcule ticks para mudar o estilo, cor e largura da linha
   ticks++;
//--- Se um número suficiente de ticks foi acumulado
   if(ticks>=N)
     {
      //--- Selecione um novo símbolo a partir da janela de observação do Mercado
      symbol=GetRandomSymbolName();
      //--- Alterar a forma
      ChangeLineAppearance();
      //--- Selecione um novo símbolo a partir da janela de observação do Mercado
      int tries=0;
      //--- Faça 5 tentativas de preencher os buffers de Plot1 com os preços a partir da símbolo
      while(!CopyFromSymbolToBuffers(symbol,rates_total,0,
            Candle1Buffer1,Candle1Buffer2,Candle1Buffer3,Candle1Buffer4)
            && tries<5)
        {
         //--- Um contador de chamadas da função CopyFromSymbolToBuffers()
         tries++;
        }
      //--- Redefinir o contador de ticks para zero
      ticks=0;
     }
//--- valor retorno de prev_calculated para a próxima chamada
   return(rates_total);
  }
//+------------------------------------------------------------------+
//| Preenche o candlestick especificado                              |
//+------------------------------------------------------------------+
bool CopyFromSymbolToBuffers(string name,
                             int total,
                             int plot_index,
                             double &buff1[],
                             double &buff2[],
                             double &buff3[],
                             double &buff4[]
                             )
  {
//--- No array de rates[], vamos copiar Open (abertura), High (alta), Low (baixa) e Close (fechamento) de preços
   MqlRates rates[];
//--- O contador de tentativas
   int attempts=0;
//--- Quanto foi copiado
   int copied=0;
//--- Fazer 25 tentativas para obter uma série temporal(timeseries) sobre o símbolo desejado
   while(attempts<25 && (copied=CopyRates(name,_Period,0,bars,rates))<0)
     {
      Sleep(100);
      attempts++;
      if(messagesPrintFormat("%s Copiar taxas(%s) tentativas=%d",__FUNCTION__,nome,tentativas);
     }
//--- Se falhou em copiar um número suficiente de barras
   if(copied!=bars)
     {
      //--- Formar uma mensagem string
      string comm=StringFormat("Para o símbolo %s, conseguiu receber somente %d barras de %d solicitadas",
                               name,
                               copied,
                               bars
                               );
      //--- Mostrar uma mensagem num comentário na janela do gráfico principal
      Comment(comm);
      //--- Mostrar a mensagem
      if(messagesPrint(comm);
      return(false);
     }
   else
     {
      //--- Definir a exibição do símbolo
      PlotIndexSetString(plot_index,PLOT_LABEL,name+" Open;"+name+" High;"+name+" Low;"+name+" Close");
     }
//--- Inicializar buffers com valores vazios
   ArrayInitialize(buff1,0.0);
   ArrayInitialize(buff2,0.0);
   ArrayInitialize(buff3,0.0);
   ArrayInitialize(buff4,0.0);
//--- Sobre cada tick é copiado preços para os buffers
   for(int i=0;i<copied;i++)
     {
      //--- Calcular o índice apropriado para os buffers
      int buffer_index=total-copied+i;
      //--- Escreva os preços para os buffers
      buff1[buffer_index]=rates[i].open;
      buff2[buffer_index]=rates[i].high;
      buff3[buffer_index]=rates[i].low;
      buff4[buffer_index]=rates[i].close;
     }
   return(true);
  }
//+------------------------------------------------------------------+
//| Aleatoriamente retorna um símbolo de Observação do Mercado   |
//+------------------------------------------------------------------+
string GetRandomSymbolName()
  {
//--- O número de símbolos mostrada na janela de observação do Mercado
   int symbols=SymbolsTotal(true);
//--- A posição de um símbolo na lista - um número aleatório de 0 para símbolos
   int number=MathRand()%symbols;
//--- Retornar o nome de um símbolo na posição especificada
   return SymbolName(number,true);
  }
//+------------------------------------------------------------------+
//| Altera a aparência das barras                                        |
//+------------------------------------------------------------------+
void ChangeLineAppearance()
  {
//--- Uma string para a formação de informações sobre as propriedades da barra
   string comm="";
//--- Um bloco para alterar a cor das barras
   int number=MathRand(); // Obter um número aleatório
//--- O divisor é igual ao tamanho do array colors[]
   int size=ArraySize(colors);
//--- Obter o índice para selecionar uma nova cor como o restante da divisão inteira
   int color_index=number%size;
//--- Definir a cor com a propriedade PLOT_LINE_COLOR
   PlotIndexSetInteger(0,PLOT_LINE_COLOR,colors[color_index]);
//--- Escrever a cor
   comm=comm+"\r\n"+(string)colors[color_index];
//--- Escreve o nome do símbolo
   comm="\r\n"+symbol+comm;
//--- Mostrar a informação no gráfico usando um comentário
   Comment(comm);
  }