DRAW_COLOR_LINE

O valor DRAW_COLOR_LINE é uma variante colorida do estilo DRAW_LINE; ele também desenha uma linha usando os valores do buffer do indicador. Mas esse estilo, como todos os estilos de cores com a palavra COLOR em seu título tem um buffer indicador adicional e especial que armazena o índice de cores (número) a partir de um conjunto especial array de cores. Assim, a cor de cada segmento de linha pode ser definida através da especificação do índice de cores para desenhar a linha naquela barra.

A largura, o estilo e as cores das linhas podem ser definidas usando as diretivas de compilador e dinamicamente usando a função PlotIndexSetInteger(). Mudanças dinâmicas das propriedades de plotagem permitem "avivar" os indicadores, de modo que suas mudanças de aparência dependem da situação corrente.

O número de buffers requerido para plotagem de DRAW_COLOR_LINE é 2.

  • um buffer para armazenar os valores do indicador utilizado para desenhar uma linha;
  • um buffer para armazenar o índice de cores da linha em cada barra.

Cores serão especificadas pela diretiva de compilador #property indicator_color1 separada por uma vírgula. O número de cores não pode exceder a 64.

//--- Define 5 cores para colorir cada barra (elas são armazenadas no array especial)
#property indicator_color1  clrRed,clrBlue,clrGreen,clrOrange,clrDeepPink // (Podem ser especificados até 64 cores)

Um exemplo do indicador que desenha a linha usando o fechamento de preço das barras. A largura da linha e estilo são alterados aleatoriamente a cada N=5 ticks.

Um exemplo do estilo DRAW_COLOR_LINE

As cores dos segmentos de linhas também são alteradas aleatoriamente na função personalizada ChangeColors().

//+------------------------------------------------------------------+
//| Altera a cor dos segmentos de linha                              |
//+------------------------------------------------------------------+
void  ChangeColors(color  &cols[],int plot_colors)
  {
//--- O número de cores
   int size=ArraySize(cols);
//--- 
   string comm=ChartGetString(0,CHART_COMMENT)+"\r\n\r\n";
 
//--- Para cada índice de cor definir uma nova cor aleatoriamente
   for(int plot_color_ind=0;plot_color_ind<plot_colors;plot_color_ind++)
     {
      //--- Obter um valor aleatório
      int number=MathRand();
      //--- Obter um índice no array col[] como um resto da divisão inteira
      int i=number%size;
      //--- Definir a cor para cada índice com a propriedade PLOT_LINE_COLOR
      PlotIndexSetInteger(0,                    //  O número do estilo gráfico
                          PLOT_LINE_COLOR,      //  Identificador da propriedade
                          plot_color_ind,       //  O índice da cor, onde se escreve a cor
                          cols[i]);             //  Uma nova cor
      //--- Escrever as cores
      comm=comm+StringFormat("LineColorIndex[%d]=%s \r\n",plot_color_ind,ColorToString(cols[i],true));
      ChartSetString(0,CHART_COMMENT,comm);
     }
//---
  }

O exemplo mostra a característica das versões "cor" de indicadores - para mudar a cor de um segmento de linha, você não precisa alterar os valores no buffer ColorLineColors[] (que contém os índices de cores). Tudo que você precisa fazer é definir novas cores em um array especial. Isto permite-lhe alterar rapidamente a cor de uma vez para toda a plotagem, mudando apenas um pequeno array de cores utilizando a função PlotIndexSetInteger().

Note que para inicializar plot1 com DRAW_COLOR_LINE as propriedades são definidas usando a diretiva de compilador #property, e então na função OnCalculate() existem três propriedades que são definidas aleatoriamente.

O N e Length (o comprimento dos segmentos de corres nas barras) dos parâmetros são definidos nos parâmetros externos do indicador para a possibilidade de configuração manual (a guia Parâmetros na janela Propriedades do indicador).

//+------------------------------------------------------------------+
//|                                              DRAW_COLOR_LINE.mq5 |
//|                        Copyright 2011, MetaQuotes Software Corp. |
//|                                              https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
 
#property description "Um indicador para demonstrar RAW_COLOR_LINE"
#property description "Ele desenha uma linha no Fechamento do preço em partes coloridas de cada 20 barras"
#property description "A largura, estilo e cor de partes da linha são alteradas aleatoriamente "
#property description "cada N ticks"
 
#property indicator_chart_window
#property indicator_buffers 2
#property indicator_plots   1
//--- plotar ColorLine
#property indicator_label1  "ColorLine"
#property indicator_type1   DRAW_COLOR_LINE
//--- Define 5 cores para colorir cada barra (elas são armazenadas no array especial)
#property indicator_color1  clrRed,clrBlue,clrGreen,clrOrange,clrDeepPink // (Podem ser especificados até 64 cores)
#property indicator_style1  STYLE_SOLID
#property indicator_width1  1
//--- parâmetros de entrada
input int      N=5;           //Número de ticks para alterar 
input int      Length=20;     // A largura de cada parte de cor nas barras
int            line_colors=5; // O número para definir as cores é 5 - ver #property indicator_color1
//--- Um buffer para plotagem
double         ColorLineBuffer[];
//--- Um buffer para armazenar a cor da linha sobre cada barra
double         ColorLineColors[];
 
//--- O array para armazenar cores contendo 7 elementos
color colors[]={clrRed,clrBlue,clrGreen,clrChocolate,clrMagenta,clrDodgerBlue,clrGoldenrod};
//--- Um array para armazenar os estilos de linha
ENUM_LINE_STYLE styles[]={STYLE_SOLID,STYLE_DASH,STYLE_DOT,STYLE_DASHDOT,STYLE_DASHDOTDOT};
//+------------------------------------------------------------------+
//| Função de inicialização do indicador customizado                 |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- Ligando um array e um buffer de indicador
   SetIndexBuffer(0,ColorLineBuffer,INDICATOR_DATA);
   SetIndexBuffer(1,ColorLineColors,INDICATOR_COLOR_INDEX);
//--- Inicializando o gerador de números pseudo-aleatórios
   MathSrand(GetTickCount());
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Função de iteração do indicador customizado                      |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
   static int ticks=0;
//--- Calcule ticks para mudar o estilo, cor e largura da linha
   ticks++;
//--- Se um número crítico de ticks tem sido acumulado
   if(ticks>=N)
     {
      //--- Alterar as propriedades da linha
      ChangeLineAppearance();
      //--- Alterar as cores de seções de linhas
      ChangeColors(colors,5);
      //--- Redefinir o contador de ticks para zero
      ticks=0;
     }
 
//--- Bloco para cálculo dos valores do indicador
   for(int i=0;i<rates_total;i++)
     {
      //--- Escrever o valor do indicador para o buffer
      ColorLineBuffer[i]=close[i];
      //--- Agora, aleatoriamente definir um índice de cores para esta barra
      int color_index=i%(5*Length);
      color_index=color_index/Length;
      //--- Para esta barra, a linha terá a cor com o índice color_index
      ColorLineColors[i]=color_index;
     }
 
//--- Retorna o valor de prev_calculated para a próxima chamada da função
   return(rates_total);
  }
//+------------------------------------------------------------------+
//| Altera a cor dos segmentos de linha                              |
//+------------------------------------------------------------------+
void  ChangeColors(color  &cols[],int plot_colors)
  {
//--- O número de cores
   int size=ArraySize(cols);
//--- 
   string comm=ChartGetString(0,CHART_COMMENT)+"\r\n\r\n";
 
//--- Para cada índice de cor definir uma nova cor aleatoriamente
   for(int plot_color_ind=0;plot_color_ind<plot_colors;plot_color_ind++)
     {
      //--- Obter um valor aleatório
      int number=MathRand();
      //--- Obter um índice no array col[] como um resto da divisão inteira
      int i=number%size;
      //--- Definir a cor para cada índice com a propriedade PLOT_LINE_COLOR
      PlotIndexSetInteger(0,                    //  O número do estilo gráfico
                          PLOT_LINE_COLOR,      //  Identificador da propriedade
                          plot_color_ind,       //  O índice da cor, onde se escreve a cor
                          cols[i]);             //  Uma nova cor
      //--- Escrever as cores
      comm=comm+StringFormat("LineColorIndex[%d]=%s \r\n",plot_color_ind,ColorToString(cols[i],true));
      ChartSetString(0,CHART_COMMENT,comm);
     }
//---
  }
//+------------------------------------------------------------------+
//| Altera a aparência de uma linha visualizada no indicador         |
//+------------------------------------------------------------------+
void ChangeLineAppearance()
  {
//--- Uma string para a formação de informações sobre as propriedades de linha
   string comm="";
//--- Um bloco para alterar a largura da linha
   int number=MathRand();
//--- Obter a largura do restante da divisão inteira
   int width=number%5; // A largura é definida de 0 a 4
//--- Definir a cor com a propriedade PLOT_LINE_WIDTH
   PlotIndexSetInteger(0,PLOT_LINE_WIDTH,width);
//--- Escrever a largura da linha
   comm=comm+" Width="+IntegerToString(width);
 
//--- Um bloco para mudar o estilo da linha
   number=MathRand();
//--- O divisor é igual ao tamanho do array de estilos
   int size=ArraySize(styles);
//--- Obter o índice para selecionar um novo estilo como o resto da divisão inteira
   int style_index=number%size;
//--- Definir a cor com a propriedade PLOT_LINE_COLOR
   PlotIndexSetInteger(0,PLOT_LINE_STYLE,styles[style_index]);
//--- Escrever o estilo de linha
   comm=EnumToString(styles[style_index])+", "+comm;
//--- Mostrar a informação no gráfico usando um comentário
   Comment(comm);
  }