OnnxRun

Запуск модели ONNX на исполнение.

bool  OnnxRun(
   long    onnx_handle,  // хэндл сессии ONNX
   ulong   flags,        // флаги, описывающие режим запуска
   ...                   // входные и выходные параметры модели
   );

Параметры

onnx_handle

[in] Хэндл объекта сессии ONNX, созданный через OnnxCreate или OnnxCreateFromBuffer.

flags

[in] Флаги из ENUM_ONNX_FLAGS, описывающие режим запуска — ONNX_DEBUG_LOGS и ONNX_NO_CONVERSION.

...

[in] [out] Входные и выходные параметры модели.

В случае успешного выполнения возвращает true, иначе false. Для получения кода ошибки вызовите функцию GetLastError.

ENUM_ONNX_FLAGS

Идентификатор	Описание
ONNX_LOGLEVEL_VERBOSE	Логировать все сообщения
ONNX_LOGLEVEL_INFO	Логировать информационные сообщения, предупреждения и ошибки (этот флаг заменяет ONNX_DEBUG_LOGS)
ONNX_LOGLEVEL_WARNING	Логировать предупреждения и ошибки (по умолчанию)
ONNX_LOGLEVEL_ERROR	Логировать только ошибки
ONNX_NO_CONVERSION	Запрет на автоконверсию, использовать данные пользователя как есть
ONNX_COMMON_FOLDER	Загрузка файла модели из папки Common\Files, по значению равен флагу FILE_COMMON
ONNX_USE_CPU_ONLY	При выполнении ONNX модели использовать только CPU
ONNX_GPU_DEVICE_0	Устройство CUDA с номером 0 (по умолчанию)
ONNX_GPU_DEVICE_1	Устройство CUDA с номером 1 *
ONNX_GPU_DEVICE_2	Устройство CUDA с номером 2 *
ONNX_GPU_DEVICE_3	Устройство CUDA с номером 3 *
ONNX_GPU_DEVICE_4	Устройство CUDA с номером 4 *
ONNX_GPU_DEVICE_5	Устройство CUDA с номером 5 *
ONNX_GPU_DEVICE_6	Устройство CUDA с номером 6 *
ONNX_GPU_DEVICE_7	Устройство CUDA с номером 7 *
ONNX_ENABLE_PROFILING	Включает профилировку ONNX модели

* Флаги вида ONNX_GPU_DEVICE_N следует использовать в системах с двумя и более CUDA-совместимыми GPU. Если указано несколько флагов выбора GPU, будет использовано устройство с наименьшим индексом.

Если указать номер несуществующего устройства, то будет сделан автоматический выбор.

Пример:

const long                             ExtOutputShape[] = {1,1};    // форма выходных данных модели
const long                             ExtInputShape [] = {1,10,4}; // форма входных данных модели
#resource "Python/model.onnx" as uchar ExtModel[]                   // модель в виде ресурса
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
int OnStart(void)
  {
   matrix rates;
//--- получаем 10 баров
   if(!rates.CopyRates("EURUSD",PERIOD_H1,COPY_RATES_OHLC,2,10))
      return(-1);
//--- подаем на вход набор векторов OHLC
   matrix x_norm=rates.Transpose();
   vector m=x_norm.Mean(0);
   vector s=x_norm.Std(0);
   matrix mm(10,4);
   matrix ms(10,4);
//--- заполним матрицы нормировки
   for(int i=0; i<10; i++)
     {
      mm.Row(m,i);
      ms.Row(s,i);
     }
//--- нормируем входные данные
   x_norm-=mm;
   x_norm/=ms;
//--- создаём модель
   long handle=OnnxCreateFromBuffer(ExtModel,ONNX_DEBUG_LOGS);
//--- укажем форму входных данных
   if(!OnnxSetInputShape(handle,0,ExtInputShape))
     {
      Print("OnnxSetInputShape failed, error ",GetLastError());
      OnnxRelease(handle);
      return(-1);
     }
//--- укажем форму выходных данных
   if(!OnnxSetOutputShape(handle,0,ExtOutputShape))
     {
      Print("OnnxSetOutputShape failed, error ",GetLastError());
      OnnxRelease(handle);
      return(-1);
     }
//--- конвертируем нормированные входные данные в тип float
   matrixf x_normf;
   x_normf.Assign(x_norm);
//--- сюда получим выходные данные модели - предсказание цены
   vectorf y_norm(1);
//--- запускаем модель
   if(!OnnxRun(handle,ONNX_DEBUG_LOGS | ONNX_NO_CONVERSION,x_normf,y_norm))
     {
      Print("OnnxRun failed, error ",GetLastError());
      OnnxRelease(handle);
      return(-1);
     }
//--- выведем в лог выходное значение модели
   Print(y_norm);
//--- сделаем обратное преобразование для  получения предсказанной цены
   double y_pred=y_norm[0]*s[3]+m[3];
   Print("price predicted:",y_pred);
//--- завершили работу
   OnnxRelease(handle);
   return(0);
  };

Смотри также

OnnxSetInputShape, OnnxSetOutputShape

OnnxRelease

OnnxGetInputCount