DRAW_COLOR_HISTOGRAM

O estilo DRAW_COLOR_HISTOGRAM desenha um histograma como uma seqüência de colunas coloridas a partir de zero pra um valor específico. Os valores são extraídos do buffer do indicador. Cada coluna pode ter a sua própria cor a partir de um conjunto pré-definido de cores.

A largura, cor e estilo do histograma podem ser especificados como para o estilo DRAW_HISTOGRAM - usando as diretivas de compilador ou dinamicamente usando a função PlotIndexSetInteger(). Mudanças dinâmicas das propriedades de plotagem permitem alterar o visual do histograma com base na situação atual.

Uma vez que uma coluna a partir do nível zero é desenhado em cada barra, DRAW_COLOR_HISTOGRAM será melhor utilizado numa janela de gráfico em separado. Na maioria das vezes este tipo de plotagem é usada para criar indicadores do tipo osciladores, por exemplo, Awesome Oscillator ou Market Facilitation Index. Para os valores vazios que não são visíveis, o valor zero deve ser especificado.

O número de buffers necessários para plotagem DRAW_COLOR_HISTOGRAM é 2.

  • um buffer para armazenar um valor que não seja zero do segmento vertical em cada barra, a segunda extremidade do segmento estará sempre na linha zero do indicador;
  • um buffer para armazenar o índice de cor, que é usada para desenhar a seção (faz sentido definir apenas valores não vazios).

Cores podem ser determinadas usando a diretiva de compilador #property indicator_color1 separadas por uma vírgula. O número de cores não pode exceder a 64.

Um exemplo do indicador que desenha uma senóide de uma cor específica com base na função MathSin(). A cor, a largura e o estilo de todas colunas do histograma mudam aleatoriamente a cada N ticks. O parâmetro de barras determina o período da senóide, isto é, após um número especifico de barras a senóide vai repetir o ciclo.

Um exemplo de DRAW_COLOR_HISTOGRAM

Por favor note que para plot1 com o estilo DRAW_COLOR_HISTOGRAM, 5 cores são definidas usando a diretiva de compilador #property, e então na função OnCalculate(), as cores são selecionadas aleatoriamente a partir de quatorze cores armazenada no array de colors[]. O parâmetro N é definido nos parâmetros externos do indicador para a possibilidade de configuração manual (o guia Parâmetros na janela Propriedades do indicador).

//+------------------------------------------------------------------+
//|                                         DRAW_COLOR_HISTOGRAM.mq5 |
//|                        Copyright 2011, MetaQuotes Software Corp. |
//|                                              https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2011, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
 
#property description "Um indicador para demonstrar DRAW_COLOR_HISTOGRAM"
#property description "Ele desenha um senóide como um histograma em uma janela separada"
#property description "A cor e a largura das colunas são alterados aleatoriamente"
#property description "depois de cada N ticks"
#property description "O parâmetro de barras define o número de barras para repetir a senóide"
 
#property indicator_separate_window
#property indicator_buffers 2
#property indicator_plots   1
//--- parâmetros de entrada
input int      bars=30;          // O período de uma senóide em barras
input int      N=5;              // O número de ticks para alterar o histograma
//--- plotar Color_Histogram
#property indicator_label1  "Color_Histogram"
#property indicator_type1   DRAW_COLOR_HISTOGRAM
//--- Definir 8 cores para colorir seções (eles são armazenados numa array especial)
#property indicator_color1  clrRed,clrGreen,clrBlue,clrYellow,clrMagenta,clrCyan,clrMediumSeaGreen,clrGold
#property indicator_style1  STYLE_SOLID
#property indicator_width1  1
//--- Um buffer de valores
double         Color_HistogramBuffer[];
//--- Um buffer de índices de cor
double         Color_HistogramColors[];
//--- Um fator para obter o ângulo 2Pi em radianos, quando multiplicado pelo parâmetro das barras 
double         multiplier;
int            color_sections;
//--- Um array para armazenar as cores que contém 14 elementos
color colors[]=
  {
   clrRed,clrBlue,clrGreen,clrChocolate,clrMagenta,clrDodgerBlue,clrGoldenrod,
   clrIndigo,clrLightBlue,clrAliceBlue,clrMoccasin,clrWhiteSmoke,clrCyan,clrMediumPurple
  };
//--- Um array para armazenar os estilos de linha
ENUM_LINE_STYLE styles[]={STYLE_SOLID,STYLE_DASH,STYLE_DOT,STYLE_DASHDOT,STYLE_DASHDOTDOT};
//+------------------------------------------------------------------+
//| Função de inicialização do indicador customizado                 |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- mapeamento de buffers do indicador
   SetIndexBuffer(0,Color_HistogramBuffer,INDICATOR_DATA);
   SetIndexBuffer(1,Color_HistogramColors,INDICATOR_COLOR_INDEX);
//---- O número de cores para a colorir a senóide
   color_sections=8;   //  Veja comentário para #property indicator_color1
//--- Calcular a multiplicação
   if(bars>1)multiplier=2.*M_PI/bars;
   else
     {
      PrintFormat("Defina o valor das barras=%d maior do que 1",bars);
      //--- Finalização antecipada do indicador
      return(INIT_PARAMETERS_INCORRECT);
     }   
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Função de iteração do indicador customizado                      |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
   static int ticks=0;
//--- Calcule ticks para mudar o estilo, cor e largura da linha
   ticks++;
//--- Se um número crítico de ticks tem sido acumulado
   if(ticks>=N)
     {
      //--- Alterar as propriedades da linha
      ChangeLineAppearance();
      //--- Alterar cores usadas para o histograma
      ChangeColors(colors,color_sections);      
      //--- Redefinir o contador de ticks para zero
      ticks=0;
     }
 
//--- Calcule os valores do indicador
   int start=0;
//--- Se já foi calculado durante os inícios anteriores do OnCalculate
   if(prev_calculated>0) start=prev_calculated-1; // definir o início do cálculo com a penúltima barra
//--- Preencher o buffer do indicador com valores
   for(int i=start;i<rates_total;i++)
     {
      //--- Um valor
      Color_HistogramBuffer[i]=sin(i*multiplier);
      //--- Cor
      int color_index=i%(bars*color_sections);
      color_index/=bars;
      Color_HistogramColors[i]=color_index;
     }
//--- Retorna o valor de prev_calculated para a próxima chamada da função
   return(rates_total);
  }
//+------------------------------------------------------------------+
//| Altera a cor dos segmentos de linha                              |
//+------------------------------------------------------------------+
void  ChangeColors(color  &cols[],int plot_colors)
  {
//--- O número de cores
   int size=ArraySize(cols);
//--- 
   string comm=ChartGetString(0,CHART_COMMENT)+"\r\n\r\n";
 
//--- Para cada índice de cor definir uma nova cor aleatoriamente
   for(int plot_color_ind=0;plot_color_ind<plot_colors;plot_color_ind++)
     {
      //--- Obter um valor aleatório
      int number=MathRand();
      //--- Obter um índice no array col[] como um resto da divisão inteira
      int i=number%size;
      //--- Definir a cor para cada índice com a propriedade PLOT_LINE_COLOR
      PlotIndexSetInteger(0,                    //  O número do estilo gráfico
                          PLOT_LINE_COLOR,      //  Identificador da propriedade
                          plot_color_ind,       //  O índice da cor, onde se escreve a cor
                          cols[i]);             //  Uma nova cor
      //--- Escrever as cores
      comm=comm+StringFormat("HistogramColorIndex[%d]=%s \r\n",plot_color_ind,ColorToString(cols[i],true));
      ChartSetString(0,CHART_COMMENT,comm);
     }
//---
  }
//+------------------------------------------------------------------+
//| Altera a aparência de uma linha visualizada no indicador         |
//+------------------------------------------------------------------+
void ChangeLineAppearance()
  {
//--- Uma string para a formação de informações sobre as propriedades de linha
   string comm="";
//--- Um bloco para alterar a largura da linha
   int number=MathRand();
//--- Obter a largura do restante da divisão inteira
   int width=number%5; // A largura é definida de 0 a 4
//--- Definir a cor com a propriedade PLOT_LINE_WIDTH
   PlotIndexSetInteger(0,PLOT_LINE_WIDTH,width);
//--- Escrever a largura da linha
   comm=comm+" Width="+IntegerToString(width);
 
//--- Um bloco para mudar o estilo da linha
   number=MathRand();
//--- O divisor é igual ao tamanho do array de estilos
   int size=ArraySize(styles);
//--- Obter o índice para selecionar um novo estilo como o resto da divisão inteira
   int style_index=number%size;
//--- Definir a cor com a propriedade PLOT_LINE_COLOR
   PlotIndexSetInteger(0,PLOT_LINE_STYLE,styles[style_index]);
//--- Escrever o estilo de linha
   comm=EnumToString(styles[style_index])+", "+comm;
//--- Mostrar a informação no gráfico usando um comentário
   Comment(comm);
  }