DRAW_HISTOGRAM

O estilo DRAW_HISTOGRAM desenha um histograma como uma seqüência de colunas de uma especifica cor do zero para um especifico valor. Os valores são extraídos do buffer do indicador. A largura, cor e estilo da coluna pode ser especificado como para o estilo DRAW_LINE - usando diretivas de compilação ou dinamicamente usando a função PlotIndexSetInteger(). Mudanças dinâmicas das propriedades de plotagem permitem alterar o visual do histograma com base na situação atual.

Uma vez que uma coluna a partir do nível zero é desenhada sobre cada barra, DRAW_HISTOGRAM deve ser melhor utilizada numa janela do gráfico em separado. Na maioria das vezes este tipo de de plotagem é usada para criar indicadores do tipo de oscilador, por exemplo, Bears Power ou OsMA. Para os valores vazios que não são visíveis, o valor zero deve ser especificado.

O número de buffers requerido para plotagem de DRAW_HISTOGRAM é 1.

Um exemplo do indicador que desenha uma senóide de uma cor específica com base na função MathSin(). A cor, a largura e o estilo de todas colunas do histograma mudam aleatoriamente a cada N ticks. O parâmetro de barras determina o período da senóide, isto é, após um número especifico de barras a senóide vai repetir o ciclo.

Um exemplo do estilo DRAW_HISTOGRAM

Note que inicialmente para plot1 com DRAW_HISTOGRAM, as propriedades são definidas usando a diretiva de compilador #property, e então na função OnCalculate() estas três propriedades são definidas aleatoriamente. O parâmetro N é definido nos parâmetros externos do indicador para a possibilidade de configuração manual (o guia Parâmetros na janela Propriedades do indicador).

//+------------------------------------------------------------------+
//|                                               DRAW_HISTOGRAM.mq5 |
//|                         Copyright 2000-2024, MetaQuotes Ltd. |
//|                                              https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
 
#property description "Um indicador para demonstrar DRAW_HISTOGRAM"
#property description "Ele desenha um senóide como um histograma em uma janela separada"
#property description "A cor e a largura das colunas são alterados aleatoriamente"
#property description "depois de cada N ticks"
#property description "O parâmetro das barras define o número de barras no ciclo da senóide"
 
#property indicator_separate_window
#property indicator_buffers 1
#property indicator_plots   1
//--- plotar Histograma
#property indicator_label1  "Histograma"
#property indicator_type1   DRAW_HISTOGRAM
#property indicator_color1  clrBlue
#property indicator_style1  STYLE_SOLID
#property indicator_width1  1
//--- parâmetros de entrada
input int      bars=30;          // O período de uma senóide em barras
input int      N=5;              // O número de ticks para alterar o histograma
//--- buffers do indicador
double         HistogramBuffer[];
//--- Um fator para obter o ângulo 2Pi em radianos, quando multiplicado pelo parâmetro das barras
double    multiplier;
//--- Um array para armazenar as cores
color colors[]={clrRed,clrBlue,clrGreen};
//--- Um array para armazenar os estilos de linha
ENUM_LINE_STYLE styles[]={STYLE_SOLID,STYLE_DASH,STYLE_DOT,STYLE_DASHDOT,STYLE_DASHDOTDOT};
//+------------------------------------------------------------------+
//| Função de inicialização do indicador customizado                 |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- mapeamento de buffers do indicador
   SetIndexBuffer(0,HistogramBuffer,INDICATOR_DATA);
//--- Calcular a multiplicação
   if(bars>1)multiplier=2.*M_PI/bars;
   else
     {
      PrintFormat("Defina o valor das barras=%d maior do que 1",bars);
      //--- Finalização antecipada do indicador
      return(INIT_PARAMETERS_INCORRECT);
     }
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Função de iteração do indicador customizado                      |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
   static int ticks=0;
//--- Calcule ticks para mudar o estilo, cor e largura da linha
   ticks++;
//--- Se um número crítico de ticks tem sido acumulado
   if(ticks>=N)
     {
      //--- Alterar as propriedades da linha
      ChangeLineAppearance();
      //--- Redefinir o contador de ticks para zero
      ticks=0;
     }
 
//--- Calcule os valores do indicador
   int start=0;
//--- Se já foi calculado durante os inícios anteriores do OnCalculate
   if(prev_calculated>0) start=prev_calculated-1; // definir o início do cálculo com a penúltima barra
//--- Preencher o buffer do indicador com valores
   for(int i=start;i<rates_total;i++)
     {
      HistogramBuffer[i]=sin(i*multiplier);
     }
//--- Retorna o valor de prev_calculated para a próxima chamada da função
   return(rates_total);
  }
//+------------------------------------------------------------------+
//| Altera a aparência das linhas no indicador                       |
//+------------------------------------------------------------------+
void ChangeLineAppearance()
  {
//--- Uma string para a formação de informações sobre as propriedades de linha
   string comm="";
//--- Um bloco para alterar a cor da linha
   int number=MathRand(); // Obter um número aleatório
//--- O divisor é igual ao tamanho do array colors[]
   int size=ArraySize(colors);
//--- Obter o índice para selecionar uma nova cor como o restante da divisão inteira
   int color_index=number%size;
//--- Definir a cor com a propriedade PLOT_LINE_COLOR
   PlotIndexSetInteger(0,PLOT_LINE_COLOR,colors[color_index]);
//--- Escrever a cor da linha
   comm=comm+"\r\n"+(string)colors[color_index];
 
//--- Um bloco para alterar a largura da linha
   number=MathRand();
//--- Obter a largura do restante da divisão inteira
   int width=number%5;   // A largura é definida de 0 a 4
//--- Definir a largura
   PlotIndexSetInteger(0,PLOT_LINE_WIDTH,width);
//--- Escrever a largura da linha
   comm=comm+"\r\nWidth="+IntegerToString(width);
 
//--- Um bloco para mudar o estilo da linha
   number=MathRand();
//--- O divisor é igual ao tamanho do array de estilos
   size=ArraySize(styles);
//--- Obter o índice para selecionar um novo estilo como o resto da divisão inteira
   int style_index=number%size;
//--- define o estilo da linha
   PlotIndexSetInteger(0,PLOT_LINE_STYLE,styles[style_index]);
//--- Escrever o estilo de linha
   comm="\r\n"+EnumToString(styles[style_index])+""+comm;
//--- Mostrar a informação no gráfico usando um comentário
   Comment(comm);
  }