Manual de referencia de MQL5Objetos gráficosTextSetFont

TextSetFont

Establece la fuente para visualizar el texto a través de los métodos del dibujo y devuelve el resultado de esta operación. Por defecto se usa la fuente Arial con el tamaño -120 (12 pt).

bool  TextSetFont(
   const string  name,            // nombre de la fuente o la ruta del archivo de la fuente en el disco
   int           size,            // tamaño de la fuente
   uint          flags,           // combinación de banderas
   int           orientation=0    // ángulo de inclinación del texto
   );

Parámetros

name

[in] Nombre de la fuente en el sistema, o el nombre del recurso que contiene la fuente, o la ruta del archivo de la fuente en el disco.

size

[in] Tamaño de la fuente que puede ser establecido con valores positivos y negativos. En caso de valores positivos, el tamaño del texto a mostrar no depende de los ajustes de tamaños de las fuentes en el sistema operativo. En caso de valores negativos, el valor se establece en las décimas partes del punto y el tamaño del texto va a depender de los ajustes del sistema ("escala estándar" o "escala grande"). Más detalles sobre la diferencia entre los regímenes se puede leer en la Nota.

flags

[in] Combinación de banderas que describen el estilo de la fuente.

orientation

[in] Ángulo de inclinación del texto por la horizontal respecto al eje X, la unidad de medición es de 0,1 del grado. Es decir, orientation=450 significa la inclinación bajo un ángulo de 45 grados.

Valor devuelto

Devuelve true si la fuente actual se establece con éxito, de lo contrario es false. Posibles códigos de errores:

ERR_INVALID_PARAMETER(4003) - name representa NULL o "" (cadena vacía),
ERR_INTERNAL_ERROR(4001) - error del sistema operativo (por ejemplo, intento de crear una fuente que no existe).

Nota

Si en el nombre de la fuente se utiliza "::", la fuente se carga desde un recurso EX5. Si el nombre de la fuente name va acompañado con la extensión, entonces esta fuente se carga desde el archivo. En esta caso, si la ruta de la fuente se empieza con "\" o "/", el archivo se busca referente la carpeta MQL5, de lo contrario se busca referente a la ruta del archivo EX5 que ha llamado a la función TextSetFont().

El tamaño de la fuente se establece con valores positivos o negativos, el signo determina la dependencia del tamaño de la fuente de los ajustes del sistema operativo (la escala de la fuente).

Si para establecer el tamaño se utiliza un número positivo, este tamaño se transforma en unidades físicas de medición del dispositivo (píxeles) durante el cambio de la fuente lógica a la física, y este tamaño corresponde a la altura de los glifos del símbolo escogidos desde las fuentes disponibles. Este caso no es recomendable cuando se supone el uso común de los textos visualizados por la función TextOut() y los textos visualizados a través del objeto gráfico OBJ_LABEL ("Etiqueta de texto") en el mismo gráfico.
Si para establecer el tamaño se utiliza un número negativo, se supone que el número especificado se establece en décimas partes del punto lógico (el valor -350 es igual a 35 puntos lógicos) y se divide por 10. Luego el valor obtenido se transforma en unidades físicas de medición del dispositivo (píxeles) y corresponde al valor absoluto de la altura del símbolo desde las fuentes disponibles. Para conseguir en la pantalla el texto con el mismo tamaño que hay en el objeto OBJ_LABEL, es necesario multiplicar el tamaño de la fuente especificada en las propiedades del objeto por -10.

Las banderas pueden ser utilizadas como combinaciones de las banderas del estilo con una de las banderas que determina el grosor de la fuente. Los nombres de las banderas se listan a continuación.

Banderas para fijar el estilo de escritura de la fuente

Bandera	Descripción
FONT_ITALIC	Cursiva
FONT_UNDERLINE	Subrayado
FONT_STRIKEOUT	Tachado

Banderas para fijar el grosor de la fuente

Bandera
FW_DONTCARE
FW_THIN
FW_EXTRALIGHT
FW_ULTRALIGHT
FW_LIGHT
FW_NORMAL
FW_REGULAR
FW_MEDIUM
FW_SEMIBOLD
FW_DEMIBOLD
FW_BOLD
FW_EXTRABOLD
FW_ULTRABOLD
FW_HEAVY
FW_BLACK

Ejemplo:

#property copyright "Copyright 2025, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"

#define   COORD_X    200
#define   COORD_Y    100
#define   OBJ_NAME   "TestTextGetSizeBitmapLabel"
#define   RES_NAME   "TestTextGetSizeResource"
#define   COLOR_NULL 0x00FFFFFF
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- identificador del gráfico actual
   long   chart_id= ChartID();

   string font_names[] ={"Arial", "Tahoma", "Calibri"};
   uint   flags_array[]={0, FONT_ITALIC, FONT_UNDERLINE, FONT_STRIKEOUT};
   uint   fw_array[]={FW_DONTCARE, FW_THIN, FW_EXTRALIGHT, FW_ULTRALIGHT, FW_LIGHT,
                      FW_NORMAL, FW_REGULAR, FW_MEDIUM, FW_SEMIBOLD, FW_DEMIBOLD,
                      FW_BOLD, FW_EXTRABOLD, FW_ULTRABOLD, FW_HEAVY, FW_BLACK};

//--- prohibimos la representación de cualquier atributo del gráfico de precios
   ChartSetInteger(chart_id, CHART_SHOW, false);

//--- declaramos los parámetros del recurso gráfico
   uint rc_width =(int)ChartGetInteger(chart_id, CHART_WIDTH_IN_PIXELS);
   uint rc_height=(int)ChartGetInteger(chart_id, CHART_HEIGHT_IN_PIXELS);
   uint rc_data[];
   uint rc_size=rc_width*rc_height;

//--- creamos un recurso gráfico para la muestra de texto
   if(!CreateResource(chart_id, rc_data, rc_width, rc_height))
      return;

//--- ciclo por los nombres de las fuentes
   for(int i=0; i<(int)font_names.Size(); i++)
     {
      //--- ciclo por las banderas de las fuentes
      for(int j=0; j<(int)flags_array.Size(); j++)
        {
         //--- dibujamos el texto con la fuente y la bandera de dibujado obtenidos del array
         DrawText(font_names[i], flags_array[j], rc_data, rc_width, rc_height);
         Sleep(800);
         ArrayInitialize(rc_data, COLOR_NULL);
        }
      Sleep(800);
      ArrayInitialize(rc_data, COLOR_NULL);
     }

//--- después de mostrar todos los textos con diferentes tamaños y dibujado de fuente,
//--- mostramos el texto con diferentes banderas de grosor de fuente
   for(int i=0; i<(int)fw_array.Size(); i++)
     {
      //--- establecemos el tamaño y el nombre de la fuente para mostrar el texto con las banderas de grosor
      string font_name="Tahoma";
      int    size=-140;
      TextSetFont(font_name, size, fw_array[i]);

      //--- creamos la cadena de texto dibujada, la mostramos en el array de píxeles del recurso y actualizamos el recurso
      string text=StringFormat("Text%d: Font name: \"%s%s\", size: %d (%d)", i+1, font_name, FlagWidthDescription(fw_array[i]), size, size/-10);
      TextOut(text, COORD_X, COORD_Y, ANCHOR_LEFT_UPPER, rc_data, rc_width, rc_height, ColorToARGB(clrDodgerBlue), COLOR_FORMAT_ARGB_NORMALIZE);
      Update(RES_NAME, rc_data, rc_width, rc_height, true);
      //--- esperamos un segundo
      Sleep(1000);
      ArrayInitialize(rc_data, COLOR_NULL);
     }

//--- esperamos cinco segundos, luego liberamos el recurso y eliminamos el objeto gráfico
   Sleep(5000);
   ResourceFree(RES_NAME);
   ObjectDelete(chart_id, OBJ_NAME);

//--- permitimos la representación de cualquier atributo del gráfico de precios
   ChartSetInteger(chart_id, CHART_SHOW, true);
   ChartRedraw(chart_id);
   /*
  como resultado del funcionamiento del script, se mostrarán mensajes de texto en el gráfico
  diferentes tipos de fuente con diferentes tamaños y banderas de dibujado y anchura de texto
   */
  }
//+------------------------------------------------------------------+
//| Muestra en el gráfico cinco cadenas de texto de diferentes       |
//| tamaños con la fuente y las banderas especificadas               |
//+------------------------------------------------------------------+
void DrawText(const string font_name, uint flags, uint &pixels_array[], uint res_width, uint res_height)
  {
//--- mostramos cinco cadenas de texto con diferentes tamaños de fuente
   for(int i=0; i<5; i++)
     {
      //--- calculamos el tamaño de fuente y establecemos la fuente para mostrar el texto mediante los métodos de dibujado
      int size=-140+10*i;
      TextSetFont(font_name, size, flags);

      //--- creamos la cadena de texto dibujada, la mostramos en el array de píxeles del recurso y actualizamos el recurso
      string text=StringFormat("Text%d: Font name: \"%s%s\", size: %d (%d)", i+1, font_name, FlagDescription(flags), size, size/-10);
      TextOut(text, COORD_X, COORD_Y+22*i, ANCHOR_LEFT_UPPER, pixels_array, res_width, res_height, ColorToARGB(clrDodgerBlue), COLOR_FORMAT_ARGB_NORMALIZE);
      Update(RES_NAME, pixels_array, res_width, res_height, true);
      //--- esperamos un poco
      Sleep(800);
     }
  }
//+------------------------------------------------------------------+
//| Retorna la descripción de las banderas de dibujado de la fuente  |
//+------------------------------------------------------------------+
string FlagDescription(const uint flag)
  {
   switch(flag)
     {
      case FONT_ITALIC     :  return(" Italic");
      case FONT_UNDERLINE  :  return(" Underline");
      case FONT_STRIKEOUT  :  return(" Strikeout");
     }
   return("");
  }
//+------------------------------------------------------------------+
//| Retorna la descripción de las banderas de grosor de la fuente    |
//+------------------------------------------------------------------+
string FlagWidthDescription(const uint flag)
  {
   switch(flag)
     {
      case FW_DONTCARE  :  return(" Dontcare");
      case FW_THIN      :  return(" Thin");
      case FW_EXTRALIGHT:  return(" Extralight");
      case FW_ULTRALIGHT:  return(" Ultralight");
      case FW_LIGHT     :  return(" Light");
      case FW_NORMAL    :  return(" Normal");
      case FW_REGULAR   :  return(" Regular");
      case FW_MEDIUM    :  return(" Medium");
      case FW_SEMIBOLD  :  return(" Semibold");
      case FW_DEMIBOLD  :  return(" Demibold");
      case FW_BOLD      :  return(" Bold");
      case FW_EXTRABOLD :  return(" Extrabold");
      case FW_ULTRABOLD :  return(" Ultrabold");
      case FW_HEAVY     :  return(" Heavy");
      case FW_BLACK     :  return(" Black");
     }
   return("");
  }
//+------------------------------------------------------------------+
//| Crea un recurso gráfico para todo el gráfico                     |
//+------------------------------------------------------------------+
bool CreateResource(const long chart_id, uint &pixel_data[], const uint width, const uint height)
  {
//--- establecemos el tamaño del array de píxeles
   ResetLastError();
   uint size=width*height;
   if(ArrayResize(pixel_data, size)!=size)
     {
      PrintFormat("%s: ArrayResize() failed. Error code %d",__FUNCTION__, GetLastError());
      return(false);
     }
//--- rellenamos el array de píxeles con un color transparente y creamos un recurso gráfico basado en él
   ArrayInitialize(pixel_data, COLOR_NULL);
   if(!ResourceCreate(RES_NAME, pixel_data, width, height, 0, 0, 0, COLOR_FORMAT_ARGB_NORMALIZE))
     {
      PrintFormat("%s: ResourceCreate() failed. Error code ",__FUNCTION__, GetLastError());
      return(false);
     }

//--- creamos un objeto "Etiqueta Gráfica" en las coordenadas de la esquina superior izquierda del gráfico
   if(!ObjectCreate(0, OBJ_NAME, OBJ_BITMAP_LABEL, 0, 0, 0))
     {
      PrintFormat("%s: ObjectCreate() failed. Error code %d",__FUNCTION__, GetLastError());
      return(false);
     }
//--- establecemos una anchura y altura del objeto de dibujo creado iguales a la anchura y altura del recurso gráfico.
//--- establecemos el punto de anclaje del objeto en su centro.
   if(!ObjectSetInteger(chart_id, OBJ_NAME, OBJPROP_XSIZE, width))
     {
      PrintFormat("%s: ObjectSetInteger() failed. Error code %d",__FUNCTION__, GetLastError());
      return(false);
     }
   if(!ObjectSetInteger(chart_id, OBJ_NAME, OBJPROP_YSIZE, height))
     {
      PrintFormat("%s: ObjectSetInteger() failed. Error code %d",__FUNCTION__, GetLastError());
      return(false);
     }
//--- para el objeto de imagen, especificamos como archivo de imagen el recurso gráfico creado previamente
//--- en este caso, para especificar el nombre del recurso gráfico utilizado, deberemos escribir antes de su nombre "::"
   if(!ObjectSetString(chart_id, OBJ_NAME, OBJPROP_BMPFILE, "::"+RES_NAME))
     {
      PrintFormat("%s: ObjectSetString() failed. Error code %d",__FUNCTION__, GetLastError());
      return(false);
     }

//--- todo ha tenido éxito
   return(true);
  }
//+------------------------------------------------------------------+
//| Actualiza los datos del recurso gráfico                          |
//+------------------------------------------------------------------+
void Update(const string res_name, const uint &pixel_data[], const uint width, const uint height, const bool redraw)
  {
//--- si se ha transferido un tamaño cero, salimos
   if(width==0 || height==0)
      return;
//--- actualizamos los datos de recursos y redibujamos el gráfico
   if(ResourceCreate(res_name, pixel_data, width, height, 0, 0, 0, COLOR_FORMAT_ARGB_NORMALIZE) && redraw)
      ChartRedraw();
  }

Véase también

Recursos, ResourceCreate(), ResourceSave(), TextOut()

ObjectGetString

TextOut