DRAW_HISTOGRAM2

O estilo DRAW_HISTOGRAM2 desenha uma histograma de uma cor especifica — segmentos verticais usando os valores de dois buffers do indicator. A largura, cor e estilo dos segmentos podem ser especificados para o estilo DRAW_LINE - usando diretivas de compilação ou dinamicamente usando a função PlotIndexSetInteger(). Mudanças dinâmicas das propriedades de plotagem permitem alterar o visual do histograma com base na situação atual.

O estilo DRAW_HISTOGRAM2 pode ser usado numa sub-janela separada e na sua janela principal. Para valores vazios nada é desenhado, todos os valores nos buffers do indicador precisam ser definidos explicitamente. Buffers não são inicializados com o valor zero.

O número de buffers requerido para plotagem de DRAW_HISTOGRAM2 é 2.

Um exemplo de indicador que plota um segmento vertical da cor especifica e largura entre a Abertura (open) e o Fechamento (close) de preços de cada barra. A cor, a largura e o estilo de todas as colunas do histograma mudam aleatoriamente a cada N ticks. durante a inicialização do indicador, na função OnInit(), o número do dia da semana em que não será desenhado o histograma - invisible_day - é definido aleatoriamente. Para este fim um valor vazio é definido PLOT_EMPTY_VALUE=0:

//--- Definir um valor vazio
   PlotIndexSetDouble(index_of_plot_DRAW_SECTION,PLOT_EMPTY_VALUE,0);

Um examplo de DRAW_HISTOGRAM2

Note que inicialmente para plot1 com DRAW_HISTOGRAM2, as propriedades são definidas usando a diretiva de compilador #property, e então na função OnCalculate() estas três propriedades são definidas aleatoriamente. O parâmetro N é definido nos parâmetros externos do indicador para a possibilidade de configuração manual (o guia Parâmetros na janela Propriedades do indicador).

//+------------------------------------------------------------------+
//|                                              DRAW_HISTOGRAM2.mq5 |
//|                         Copyright 2000-2024, MetaQuotes Ltd. |
//|                                              https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
 
#property description "Un indicador para demonstrar DRAW_HISTOGRAM2"
#property description "É desenhado um segmento entre a abertura e fechamento em cada barra"
#property description "A cor, a largura e o estilo são alterados aleatoriamente"
#property description "depois de cada N ticks"
 
#property indicator_chart_window
#property indicator_buffers 2
#property indicator_plots   1
//--- plotar Histogram_2
#property indicator_label1  "Histogram_2"
#property indicator_type1   DRAW_HISTOGRAM2
#property indicator_color1  clrRed
#property indicator_style1  STYLE_SOLID
#property indicator_width1  1
//--- parâmetros de entrada
input int      N=5;              // O número de ticks para alterar o histograma
//--- buffers do indicador
double         Histogram_2Buffer1[];
double         Histogram_2Buffer2[];
//--- O dia da semana, em que o indicador não é plotado
int invisible_day;
//--- Um array para armazenar as cores
color colors[]={clrRed,clrBlue,clrGreen};
//--- Um array para armazenar os estilos de linha
ENUM_LINE_STYLE styles[]={STYLE_SOLID,STYLE_DASH,STYLE_DOT,STYLE_DASHDOT,STYLE_DASHDOTDOT};
//+------------------------------------------------------------------+
//| Função de inicialização do indicador customizado                 |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- mapeamento de buffers do indicador
   SetIndexBuffer(0,Histogram_2Buffer1,INDICATOR_DATA);
   SetIndexBuffer(1,Histogram_2Buffer2,INDICATOR_DATA);
//--- Definir um valor vazio
   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0);
//--- Obtém aleatoriamente um número a partir do 0 até 5
   invisible_day=MathRand()%6;
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Função de iteração do indicador customizado                      |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
   static int ticks=0;
//--- Calcule ticks para mudar o estilo, cor e largura da linha
   ticks++;
//--- Se um número crítico de ticks tem sido acumulado
   if(ticks>=N)
     {
      //--- Alterar as propriedades da linha
      ChangeLineAppearance();
      //--- Redefinir o contador de ticks para zero
      ticks=0;
     }
 
//--- Calcule os valores do indicador
   int start=0;
//--- Para obter o dia da semana pela abertura de preço de cada barra
   MqlDateTime dt;
//--- Se já foi calculado durante os inícios anteriores do OnCalculate
   if(prev_calculated>0) start=prev_calculated-1; // definir o início do cálculo com a penúltima barra
//--- Preencher o buffer do indicador com valores
   for(int i=start;i<rates_total;i++)
     {
      TimeToStruct(time[i],dt);
      if(dt.day_of_week==invisible_day)
        {
         Histogram_2Buffer1[i]=0;
         Histogram_2Buffer2[i]=0;
        }
      else
        {
         Histogram_2Buffer1[i]=open[i];
         Histogram_2Buffer2[i]=close[i];
        }
     }
//--- Retorna o valor de prev_calculated para a próxima chamada da função
   return(rates_total);
  }
//+------------------------------------------------------------------+
//| Altera a aparência das linhas no indicador                       |
//+------------------------------------------------------------------+
void ChangeLineAppearance()
  {
//--- Uma string para a formação de informações sobre as propriedades de linha
   string comm="";
//--- Um bloco de mudança da cor da linha
   int number=MathRand(); // Obter um número aleatório
//--- O divisor é igual ao tamanho do array colors[]
   int size=ArraySize(colors);
//--- Obter o índice para selecionar uma nova cor como o restante da divisão inteira
   int color_index=number%size;
//--- Definir a cor com a propriedade PLOT_LINE_COLOR
   PlotIndexSetInteger(0,PLOT_LINE_COLOR,colors[color_index]);
//--- Escrever a cor da linha
   comm=comm+"\r\n"+(string)colors[color_index];
 
//--- Um bloco para alterar a largura da linha
   number=MathRand();
//--- Obter a largura do restante da divisão inteira
   int width=number%5;   // A largura é definida de 0 a 4
//--- Define a largura da linha
   PlotIndexSetInteger(0,PLOT_LINE_WIDTH,width);
//--- Escrever a largura da linha
   comm=comm+"\r\nWidth="+IntegerToString(width);
 
//--- Um bloco para mudar o estilo da linha
   number=MathRand();
//--- O divisor é igual ao tamanho do array de estilos
   size=ArraySize(styles);
//--- Obter o índice para selecionar um novo estilo como o resto da divisão inteira
   int style_index=number%size;
//--- define o estilo da linha
   PlotIndexSetInteger(0,PLOT_LINE_STYLE,styles[style_index]);
//--- Escrever o estilo de linha
   comm="\r\n"+EnumToString(styles[style_index])+""+comm;
//--- Adiciona informação sobre o dia que é omitido nos cálculos
   comm="\r\nDia não plotado - "+EnumToString((ENUM_DAY_OF_WEEK)invisible_day)+comm;
//--- Mostrar a informação no gráfico usando um comentário
   Comment(comm);
  }