#include <Trade\Trade.mqh>
#define MAGIC (123)
//--- input parameters
input string InpFileNameOK = "ok.wav"; // файл с озвучиванием успеха
input string InpFileNameErr = "timeout.wav"; // файл с озвучиванием ошибки
input ENUM_ORDER_TYPE InpOrderType = ORDER_TYPE_BUY_LIMIT; // тип ордера
input double InpLots = 0.1; // лоты
//--- global variables
CTrade ExtTrade;
//+------------------------------------------------------------------+
//| Script program start function |
//+------------------------------------------------------------------+
void OnStart()
{
//--- устанавливаем магик и тип ордера по исполнению согласно настройкам символа
ExtTrade.SetExpertMagicNumber(MAGIC);
ExtTrade.SetTypeFillingBySymbol(Symbol());
//--- вызываем функцию установки ордера или открытия позиции с воспроизведением звука
OrderSendWithAudio();
}
//+------------------------------------------------------------------+
//| Функция устанавливает ордер или открывает позицию |
//| и воспроизводит звук успеха или ошибки |
//+------------------------------------------------------------------+
void OrderSendWithAudio(void)
{
bool res=true;
MqlTick tick= {};
ResetLastError();
if(!SymbolInfoTick(Symbol(),tick))
{
Print("SymbolInfoTick() failed. Error code: ",GetLastError());
PlaySound(InpFileNameErr);
return;
}
//--- отправим запрос на сервер
switch(InpOrderType)
{
case ORDER_TYPE_BUY :
res=ExtTrade.Buy(InpLots);
break;
case ORDER_TYPE_BUY_LIMIT :
res=ExtTrade.BuyLimit(InpLots,NormalizeDouble(tick.ask-100*Point(),Digits()));
break;
case ORDER_TYPE_BUY_STOP :
res=ExtTrade.BuyStop(InpLots,NormalizeDouble(tick.ask+100*Point(),Digits()));
break;
case ORDER_TYPE_SELL :
res=ExtTrade.Sell(InpLots);
break;
case ORDER_TYPE_SELL_LIMIT :
res=ExtTrade.SellLimit(InpLots,NormalizeDouble(tick.bid+100*Point(),Digits()));
break;
case ORDER_TYPE_SELL_STOP :
res=ExtTrade.SellStop(InpLots,NormalizeDouble(tick.bid-100*Point(),Digits()));
break;
default :
res=false;
}
if(!res)
Print("Error ",GetLastError());
Print(ExtTrade.ResultRetcodeDescription());
//--- если запрос принят, проигрываем звук ok.wav
if(ExtTrade.ResultRetcode()==TRADE_RETCODE_DONE)
PlaySound(InpFileNameOK);
else
PlaySound(InpFileNameErr);
}
|