DRAW_COLOR_HISTOGRAM2

O estilo DRAW_COLOR_HISTOGRAM2 desenha uma histograma de uma cor específica — segmentos verticais usando os valores de buffers do indicador. Mas diferentemente ao de uma cor DRAW_HISTOGRAM2, este estilo pode ter a sua própria cor a partir de um conjunto pré-definido em cada coluna do histograma. Os valores de todos os segmentos são retirados do buffer do indicador.

A largura, o estilo e a cor do histograma pode ser especificado como para o estilo DRAW_HISTOGRAM2 — usando as diretivas de compilador ou usando dinamicamente a função PlotIndexSetInteger(). Mudanças dinâmicas das propriedades de plotagem permitem alterar o visual do histograma com base na situação atual.

O estilo DRAW_COLOR_HISTOGRAM2 pode ser usado em uma sub-janela separada de um gráfico e em sua janela principal. Para valores vazios nada é desenhado, todos os valores nos buffers do indicador precisam ser definidos explicitamente. Buffers não são inicializados com valores vazios.

O número de buffers necessários para plotagem do DRAW_COLOR_HISTOGRAM2 é 3:

  • dois buffers para armazenar a extremidade superior e inferior do segmento vertical em cada barra;
  • um buffer para armazenar o índice de cor, o qual é usado para desenhar o segmento (faz sentido definir apenas valores não vazios).

Um exemplo de indicador que desenha um histograma de uma cor especifica entre os preços de alta e baixa. Para cada dia da semana, as linhas de histograma ter uma cor diferente. A cor do dia, a largura e o estilo do histograma é alterado aleatoriamente a cada N ticks.

Um exemplo do estilo DRAW_COLOR_HISTOGRAM2

Por favor note que para plot1 com o estilo DRAW_COLOR_HISTOGRAM2, 5 cores são definidas usando a diretiva de compilador #property, e então na função OnCalculate() as cores são selecionadas aleatoriamente a partir de 14 cores armazenadas no array colors[].

O parâmetro N é defindo nos parâmetros externos do indicador para a possibilidade de configuração manual (na guia Parâmetros na janela Propriedades do indicador).

//+------------------------------------------------------------------+
//|                                        DRAW_COLOR_HISTOGRAM2.mq5 |
//|                        Copyright 2011, MetaQuotes Software Corp. |
//|                                              https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
 
#property description "Um indicador para demonstrar DRAW_COLOR_HISTOGRAM2"
#property description "É desenhado um segmento entre a abertura e fechamento em cada barra"
#property description "A cor, a largura e o estilo são alterados aleatoriamente"
#property description "depois de cada N ticks"
 
#property indicator_chart_window
#property indicator_buffers 3
#property indicator_plots   1
//--- plotar ColorHistogram_2
#property indicator_label1  "ColorHistogram_2"
#property indicator_type1   DRAW_COLOR_HISTOGRAM2
//--- Definir 5 cores para colorir o histograma com base nos dias de semana (elas são armazenadas no array especial)
#property indicator_color1  clrRed,clrBlue,clrGreen,clrYellow,clrMagenta
#property indicator_style1  STYLE_SOLID
#property indicator_width1  1
 
//--- parâmetros de entrada
input int      N=5;              // O número de ticks para alterar o histograma
int            color_sections;
//--- Valores de buffers
double         ColorHistogram_2Buffer1[];
double         ColorHistogram_2Buffer2[];
//--- Um buffer de índices de cor
double         ColorHistogram_2Colors[];
//--- Um array para armazenar as cores que contém 14 elementos
color colors[]=
  {
   clrRed,clrBlue,clrGreen,clrChocolate,clrMagenta,clrDodgerBlue,clrGoldenrod,
   clrIndigo,clrLightBlue,clrAliceBlue,clrMoccasin,clrWhiteSmoke,clrCyan,clrMediumPurple
  };
//--- Um array para armazenar os estilos de linha
ENUM_LINE_STYLE styles[]={STYLE_SOLID,STYLE_DASH,STYLE_DOT,STYLE_DASHDOT,STYLE_DASHDOTDOT};
//+------------------------------------------------------------------+
//| Função de inicialização do indicador customizado                 |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- mapeamento de buffers do indicador
   SetIndexBuffer(0,ColorHistogram_2Buffer1,INDICATOR_DATA);
   SetIndexBuffer(1,ColorHistogram_2Buffer2,INDICATOR_DATA);
   SetIndexBuffer(2,ColorHistogram_2Colors,INDICATOR_COLOR_INDEX);
//--- Definir um valor vazio
   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0);
//---- O número de cores para a colorir a senóide
   color_sections=8;   //  Veja um comentário #property indicator_color1
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Função de iteração do indicador customizado                      |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
   static int ticks=0;
//--- Calcule ticks para mudar o estilo, cor e largura da linha
   ticks++;
//--- Se um número crítico de ticks tem sido acumulado
   if(ticks>=N)
     {
      //--- Alterar as propriedades da linha
      ChangeLineAppearance();
      //--- Mude as cores usadas para desenhar o histograma
      ChangeColors(colors,color_sections);      
      //--- Redefinir o contador de ticks para zero
      ticks=0;
     }
 
//--- Calcule os valores do indicador
   int start=0;
//--- Para obter o dia da semana pela abertura de preço de cada barra
   MqlDateTime dt;
//--- Se já foi calculado durante os inícios anteriores do OnCalculate
   if(prev_calculated>0) start=prev_calculated-1; // definir o início do cálculo com a penúltima barra
//--- Preencher o buffer do indicador com valores
   for(int i=start;i<rates_total;i++)
     {
      TimeToStruct(time[i],dt);
      //--- valor
      ColorHistogram_2Buffer1[i]=high[i];
      ColorHistogram_2Buffer2[i]=low[i];
      //--- Define o índice de cores de acordo com o dia da semana
      int day=dt.day_of_week;
      ColorHistogram_2Colors[i]=day;
     }
//--- Retorna o valor de prev_calculated para a próxima chamada da função
   return(rates_total);
  }
//+------------------------------------------------------------------+
//| Altera a cor dos segmentos de linha                              |
//+------------------------------------------------------------------+
void  ChangeColors(color  &cols[],int plot_colors)
  {
//--- O número de cores
   int size=ArraySize(cols);
//--- 
   string comm=ChartGetString(0,CHART_COMMENT)+"\r\n\r\n";
 
//--- Para cada índice de cor definir uma nova cor aleatoriamente
   for(int plot_color_ind=0;plot_color_ind<plot_colors;plot_color_ind++)
     {
      //--- Obter um valor aleatório
      int number=MathRand();
      //--- Obter um índice no array col[] como um resto da divisão inteira
      int i=number%size;
      //--- Definir a cor para cada índice com a propriedade PLOT_LINE_COLOR
      PlotIndexSetInteger(0,                    //  O número do estilo gráfico
                          PLOT_LINE_COLOR,      //  Identificador da propriedade
                          plot_color_ind,       //  O índice da cor, onde se escreve a cor
                          cols[i]);             //  Uma nova cor
      //--- Escrever as cores
      comm=comm+StringFormat("HistogramColorIndex[%d]=%s \r\n",plot_color_ind,ColorToString(cols[i],true));
      ChartSetString(0,CHART_COMMENT,comm);
     }
//---
  }
//+------------------------------------------------------------------+
//| Altera a aparência de uma linha visualizada no indicador         |
//+------------------------------------------------------------------+
void ChangeLineAppearance()
  {
//--- Uma string para a formação de informações sobre as propriedades de linha
   string comm="";
//--- Um bloco para alterar a largura da linha
   int number=MathRand();
//--- Obter a largura do restante da divisão inteira
   int width=number%5; // A largura é definida de 0 a 4
//--- Definir a cor com a propriedade PLOT_LINE_WIDTH
   PlotIndexSetInteger(0,PLOT_LINE_WIDTH,width);
//--- Escrever a largura da linha
   comm=comm+" Width="+IntegerToString(width);
 
//--- Um bloco para mudar o estilo da linha
   number=MathRand();
//--- O divisor é igual ao tamanho do array de estilos
   int size=ArraySize(styles);
//--- Obter o índice para selecionar um novo estilo como o resto da divisão inteira
   int style_index=number%size;
//--- Definir a cor com a propriedade PLOT_LINE_COLOR
   PlotIndexSetInteger(0,PLOT_LINE_STYLE,styles[style_index]);
//--- Escrever o estilo de linha
   comm=EnumToString(styles[style_index])+", "+comm;
//--- Mostrar a informação no gráfico usando um comentário
   Comment(comm);
  }