//+------------------------------------------------------------------+
//| DRAW_COLOR_ZIGZAG.mq5 |
//| Copyright 2011, MetaQuotes Software Corp. |
//| https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link "https://www.mql5.com"
#property version "1.00"
#property description "Um indicador para demonstrar DRAW_COLOR_ZIGZAG"
#property description "Ele desenha uma linha tracejada, como uma seqüência das seções coloridas, a cor depende do número de dias da semana "
#property description "A cor, a largura e tamanho dos segmentos são alterados aleatoriamente"
#property description " a cada N ticks"
#property indicator_chart_window
#property indicator_buffers 3
#property indicator_plots 1
//--- plotar Color_Zigzag
#property indicator_label1 "Color_Zigzag"
#property indicator_type1 DRAW_COLOR_ZIGZAG
//--- Definir 8 cores para colorir seções (eles são armazenados numa array especial)
#property indicator_color1 clrRed,clrBlue,clrGreen,clrYellow,clrMagenta,clrCyan,clrLime,clrOrange
#property indicator_style1 STYLE_SOLID
#property indicator_width1 1
//--- parâmetros de entrada
input int N=5; // Número de ticks para alterar
int color_sections;
//--- Buffers dos valores das extremidades do segmento
double Color_ZigzagBuffer1[];
double Color_ZigzagBuffer2[];
//--- Buffers do índice de cores das extremidades dos segmento
double Color_ZigzagColors[];
//--- Um array para armazenar as cores que contém 14 elementos
color colors[]=
{
clrRed,clrBlue,clrGreen,clrChocolate,clrMagenta,clrDodgerBlue,clrGoldenrod,
clrIndigo,clrLightBlue,clrAliceBlue,clrMoccasin,clrWhiteSmoke,clrCyan,clrMediumPurple
};
//--- Um array para armazenar os estilos de linha
ENUM_LINE_STYLE styles[]={STYLE_SOLID,STYLE_DASH,STYLE_DOT,STYLE_DASHDOT,STYLE_DASHDOTDOT};
//+------------------------------------------------------------------+
//| Função de inicialização do indicador customizado |
//+------------------------------------------------------------------+
int OnInit()
{
//--- mapeamento de buffers do indicador
SetIndexBuffer(0,Color_ZigzagBuffer1,INDICATOR_DATA);
SetIndexBuffer(1,Color_ZigzagBuffer2,INDICATOR_DATA);
SetIndexBuffer(2,Color_ZigzagColors,INDICATOR_COLOR_INDEX);
//----Número de corres para colorir o zigzag
color_sections=8; // veja um comentário para a #property indicator_color1
//---
return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| Função de iteração do indicador customizado |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
const int prev_calculated,
const datetime &time[],
const double &open[],
const double &high[],
const double &low[],
const double &close[],
const long &tick_volume[],
const long &volume[],
const int &spread[])
{
static int ticks=0;
//--- Calcule ticks para mudar o estilo, cor e largura da linha
ticks++;
//--- Se um número suficiente de ticks foi acumulado
if(ticks>=N)
{
//--- Alterar as propriedades da linha
ChangeLineAppearance();
//--- Alterar cores utilizadas para plotar as seções
ChangeColors(colors,color_sections);
//--- Redefinir o contador de ticks para zero
ticks=0;
}
//--- A estrutura de tempo é necessário para obter o dia da semana de cada barra
MqlDateTime dt;
//--- A posição inicial dos cálculos
int start=0;
//--- Se o indicador foi calculado com o tick anterior, então inicia o cálculo com o passado, mas de um tick
if(prev_calculated!=0) start=prev_calculated-1;
//--- Calculando loop
for(int i=start;i<rates_total;i++)
{
//--- Escreva o tempo de abertura da barra na estrutura
TimeToStruct(time[i],dt);
//--- Se é ainda o número de barra
if(i%2==0)
{
//--- Escrever a alta no primeiro buffer e a baixa no segundo
Color_ZigzagBuffer1[i]=high[i];
Color_ZigzagBuffer2[i]=low[i];
//--- A cor do segmento
Color_ZigzagColors[i]=dt.day_of_year%color_sections;
}
//--- o número da barra é ímpar
else
{
//--- Preencha a barra numa ordem inversa
Color_ZigzagBuffer1[i]=low[i];
Color_ZigzagBuffer2[i]=high[i];
//--- A cor do segmento
Color_ZigzagColors[i]=dt.day_of_year%color_sections;
}
}
//--- valor retorno de prev_calculated para a próxima chamada
return(rates_total);
}
//+------------------------------------------------------------------+
//| Alterar a cor do segmento zigzag |
//+------------------------------------------------------------------+
void ChangeColors(color &cols[],int plot_colors)
{
//--- O número de cores
int size=ArraySize(cols);
//---
string comm=ChartGetString(0,CHART_COMMENT)+"\r\n\r\n";
//--- Para cada índice de cor definir uma nova cor aleatoriamente
for(int plot_color_ind=0;plot_color_ind<plot_colors;plot_color_ind++)
{
//--- Obter um valor aleatório
int number=MathRand();
//--- Obter um índice no array col[] como um resto da divisão inteira
int i=number%size;
//--- Definir a cor para cada índice com a propriedade PLOT_LINE_COLOR
PlotIndexSetInteger(0, // O número do estilo gráfico
PLOT_LINE_COLOR, // Identificador da propriedade
plot_color_ind, // O índice da cor, onde se escreve a cor
cols[i]); // Uma nova cor
//--- Escrever as cores
comm=comm+StringFormat("ZigzagColorIndex[%d]=%s \r\n",plot_color_ind,ColorToString(cols[i],true));
ChartSetString(0,CHART_COMMENT,comm);
}
//---
}
//+------------------------------------------------------------------+
//| Alterar a aparência dos segmentos zigzag |
//+------------------------------------------------------------------+
void ChangeLineAppearance()
{
//--- Uma string para a formação da informação sobre as propriedades de Color_ZigZag
string comm="";
//--- Um bloco para alterar a largura da linha
int number=MathRand();
//--- Obter a largura do restante da divisão inteira
int width=number%5; // A largura é definida de 0 a 4
//--- Definir a cor com a propriedade PLOT_LINE_WIDTH
PlotIndexSetInteger(0,PLOT_LINE_WIDTH,width);
//--- Escrever a largura da linha
comm=comm+"\r\nWidth="+IntegerToString(width);
//--- Um bloco para mudar o estilo da linha
number=MathRand();
//--- O divisor é igual ao tamanho do array de estilos
int size=ArraySize(styles);
//--- Obter o índice para selecionar um novo estilo como o resto da divisão inteira
int style_index=number%size;
//--- Definir a cor com a propriedade PLOT_LINE_COLOR
PlotIndexSetInteger(0,PLOT_LINE_STYLE,styles[style_index]);
//--- Escrever o estilo de linha
comm="\r\n"+EnumToString(styles[style_index])+""+comm;
//--- Mostrar a informação no gráfico usando um comentário
Comment(comm);
}
|