MQL5 リファレンス変換関数EnumToString

EnumToString

모든 유형의 열거값을 텍스트 형식으로 변환.

string  EnumToString(
   any_enum  value      // 열거값의 모든 유형
   );

매개변수

값

[in] 열거값의 모든 유형.

값 반환

열거형 텍스트를 나타내는 string. 오류 메시지를 받으려면 GetLastError() 함수를 호출.

주의

함수는 _LastError 변수에서 다음 오류 값을 설정할 수 있습니다:

ERR_INTERNAL_ERROR – 실행 환경의 오류
ERR_NOT_ENOUGH_MEMORY – 메모리가 부족하여 작업을 완료할 수 없음
ERR_INVALID_PARAMETER – 열거형 값의 이름을 허용할 수 없음

예를 들어:

enum interval  // 명명된 상수의 열거
  {
   month=1,     // 1개월 간격
   two_months,  // 2개월
   quarter,     // 3개월 - 1분기
   halfyear=6,  // 반년
   year=12,     // 1년 - 12개월
  };
//+------------------------------------------------------------------+
//| 스크립트 프로그램 시작 함수                                         |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- 시간 간격을 1개월로 설정
   interval period=month;
   Print(EnumToString(period)+"="+IntegerToString(period));

//--- 시간 간격을 1분기(3개월)로 설정
   period=quarter;
   Print(EnumToString(period)+"="+IntegerToString(period));

//--- 시간 간격을 1년(12개월)로 설정
   period=year;
   Print(EnumToString(period)+"="+IntegerToString(period));

//--- 주문 유형이 표시되는 방식을 확인
   ENUM_ORDER_TYPE type=ORDER_TYPE_BUY;
   Print(EnumToString(type)+"="+IntegerToString(type));

//--- 잘못된 값이 표시되는 방식을 확인
   type=WRONG_VALUE;
   Print(EnumToString(type)+"="+IntegerToString(type));

// 결과:
// 개월 =1
// 분기 =3
// 년=12
// ORDER_TYPE_BUY=0
// ENUM_ORDER_TYPE::-1=-1
  }

추가 참조

Enumerations, 변수 입력

DoubleToString

IntegerToString