input int InpRates=100;
//+------------------------------------------------------------------+
//| Komut dosyası başlatma fonksiyonu |
//+------------------------------------------------------------------+
void OnStart()
{
MqlRates rates[];
//--- çubukları almadan önce başlangıç zamanını hatırla
ulong start=GetMicrosecondCount();
//--- H1 zaman diliminde son 100 çubuğu iste
if(CopyRates(Symbol(), PERIOD_H1,1,InpRates,rates)<InpRates)
{
Print("CopyRates() başarısız oldu, hata ",GetLastError());
return;
}
else
{
//--- kaç tane çubuk alındı ve bunları almak için ne kadar zaman gerekti
PrintFormat("%s: CopyRates %d çubuk aldı (%d ms içerisinde)",
_Symbol,ArraySize(rates),(GetMicrosecondCount()-start)/1000);
}
//--- veritabanını depolamak için dosya adını ayarla
string filename=_Symbol+"_"+EnumToString(PERIOD_H1)+"_"+TimeToString(TimeCurrent())+".sqlite";
StringReplace(filename,":","-"); // dosya adlarında ":" karakteri kullanılamaz
//--- ortak terminal klasöründe veritabanını aç/oluştur
int db=DatabaseOpen(filename,DATABASE_OPEN_READWRITE|DATABASE_OPEN_CREATE|DATABASE_OPEN_COMMON);
if(db==INVALID_HANDLE)
{
Print(filename," veritabanının açılışı başarısız oldu, hata ",GetLastError());
return;
}
else
Print(filename," veritabanı başarıyla açıldı");
//--- Çubuklar tablosunun mevcut olup olmadığını kontrol et
if(DatabaseTableExists(db,"Çubuklar"))
{
//--- Çubuklar tablosunu kaldır
if(!DatabaseExecute(db,"DROP TABLE IF EXISTS Çubuklar"))
{
Print("Çubuklar tablosu kaldırılamadı, hata kodu ",GetLastError());
DatabaseClose(db);
return;
}
}
//--- Çubuklar tablosunu oluştur
if(!DatabaseExecute(db,"CREATE TABLE Çubuklar("
"Sembol CHAR(10),"
"Zaman INT NOT NULL,"
"Açılış REAL,"
"Yüksek REAL,"
"Düşük REAL,"
"Kapanış REAL,"
"Tik_Hacim INT,"
"Spread INT,"
"Gerçek_Hacim INT);"))
{
Print(filename," veritabanında Çubuklar tablosu oluşturulamadı, hata ",GetLastError());
DatabaseClose(db);
return;
}
//--- Çubuklar tablosundaki tüm alanların listesini görüntüle
if(DatabasePrint(db,"PRAGMA TABLE_INFO(Çubuklar)",0)<0)
{
PrintFormat("DatabasePrint(\"PRAGMA TABLE_INFO(Çubuklar)\") başarısız oldu, hata kodu=%d (%d satırında)",GetLastError(),__LINE__);
DatabaseClose(db);
return;
}
//--- Çubuklar tablosuna çubukları eklemek için parametreli istek oluştur
string sql="INSERT INTO Çubuklar(Sembol,Zaman,Açılış,Yüksek,Düşük,Kapanış,Tik_Hacmi,Spread,Gerçek_Hacim)"
" VALUES (?1,?2,?3,?4,?5,?6,?7,?8,?9)"; // istek parametreleri
int request=DatabasePrepare(db,sql);
if(request==INVALID_HANDLE)
{
PrintFormat("DatabasePrepare() başarısız oldu, hata=%d",GetLastError());
Print("SQL isteği: ",sql);
DatabaseClose(db);
return;
}
//--- ilk istek parametresinin değerini ayarla
DatabaseBind(request,0,_Symbol);
//--- Çubuklar tablosuna çubukları eklemeden önce başlangıç zamanını hatırla
start=GetMicrosecondCount();
DatabaseTransactionBegin(db);
int total=ArraySize(rates);
bool request_error=false;
for(int i=0;i<total;i++)
{
//--- girdi eklemeden önce kalan parametrelerin değerlerini ayarla
ResetLastError();
if(!DatabaseBind(request,1,rates[i].time))
{
PrintFormat("DatabaseBind() başarısız oldu, hata=%d",GetLastError());
PrintFormat("Çubuk=%d çizgi=%d",i+1,__LINE__);
request_error=true;
break;
}
//--- önceki DatabaseBind() çağrısı başarılı olduysa, sonraki parametreyi ayarla
if(!request_error &&! DatabaseBind(request,2,rates[i].open))
{
PrintFormat("DatabaseBind() başarısız oldu, hata=%d",GetLastError());
PrintFormat("Çubuk=%d çizgi=%d",i+1,__LINE__);
request_error=true;
break;
}
if(!request_error &&! DatabaseBind(request,3,rates[i].high))
{
PrintFormat("DatabaseBind() başarısız oldu, hata=%d",GetLastError());
PrintFormat("Çubuk=%d çizgi=%d",i+1,__LINE__);
request_error=true;
break;
}
if(!request_error &&! DatabaseBind(request,4,rates[i].low))
{
PrintFormat("DatabaseBind() başarısız oldu, hata=%d",GetLastError());
PrintFormat("Çubuk=%d çizgi=%d",i+1,__LINE__);
request_error=true;
break;
}
if(!request_error &&! DatabaseBind(request,5,rates[i].close))
{
PrintFormat("DatabaseBind() başarısız oldu, hata=%d",GetLastError());
PrintFormat("Çubuk=%d çizgi=%d",i+1,__LINE__);
request_error=true;
break;
}
if(!request_error &&! DatabaseBind(request,6,rates[i].tick_volume))
{
PrintFormat("DatabaseBind() başarısız oldu, hata=%d",GetLastError());
PrintFormat("Çubuk=%d çizgi=%d",i+1,__LINE__);
request_error=true;
break;
}
if(!request_error &&! DatabaseBind(request,7,rates[i].spread))
{
PrintFormat("DatabaseBind() başarısız oldu, hata=%d",GetLastError());
PrintFormat("Çubuk=%d çizgi=%d",i+1,__LINE__);
request_error=true;
break;
}
if(!request_error &&! DatabaseBind(request,8,rates[i].real_volume))
{
PrintFormat("DatabaseBind() başarısız oldu, hata=%d",GetLastError());
PrintFormat("Çubuk=%d çizgi=%d",i+1,__LINE__);
request_error=true;
break;
}
//--- girdiyi eklemek için istek yürüt ve bir hata olup olmadığını kontrol et
if(!request_error &&! DatabaseRead(request)&&(GetLastError()!=ERR_DATABASE_NO_MORE_DATA))
{
PrintFormat("DatabaseRead() başarısız oldu, hata=%d",GetLastError());
DatabaseFinalize(request);
request_error=true;
break;
}
//--- sonraki parametre güncellemesinden önce isteği sıfırla
if(!request_error &&! DatabaseReset(request))
{
PrintFormat("DatabaseReset() başarısız oldu, hata=%d",GetLastError());
DatabaseFinalize(request);
request_error=true;
break;
}
} //--- tüm çubuklardan geçiş tamamlandı
//--- durum
if(request_error)
{
PrintFormat("Çubuklar tablosuna %d çubuk eklenemedi",ArraySize(rates));
DatabaseTransactionRollback(db);
DatabaseClose(db);
return;
}
else
{
DatabaseTransactionCommit(db);
PrintFormat("Çubuklar tablosuna %d çubuk eklendi (%d ms içerisinde)",
ArraySize(rates),(GetMicrosecondCount()-start)/1000);
}
//--- Çubuklar tablosunu csv dosyasına kaydet
string csv_filename=Symbol()+".csv";
long saved=DatabaseExport(db,"SELECT * FROM Çubuklar",csv_filename,DATABASE_EXPORT_HEADER|DATABASE_EXPORT_INDEX|DATABASE_EXPORT_COMMON_FOLDER,";");
if(saved>0)
Print("Çubuklar tablosu ",Symbol(),".csv dosyasına kaydedildi");
else
Print("DatabaseExport() başarısız oldu. Hata ",GetLastError());
//--- veritabanı dosyasını kapat ve bunu rapor et
DatabaseClose(db);
PrintFormat("%s veritabanı kapatıldı",filename);
}
|