DRAW_COLOR_BARS

O estilo DRAW_COLOR_BARS desenha barra sobre valores de quatro buffers de indicador, que contém Open (abertura), High (alta), Low (baixa) e Close (fechamento) de preços. Este estilo é uma versão avançada do DRAW_BARS e permite a especificação para cada barra de uma cor individual do conjunto predefinido de cores. É usado para a criação de indicadores personalizados como barras, incluindo aqueles numa sub-janela separada de um gráfico e sobre outros instrumentos financeiros.

A cor das barras pode ser definida usando as diretivas de compilador ou dinamicamente utilizando a função PlotIndexSetInteger(). Mudanças dinâmicas das propriedades de plotagem permitem "avivar" os indicadores, de modo que suas mudanças de aparência dependem da situação corrente.

O indicador é desenhado apenas para as barras, para o qual os valores não vazios de todos quatro buffers do indicador são definidos. Para especificar o valor que deve ser considerado como "vazio", defina este valor na propriedade PLOT_EMPTY_VALUE:

//--- O valor 0 (vazio) não vai participar no desenho
   PlotIndexSetDouble(index_of_plot_DRAW_COLOR_BARS,PLOT_EMPTY_VALUE,0);

Sempre preencher explicitamente os valores dos buffers do indicador, definir um valor vazio num buffer para ignorar barras.

O número requerido de buffers para plotagem de DRAW_COLOR_BARS é 5:

  • quatro buffers para armazenar Open, High, Low e Close;
  • um buffer para armazenar o índice das cores, que é usado para desenhar uma barra(faz sentido defini-lo apenas para as barras que serão desenhadas).

Todos os buffers para a plotagem devem ir um após o outro na ordem determinada: Open, High, Low, Close e o buffer de cor. Nenhum dos buffers de preços podem conter valores nulos, uma vez que neste caso nada é plotado.

Um exemplo do indicador que desenha barras sobre um instrumento financeiro selecionado numa janela separada. A cor das barras muda aleatoriamente a cada N ticks. O parâmetro N é definido nos parâmetro externos do indicador para a possibilidade de configuração manual (na guia Parâmetros na janela Propriedades do indicador).

Um exemplo do estilo DRAW_COLOR_BARS

Por favor note que para plot1 com o estilo DRAW_COLOR_BARS, 8 cores são definidas usando a diretiva de compilador #property, e então na função OnCalculate() a cor é selecionada aleatoriamente a partir de 14 cores armazenadas no array de colors[].

//+------------------------------------------------------------------+
//|                                              DRAW_COLOR_BARS.mq5 |
//|                        Copyright 2011, MetaQuotes Software Corp. |
//|                                              https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
 
#property description "Um indicador para demonstrar DRAW_COLOR_BARS"
#property description "Ele desenha diferentes cores nas barras de um símbolo selecionado numa janela separada"
#property description "A cor e a largura das barras, bem como o símbolo são alterados aleatoriamente"
#property description "cada N ticks"
 
#property indicator_separate_window
#property indicator_buffers 5
#property indicator_plots   1
//--- plotar ColorBars
#property indicator_label1  "ColorBars"
#property indicator_type1   DRAW_COLOR_BARS
//--- Define 8 cores para colorir barras (elas são armazenadas num array especial)
#property indicator_color1  clrRed,clrBlue,clrGreen,clrYellow,clrMagenta,clrCyan,clrLime,clrOrange
#property indicator_style1  STYLE_SOLID
#property indicator_width1  1
//--- parâmetros de entrada
input int      N=5;              // O número de ticks para alterar o tipo
input int      bars=500;         // O número de barras para mostrar
input bool     messages=false;   // Mostrar mensagens no log "Expert Advisors" 
//--- buffers do Indicador
double         ColorBarsBuffer1[];
double         ColorBarsBuffer2[];
double         ColorBarsBuffer3[];
double         ColorBarsBuffer4[];
double         ColorBarsColors[];
//--- Nome do símbolo
string symbol;
int    bars_colors;
//--- Um array para armazenar as cores que contém 14 elementos
color colors[]=
  {
   clrRed,clrBlue,clrGreen,clrChocolate,clrMagenta,clrDodgerBlue,clrGoldenrod,
   clrIndigo,clrLightBlue,clrAliceBlue,clrMoccasin,clrMagenta,clrCyan,clrMediumPurple
  };
//+------------------------------------------------------------------+
//| Função de inicialização do indicador customizado                 |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- mapeamento de buffers do indicador
   SetIndexBuffer(0,ColorBarsBuffer1,INDICATOR_DATA);
   SetIndexBuffer(1,ColorBarsBuffer2,INDICATOR_DATA);
   SetIndexBuffer(2,ColorBarsBuffer3,INDICATOR_DATA);
   SetIndexBuffer(3,ColorBarsBuffer4,INDICATOR_DATA);
   SetIndexBuffer(4,ColorBarsColors,INDICATOR_COLOR_INDEX);
//---- Número de cores para colorir as barras
   bars_colors=8;   //  veja uma comentário para a #property indicator_color1
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Função de iteração do indicador customizado                      |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
   static int ticks=0;
//--- Conte ticks para mudar o estilo, cor e largura da barra
   ticks++;
//--- Se um número suficiente de ticks foi acumulado
   if(ticks>=N)
     {
      //--- Selecione um novo símbolo a partir da janela de observação do Mercado
      symbol=GetRandomSymbolName();
      //--- Alterar as propriedades da linha
      ChangeLineAppearance();
      //--- Mude as cores usadas para desenhar os candlesticks
      ChangeColors(colors,bars_colors);
      int tries=0;
      //--- Faça 5 tentativas de preencher os buffers com os preços a partir símbolo
      while(!CopyFromSymbolToBuffers(symbol,rates_total,bars_colors) && tries<5)
        {
         //--- Um contador de chamadas da função CopyFromSymbolToBuffers()
         tries++;
        }
      //--- Redefinir o contador de ticks para zero
      ticks=0;
     }
//--- valor retorno de prev_calculated para a próxima chamada
   return(rates_total);
  }
//+------------------------------------------------------------------+
//| Preencher os buffers do indicador com preços                     |
//+------------------------------------------------------------------+
bool CopyFromSymbolToBuffers(string name,int total,int bar_colors)
  {
//--- No array de rates[], vamos copiar Open (abertura), High (alta), Low (baixa) e Close (fechamento) de preços
   MqlRates rates[];
//--- O contador de tentativas
   int attempts=0;
//--- Quanto foi copiado
   int copied=0;
//--- Fazer 25 tentativas para obter uma série temporal(timeseries) sobre o símbolo desejado
   while(attempts<25 && (copied=CopyRates(name,_Period,0,bars,rates))<0)
     {
      Sleep(100);
      attempts++;
      if(messagesPrintFormat("%s Copiar taxas(%s) tentativas=%d",__FUNCTION__,nome,tentativas);
     }
//--- Se falhou em copiar um número suficiente de barras
   if(copied!=bars)
     {
      //--- Formar uma mensagem string
      string comm=StringFormat("Para o símbolo %s, conseguiu receber somente %d barras de %d solicitadas",
                               name,
                               copied,
                               bars
                               );
      //--- Mostrar uma mensagem num comentário na janela do gráfico principal
      Comment(comm);
      //--- Mostrar a mensagem
      if(messagesPrint(comm);
      return(false);
     }
   else
     {
      //--- Definir a exibição do símbolo
      PlotIndexSetString(0,PLOT_LABEL,name+" Open;"+name+" High;"+name+" Low;"+name+" Close");
      IndicatorSetString(INDICATOR_SHORTNAME,"DRAW_COLOR_BARS("+name+")");
     }
//--- Inicializar buffers com valores vazios
   ArrayInitialize(ColorBarsBuffer1,0.0);
   ArrayInitialize(ColorBarsBuffer2,0.0);
   ArrayInitialize(ColorBarsBuffer3,0.0);
   ArrayInitialize(ColorBarsBuffer4,0.0);
 
//--- Copiar os preços para os buffers
   for(int i=0;i<copied;i++)
     {
      //--- Calcular o índice apropriado para os buffers
      int buffer_index=total-copied+i;
      //--- Escreva os preços para os buffers
      ColorBarsBuffer1[buffer_index]=rates[i].open;
      ColorBarsBuffer2[buffer_index]=rates[i].high;
      ColorBarsBuffer3[buffer_index]=rates[i].low;
      ColorBarsBuffer4[buffer_index]=rates[i].close;
      //---
      ColorBarsColors[buffer_index]=i%bar_colors;
     }
   return(true);
  }
//+------------------------------------------------------------------+
//| Aleatoriamente retorna um símbolo de Observação do Mercado       |
//+------------------------------------------------------------------+
string GetRandomSymbolName()
  {
//--- O número de símbolos mostrada na janela de observação do Mercado
   int symbols=SymbolsTotal(true);
//--- A posição de um símbolo na lista - um número aleatório de 0 para símbolos
   int number=MathRand()%symbols;
//--- Retornar o nome de um símbolo na posição especificada
   return SymbolName(number,true);
  }
//+------------------------------------------------------------------+
//|  Alterar a cor do segmento zigzag                                |
//+------------------------------------------------------------------+
void  ChangeColors(color  &cols[],int plot_colors)
  {
//--- O número de cores
   int size=ArraySize(cols);
//--- 
   string comm=ChartGetString(0,CHART_COMMENT)+"\r\n\r\n";
 
//--- Para cada índice de cor definir uma nova cor aleatoriamente
   for(int plot_color_ind=0;plot_color_ind<plot_colors;plot_color_ind++)
     {
      //--- Obter um valor aleatório
      int number=MathRand();
      //--- Obter um índice no array col[] como um resto da divisão inteira
      int i=number%size;
      //--- Definir a cor para cada índice com a propriedade PLOT_LINE_COLOR
      PlotIndexSetInteger(0,                    //  O número do estilo gráfico
                          PLOT_LINE_COLOR,      //  Identificador da propriedade
                          plot_color_ind,       //  O índice da cor, onde se escreve a cor
                          cols[i]);             //  Uma nova cor
      //--- Escrever as cores
      comm=comm+StringFormat("BarColorIndex[%d]=%s \r\n",plot_color_ind,ColorToString(cols[i],true));
      ChartSetString(0,CHART_COMMENT,comm);
     }
//---
  }
//+------------------------------------------------------------------+
//| Altera a aparência das barras                                    |
//+------------------------------------------------------------------+
void ChangeLineAppearance()
  {
//--- Uma string para a formação de informações sobre as propriedades da barra
   string comm="";
 
//--- Um bloco para alterar a largura das barras
   int number=MathRand();
//--- Obter a largura do restante da divisão inteira
   int width=number%5;   // A largura é definida de 0 a 4
//--- Definir a cor com a propriedade PLOT_LINE_WIDTH
   PlotIndexSetInteger(0,PLOT_LINE_WIDTH,width);
//--- Escrever a largura da linha
   comm=comm+"\r\nWidth="+IntegerToString(width);
 
//--- Escreve o nome do símbolo
   comm="\r\n"+symbol+comm;
 
//--- Mostrar a informação no gráfico usando um comentário
   Comment(comm);
  }