#property copyright "Copyright 2025, MetaQuotes Ltd."
#property link "https://www.mql5.com"
#property version "1.00"
#define COORD_X 200
#define COORD_Y 100
#define OBJ_NAME "TestTextGetSizeBitmapLabel"
#define RES_NAME "TestTextGetSizeResource"
#define COLOR_NULL 0x00FFFFFF
//+------------------------------------------------------------------+
//| Script program start function |
//+------------------------------------------------------------------+
void OnStart()
{
//--- ID del grafico corrente
long chart_id= ChartID();
string font_names[] ={"Arial", "Tahoma", "Calibri"};
uint flags_array[]={0, FONT_ITALIC, FONT_UNDERLINE, FONT_STRIKEOUT};
uint fw_array[]={FW_DONTCARE, FW_THIN, FW_EXTRALIGHT, FW_ULTRALIGHT, FW_LIGHT,
FW_NORMAL, FW_REGULAR, FW_MEDIUM, FW_SEMIBOLD, FW_DEMIBOLD,
FW_BOLD, FW_EXTRABOLD, FW_ULTRABOLD, FW_HEAVY, FW_BLACK};
//--- disabilitare il disegno di qualsiasi attributo del grafico dei prezzi
ChartSetInteger(chart_id, CHART_SHOW, false);
//--- dichiarare i parametri della risorsa grafica
uint rc_width =(int)ChartGetInteger(chart_id, CHART_WIDTH_IN_PIXELS);
uint rc_height=(int)ChartGetInteger(chart_id, CHART_HEIGHT_IN_PIXELS);
uint rc_data[];
uint rc_size=rc_width*rc_height;
//--- creare una risorsa grafica per l'output di testo
if(!CreateResource(chart_id, rc_data, rc_width, rc_height))
return;
//--- ciclare i nomi dei caratteri
for(int i=0; i<(int)font_names.Size(); i++)
{
//--- passare attraverso i flag dei caratteri
for(int j=0; j<(int)flags_array.Size(); j++)
{
//--- disegnare il testo con il carattere e il flag di stile ottenuti dall'array
DrawText(font_names[i], flags_array[j], rc_data, rc_width, rc_height);
Sleep(800);
ArrayInitialize(rc_data, COLOR_NULL);
}
Sleep(800);
ArrayInitialize(rc_data, COLOR_NULL);
}
//--- dopo aver emesso tutti i testi con dimensioni e stili di carattere diversi,
//--- mostrare il testo con flag di larghezza di carattere differenti
for(int i=0; i<(int)fw_array.Size(); i++)
{
//--- impostare la dimensione e il nome del carattere per visualizzare il testo con flag di larghezza
string font_name="Tahoma";
int size=-140;
TextSetFont(font_name, size, fw_array[i]);
//--- creare una stringa di testo disegnata, inviala all'array di pixel della risorsa e aggiorna la risorsa
string text=StringFormat("Text%d: Font name: \"%s%s\", size: %d (%d)", i+1, font_name, FlagWidthDescription(fw_array[i]), size, size/-10);
TextOut(text, COORD_X, COORD_Y, ANCHOR_LEFT_UPPER, rc_data, rc_width, rc_height, ColorToARGB(clrDodgerBlue), COLOR_FORMAT_ARGB_NORMALIZE);
Update(RES_NAME, rc_data, rc_width, rc_height, true);
//--- attendere un secondo
Sleep(1000);
ArrayInitialize(rc_data, COLOR_NULL);
}
//--- attendere cinque secondi, quindi libera la risorsa ed elimina l'oggetto grafico
Sleep(5000);
ResourceFree(RES_NAME);
ObjectDelete(chart_id, OBJ_NAME);
//--- consentire di disegnare qualsiasi attributo del grafico dei prezzi
ChartSetInteger(chart_id, CHART_SHOW, true);
ChartRedraw(chart_id);
/*
I messaggi di testo vengono visualizzati sul grafico come risultato dell'esecuzione dello script.
I testi hanno caratteri diversi, così come flag di stile e larghezza
*/
}
//+------------------------------------------------------------------+
//| Visualizza cinque stringhe di testo diverse |
//| dimensioni con il carattere e i flag specificati |
//+------------------------------------------------------------------+
void DrawText(const string font_name, uint flags, uint &pixels_array[], uint res_width, uint res_height)
{
//--- emettere cinque stringhe di testo con diverse dimensioni di carattere
for(int i=0; i<5; i++)
{
//--- calcolare la dimensione del carattere e impostare il carattere per l'output di testo utilizzando metodi di disegno
int size=-140+10*i;
TextSetFont(font_name, size, flags);
//--- creare una stringa di testo disegnata, inviala all'array di pixel della risorsa e aggiorna la risorsa
string text=StringFormat("Text%d: Font name: \"%s%s\", size: %d (%d)", i+1, font_name, FlagDescription(flags), size, size/-10);
TextOut(text, COORD_X, COORD_Y+22*i, ANCHOR_LEFT_UPPER, pixels_array, res_width, res_height, ColorToARGB(clrDodgerBlue), COLOR_FORMAT_ARGB_NORMALIZE);
Update(RES_NAME, pixels_array, res_width, res_height, true);
//--- aspettare un attimo
Sleep(800);
}
}
//+---------------------------------------------------------------------------+
//| Restituire una descrizione dei flag di stile del carattere |
//+---------------------------------------------------------------------------+
string FlagDescription(const uint flag)
{
switch(flag)
{
case FONT_ITALIC : return(" Italic");
case FONT_UNDERLINE : return(" Underline");
case FONT_STRIKEOUT : return(" Strikeout");
}
return("");
}
//+-------------------------------------------------------------------------------+
//| Restituire la descrizione dei flag di larghezza del carattere |
//+-------------------------------------------------------------------------------+
string FlagWidthDescription(const uint flag)
{
switch(flag)
{
case FW_DONTCARE : return(" Dontcare");
case FW_THIN : return(" Thin");
case FW_EXTRALIGHT: return(" Extralight");
case FW_ULTRALIGHT: return(" Ultralight");
case FW_LIGHT : return(" Light");
case FW_NORMAL : return(" Normal");
case FW_REGULAR : return(" Regular");
case FW_MEDIUM : return(" Medium");
case FW_SEMIBOLD : return(" Semibold");
case FW_DEMIBOLD : return(" Demibold");
case FW_BOLD : return(" Bold");
case FW_EXTRABOLD : return(" Extrabold");
case FW_ULTRABOLD : return(" Ultrabold");
case FW_HEAVY : return(" Heavy");
case FW_BLACK : return(" Black");
}
return("");
}
//+------------------------------------------------------------------+
//| Creare una risorsa grafica per l'intero grafico |
//+------------------------------------------------------------------+
bool CreateResource(const long chart_id, uint &pixel_data[], const uint width, const uint height)
{
//--- impostare la dimensione dell'array di pixel
ResetLastError();
uint size=width*height;
if(ArrayResize(pixel_data, size)!=size)
{
PrintFormat("%s: ArrayResize() failed. Error code %d",__FUNCTION__, GetLastError());
return(false);
}
//--- riempire l'array di pixel con un colore trasparente e creare una risorsa grafica basata su di esso
ArrayInitialize(pixel_data, COLOR_NULL);
if(!ResourceCreate(RES_NAME, pixel_data, width, height, 0, 0, 0, COLOR_FORMAT_ARGB_NORMALIZE))
{
PrintFormat("%s: ResourceCreate() failed. Error code ",__FUNCTION__, GetLastError());
return(false);
}
//--- creare l'oggetto Etichetta Grafica alle coordinate dell'angolo in alto a sinistra del grafico
if(!ObjectCreate(0, OBJ_NAME, OBJ_BITMAP_LABEL, 0, 0, 0))
{
PrintFormat("%s: ObjectCreate() failed. Error code %d",__FUNCTION__, GetLastError());
return(false);
}
//--- impostare la larghezza e l'altezza dell'oggetto bitmap creato uguali alla larghezza e all'altezza della risorsa grafica.
//--- impostare il punto di ancoraggio dell'oggetto al suo centro.
if(!ObjectSetInteger(chart_id, OBJ_NAME, OBJPROP_XSIZE, width))
{
PrintFormat("%s: ObjectSetInteger() failed. Error code %d",__FUNCTION__, GetLastError());
return(false);
}
if(!ObjectSetInteger(chart_id, OBJ_NAME, OBJPROP_YSIZE, height))
{
PrintFormat("%s: ObjectSetInteger() failed. Error code %d",__FUNCTION__, GetLastError());
return(false);
}
//--- specificare la risorsa grafica creata in precedenza per l'oggetto bitmap come file immagine
//--- in questo caso, per indicare il nome della risorsa grafica utilizzata, dobbiamo aggiungere "::" prima del suo nome
if(!ObjectSetString(chart_id, OBJ_NAME, OBJPROP_BMPFILE, "::"+RES_NAME))
{
PrintFormat("%s: ObjectSetString() failed. Error code %d",__FUNCTION__, GetLastError());
return(false);
}
//--- tutto è andato bene
return(true);
}
//+------------------------------------------------------------------+
//| Aggiornare i dati della risorsa grafica |
//+------------------------------------------------------------------+
void Update(const string res_name, const uint &pixel_data[], const uint width, const uint height, const bool redraw)
{
//--- esci se vengono passate dimensioni zero
if(width==0 || height==0)
return;
//--- aggiorna i dati delle risorse e ridisegna il grafico
if(ResourceCreate(res_name, pixel_data, width, height, 0, 0, 0, COLOR_FORMAT_ARGB_NORMALIZE) && redraw)
ChartRedraw();
}
|