DokümantasyonBölümler
MQL5 ReferansıDönüşüm FonksiyonlarıEnumToString 

EnumToString

Herhangi bir tipteki bir sayım değerini, metin biçimine dönüştürür.

string  EnumToString(
   any_enum  value      // herhangi bir tipte sayım değeri
   );

Parametreler

value

[in]  Herhangi bir tipteki sayım değeri.

Dönüş değeri

Sayımın metin ifadesini içeren bir dizgi. Hata mesajını almak için GetLastError() fonksiyonunu çağırın.

Not

Bu fonksiyon, _LastError değişkeni içinde şu hata değerlerini ayarlayabilir:

  • ERR_INTERNAL_ERROR – çalışma ortamı hatası
  • ERR_NOT_ENOUGH_MEMORY – işlemi tamamlamak için yeterli bellek yok
  • ERR_INVALID_PARAMETER – bu sayım değeri ismine izin verilmiyor

 

Örnek:

enum interval  // isimli sabitlerin sayımı
  {
   month=1,     // bir aylık zaman aralığı
   two_months,  // iki ay
   quarter,     // üç ay - bir çeyrek
   halfyear=6,  // yarım yıl
   year=12,     // bir yıl - 12 ay
  };
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- zaman aralığını bir ay olarak ayarla
   interval period=month;
   Print(EnumToString(period)+"="+IntegerToString(period));
 
//--- zaman aralığını bir çeyrek (üç ay) olarak ayarla
   period=quarter;
   Print(EnumToString(period)+"="+IntegerToString(period));
 
//--- zaman aralığını bir yıl (12 ay) olarak ayarla
   period=year;
   Print(EnumToString(period)+"="+IntegerToString(period));
 
//--- emir tipinin nasıl göründüğünü kontrol et
   ENUM_ORDER_TYPE type=ORDER_TYPE_BUY;
   Print(EnumToString(type)+"="+IntegerToString(type));
 
//--- hatalı değerlerin nasıl göründüğünü kontrol et
   type=WRONG_VALUE;
   Print(EnumToString(type)+"="+IntegerToString(type));
 
// Sonuç:
// month=1
// quarter=3
// year=12
// ORDER_TYPE_BUY=0
// ENUM_ORDER_TYPE::-1=-1
  }

Ayrıca Bakınız

Sayımlar, Girdi değişkenleri