DRAW_COLOR_CANDLES

O estilo DRAW_COLOR_CANDLES style, como o DRAW_CANDLES, desenha candlesticks usando valores de quatro buffers de indicador o qual contém Open (abertura), High (alta), Low (baixa) e Close (fechamento) de preços. Além disso, ele permite a especificação de uma cor para cada um candlestick de um determinado conjunto. Para esta finalidade, o estilo tem um buffer de cor especial que armazena os índices de cor para cada barra. É usado para a criação de indicadores personalizados como uma seqüência de candlesticks, incluindo os inseridos numa sub-janela separada de um gráfico e noutros instrumentos financeiros.

O número de cores de candlesticks pode ser definido usando as diretivas de compilador ou dinamicamente usando a função PlotIndexSetInteger(). Mudanças dinâmicas das propriedades de plotagem permitem "avivar" os indicadores, de modo que suas mudanças de aparência dependem da situação corrente.

O indicador é desenhado apenas para as barras, para o qual os valores não vazios de quatro buffers de preços do indicador são definidos. Para especificar o valor que deve ser considerado como "vazio", defina esse valor na propriedade PLOT_EMPTY_VALUE:

//--- O valor 0 (vazio) não vai participar no desenho
   PlotIndexSetDouble(index_of_plot_DRAW_COLOR_CANDLES,PLOT_EMPTY_VALUE,0);

Sempre preencher explicitamente os valores dos buffers do indicador, definir um valor vazio num buffer para ignorar barras.

O número de buffers necessários para plotagem de DRAW_COLOR_CANDLES é 5:

  • quatro buffers para armazenar Open, High, Low e Close;
  • um buffer para armazenar o índice de cor, que é usada para desenhar um candlestick (faz sentido defini-lo apenas para os candlesticks que serão desenhados).

Todos os buffers para a plotagem devem ir um após o outro na ordem determinada: Open, High, Low, Close e o buffer de cor. Nenhum dos buffers de preços pode conter apenas valores vazios, uma vez que, neste caso, nada é plotado.

Um exemplo de indicador que desenha candlesticks para um instrumento financeiro selecionado em uma janela separada. A cor dos candlesticks muda aleatoriamente a cada N ticks. O parâmetro N é definido nos parâmetro externos do indicador para a possibilidade de configuração manual (na guia Parâmetros na janela Propriedades do indicador).

Um exemplo do estilo DRAW_COLOR_CANDLES

Por favor, note que para plot1, a cor é definida usando a diretiva de compilador #property, e então, na função OnCalculate() a cor é definida aleatoriamente a partir de uma lista preparada anteriormente.

//+------------------------------------------------------------------+
//|                                           DRAW_COLOR_CANDLES.mq5 |
//|                        Copyright 2011, MetaQuotes Software Corp. |
//|                                              https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
 
#property description "Um indicador para demonstrar DRAW_COLOR_CANDLES."
#property description "ele desenha candlesticks de um símbolo selecionado numa janela separada"
#property description " "
#property description "A cor e a largura dos candlesticks, bem como o símbolo são alterados"
#property description "aleatoriamente a cada N ticks"
 
#property indicator_separate_window
#property indicator_buffers 5
#property indicator_plots   1
//--- Plotar ColorCandles
#property indicator_label1  "ColorCandles"
#property indicator_type1   DRAW_COLOR_CANDLES
//--- Definir 8 cores para colorir os candlesticks (eles são armazenados na array especial)
#property indicator_color1  clrRed,clrBlue,clrGreen,clrYellow,clrMagenta,clrCyan,clrLime,clrOrange
#property indicator_style1  STYLE_SOLID
#property indicator_width1  1
 
//--- parâmetros de entrada
input int      N=5;              // O número de ticks para alterar o tipo
input int      bars=500;         // O número de candlesticks para mostrar
input bool     messages=false;   // Mostrar mensagens no log "Expert Advisors" 
//--- buffers do Indicador
double         ColorCandlesBuffer1[];
double         ColorCandlesBuffer2[];
double         ColorCandlesBuffer3[];
double         ColorCandlesBuffer4[];
double         ColorCandlesColors[];
int            candles_colors;
//--- Nome do símbolo
string symbol;
//--- Um array para armazenar as cores que contém 14 elementos
color colors[]=
  {
   clrRed,clrBlue,clrGreen,clrChocolate,clrMagenta,clrDodgerBlue,clrGoldenrod,
   clrIndigo,clrLightBlue,clrAliceBlue,clrMoccasin,clrMagenta,clrCyan,clrMediumPurple
  };
//+------------------------------------------------------------------+
//| Função de inicialização do indicador customizado                 |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- Se as barras são muito pequenas - concluir o trabalho antes do tempo
   if(bars<50)
     {
      Comment("Por favor, especifique um número maior de barras! A operação do indicador foi terminada");
      return(INIT_PARAMETERS_INCORRECT);
     }
//--- mapeamento de buffers do indicador
   SetIndexBuffer(0,ColorCandlesBuffer1,INDICATOR_DATA);
   SetIndexBuffer(1,ColorCandlesBuffer2,INDICATOR_DATA);
   SetIndexBuffer(2,ColorCandlesBuffer3,INDICATOR_DATA);
   SetIndexBuffer(3,ColorCandlesBuffer4,INDICATOR_DATA);
   SetIndexBuffer(4,ColorCandlesColors,INDICATOR_COLOR_INDEX);
//--- Um valor vazio
   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0);
//--- O nome do símbolo, para o qual as barras são desenhadas
   symbol=_Symbol;
//--- Definir a exibição do símbolo
   PlotIndexSetString(0,PLOT_LABEL,symbol+" Open;"+symbol+" High;"+symbol+" Low;"+symbol+" Close");
   IndicatorSetString(INDICATOR_SHORTNAME,"DRAW_COLOR_CANDLES("+symbol+")");
//---- O número de cores para a cor dos candlesticks
   candles_colors=8;     //  Veja uma comentário para a #property indicator_color1
//--- 
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Função de iteração do indicador customizado                      |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
   static int ticks=INT_MAX-100;
//--- Contar ticks para mudar o estilo e cor
   ticks++;
//--- Se um número suficiente de ticks foi acumulado
   if(ticks>=N)
     {
      //--- Selecione um novo símbolo a partir da janela de observação do Mercado
      symbol=GetRandomSymbolName();
      //--- Alterar a forma
      ChangeLineAppearance();
      //--- Mude as cores usadas para desenhar os candlesticks
      ChangeColors(colors,candles_colors);
 
      int tries=0;
      //--- Faça 5 tentativas de preencher os buffers de Plot1 com os preços a partir da símbolo
      while(!CopyFromSymbolToBuffers(symbol,rates_total,0,
            ColorCandlesBuffer1,ColorCandlesBuffer2,ColorCandlesBuffer3,
            ColorCandlesBuffer4,ColorCandlesColors,candles_colors)
            && tries<5)
        {
         //--- Um contador de chamadas da função CopyFromSymbolToBuffers()
         tries++;
        }
      //--- Redefinir o contador de ticks para zero
      ticks=0;
     }
//--- valor retorno de prev_calculated para a próxima chamada
   return(rates_total);
  }
//+------------------------------------------------------------------+
//| Preenche o candlestick especificado                              |
//+------------------------------------------------------------------+
bool CopyFromSymbolToBuffers(string name,
                             int total,
                             int plot_index,
                             double &buff1[],
                             double &buff2[],
                             double &buff3[],
                             double &buff4[],
                             double &col_buffer[],
                             int    cndl_colors
                             )
  {
//--- No array de rates[], vamos copiar Open (abertura), High (alta), Low (baixa) e Close (fechamento) de preços
   MqlRates rates[];
//--- O contador de tentativas
   int attempts=0;
//--- Quanto foi copiado
   int copied=0;
//--- Fazer 25 tentativas para obter uma série temporal(timeseries) sobre o símbolo desejado
   while(attempts<25 && (copied=CopyRates(name,_Period,0,bars,rates))<0)
     {
      Sleep(100);
      attempts++;
      if(messagesPrintFormat("%s Copiar taxas(%s) tentativas=%d",__FUNCTION__,nome,tentativas);
     }
//--- Se falhou em copiar um número suficiente de barras
   if(copied!=bars)
     {
      //--- Formar uma mensagem string
      string comm=StringFormat("Para o símbolo %s, conseguiu receber somente %d barras de %d solicitadas",
                               name,
                               copied,
                               bars
                               );
      //--- Mostrar uma mensagem num comentário na janela do gráfico principal
      Comment(comm);
      //--- Mostrar a mensagem
      if(messages) Print(comm);
      return(false);
     }
   else
     {
      //--- Definir a exibição do símbolo
      PlotIndexSetString(plot_index,PLOT_LABEL,name+" Open;"+name+" High;"+name+" Low;"+name+" Close");
      IndicatorSetString(INDICATOR_SHORTNAME,"DRAW_COLOR_CANDLES("+symbol+")");
     }
//--- Inicializar buffers com valores vazios
   ArrayInitialize(buff1,0.0);
   ArrayInitialize(buff2,0.0);
   ArrayInitialize(buff3,0.0);
   ArrayInitialize(buff4,0.0);
//--- Sobre cada tick é copiado preços para os buffers
   for(int i=0;i<copied;i++)
     {
      //--- Calcular o índice apropriado para os buffers
      int buffer_index=total-copied+i;
      //--- Escreva os preços para os buffers
      buff1[buffer_index]=rates[i].open;
      buff2[buffer_index]=rates[i].high;
      buff3[buffer_index]=rates[i].low;
      buff4[buffer_index]=rates[i].close;
      //--- Definir a cor do candlestick
      int color_index=i%cndl_colors;
      col_buffer[buffer_index]=color_index;
     }
   return(true);
  }
//+------------------------------------------------------------------+
//| Aleatoriamente retorna um símbolo de Observação do Mercado       |
//+------------------------------------------------------------------+
string GetRandomSymbolName()
  {
//--- O número de símbolos mostrada na janela de observação do Mercado
   int symbols=SymbolsTotal(true);
//--- A posição de um símbolo na lista - um número aleatório de 0 para símbolos
   int number=MathRand()%symbols;
//--- Retornar o nome de um símbolo na posição especificada
   return SymbolName(number,true);
  }
//+------------------------------------------------------------------+
//| Mudar a cor dos segmentos de candlestick                         |
//+------------------------------------------------------------------+
void  ChangeColors(color  &cols[],int plot_colors)
  {
//--- O número de cores
   int size=ArraySize(cols);
//--- 
   string comm=ChartGetString(0,CHART_COMMENT)+"\r\n\r\n";
 
//--- Para cada índice de cor definir uma nova cor aleatoriamente
   for(int plot_color_ind=0;plot_color_ind<plot_colors;plot_color_ind++)
     {
      //--- Obter um valor aleatório
      int number=MathRand();
      //--- Obter um índice no array col[] como um resto da divisão inteira
      int i=number%size;
      //--- Definir a cor para cada índice com a propriedade PLOT_LINE_COLOR
      PlotIndexSetInteger(0,                    //  O número do estilo gráfico
                          PLOT_LINE_COLOR,      //  Identificador da propriedade
                          plot_color_ind,       //  O índice da cor, onde se escreve a cor
                          cols[i]);             //  Uma nova cor
      //--- Escrever as cores
      comm=comm+StringFormat("CandleColorIndex[%d]=%s \r\n",plot_color_ind,ColorToString(cols[i],true));
      ChartSetString(0,CHART_COMMENT,comm);
     }
//---
  }
//+------------------------------------------------------------------+
//| Mudar a aparência dos candlesticks                               |
//+------------------------------------------------------------------+
void ChangeLineAppearance()
  {
//--- Uma string para a formação de informações sobre as propriedades do candlestick
   string comm="";
//--- Escreve o nome do símbolo
   comm="\r\n"+symbol+comm;
//--- Mostrar a informação no gráfico usando um comentário
   Comment(comm);
  }