DRAW_COLOR_HISTOGRAM

//+------------------------------------------------------------------+
//|                                         DRAW_COLOR_HISTOGRAM.mq5 |
//|                         Copyright 2000-2024, MetaQuotes Ltd. |
//|                                              https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
 
#property description "DRAW_COLOR_HISTOGRAM을 시연하기 위한 지표"
#property description "별도의 창에 사인파를 히스토그램으로 그립니다"
#property description "열의 색상과 너비가 임의로 변경됩니다"
#property description "모든 N 틱 후"
#property description "막대 매개변수는 사인파형을 반복할 막대 수를 설정합니다"
 
#property indicator_separate_window
#property indicator_buffers 2
#property indicator_plots   1
//--- 매개변수 입력
input int      bars=30;          // 막대의 사인파 주기
input int      N=5;              // 히스토그램을 변경할 틱 
//--- Color_Histogram 플롯
#property indicator_label1  "Color_Histogram"
#property indicator_type1   DRAW_COLOR_HISTOGRAM
//--- 채색 섹션을 위한 8가지 색상 정의(특수 배열에 저장됨)
#property indicator_color1  clrRed,clrGreen,clrBlue,clrYellow,clrMagenta,clrCyan,clrMediumSeaGreen,clrGold
#property indicator_style1  STYLE_SOLID
#property indicator_width1  1
//--- 값의 버퍼
double         Color_HistogramBuffer[];
//--- 색상 인덱스의 버퍼
double         Color_HistogramColors[];
//--- 막대 매개변수를 곱산 경우 라디안 단위로 2Pi 각도를 구하는 계수
double         multiplier;
int            color_sections;
//--- 색상을 저장하는 배열에는 14개의 요소가 포함됩니다
color colors[]=
  {
   clrRed,clrBlue,clrGreen,clrChocolate,clrMagenta,clrDodgerBlue,clrGoldenrod,
   clrIndigo,clrLightBlue,clrAliceBlue,clrMoccasin,clrWhiteSmoke,clrCyan,clrMediumPurple
  };
//--- 선 스타일을 저장할 배열
ENUM_LINE_STYLE styles[]={STYLE_SOLID,STYLE_DASH,STYLE_DOT,STYLE_DASHDOT,STYLE_DASHDOTDOT};
//+------------------------------------------------------------------+
//| 사용자 지정 지표 초기화 함수                         |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- 지표 버퍼 맵핑
   SetIndexBuffer(0,Color_HistogramBuffer,INDICATOR_DATA);
   SetIndexBuffer(1,Color_HistogramColors,INDICATOR_COLOR_INDEX);
//---- 사인파를 채색할 색상의 수
   color_sections=8;   //  see A comment to #property indicator_color1   
//--- 승수를 계산
   if(bars>1)multiplier=2.*M_PI/bars;
   else
     {
      PrintFormat("Set the value of bars=%d greater than 1",bars);
      //--- 지표의 조기 종료
      return(INIT_PARAMETERS_INCORRECT);
     }   
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| 사용자 지정 지표 반복 함수                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
   static int ticks=0;
//--- 틱을 계산하여 선의 스타일, 색상 및 너비 변경
   ticks++;
//--- 틱의 임계 수가 누적된 경우
   if(ticks>=N)
     {
      //--- 선 속성 변경
      ChangeLineAppearance();
      //--- 히스토그램에 사용되는 색상 변경
      ChangeColors(colors,color_sections);      
      //--- 틱 카운터를 0으로 재설정
      ticks=0;
     }
 
//--- 지표 값 계산
   int start=0;
//--- 이전 OnCalculate 시작 중에 이미 계산된 경우
   if(prev_calculated>0) start=prev_calculated-1; // 계산의 시작을 단 하나의 막대로 설정
//--- 지표 버퍼에 값을 입력
   for(int i=start;i<rates_total;i++)
     {
      //--- 값
      Color_HistogramBuffer[i]=sin(i*multiplier);
      //--- 색상
      int color_index=i%(bars*color_sections);
      color_index/=bars;
      Color_HistogramColors[i]=color_index;
     }
//--- 함수의 다음 호출에 대해 prev_calculated 값을 반환
   return(rates_total);
  }
//+------------------------------------------------------------------+
//| 선 세그먼트의 색상을 변경                               |
//+------------------------------------------------------------------+
void  ChangeColors(color  &cols[],int plot_colors)
  {
//--- 색상의 수
   int size=ArraySize(cols);
//--- 
   string comm=ChartGetString(0,CHART_COMMENT)+"\r\n\r\n";
 
//--- 각 색상 인덱스에 대해 임의로 새 색상 정의
   for(int plot_color_ind=0;plot_color_ind<plot_colors;plot_color_ind++)
     {
      //--- 임의 값 가져오기
      int number=MathRand();
      //--- col[] 배열의 인덱스를 정수 나눗셈의 나머지 항목으로 가져오기
      int i=number%size;
      //--- 각 인덱스의 색상을 PLOT_LINE_COLOR 속성으로 설정
      PlotIndexSetInteger(0,                    //  그래픽 스타일의 수
                          PLOT_LINE_COLOR,      //  속성 식별자
                          plot_color_ind,       //  색의 인덱스, 색상을 쓰는 곳
                          cols[i]);             //  새 색상
      //--- 색상 쓰기
      comm=comm+StringFormat("HistogramColorIndex[%d]=%s \r\n",plot_color_ind,ColorToString(cols[i],true));
      ChartSetString(0,CHART_COMMENT,comm);
     }
//---
  }
//+------------------------------------------------------------------+
//| 지표에 표시된 선의 모양을 변경      |
//+------------------------------------------------------------------+
void ChangeLineAppearance()
  {
//--- 라인 속성에 대한 정보를 구성하기 위한 문자열
   string comm="";
//--- 선 너비 변경 블록
   int number=MathRand();
//--- 정수 나눗셈의 나머지 너비 가져오기
   int width=number%5; // 너비는 0 ~ 4로 설정됩니다
//--- 색상을 PLOT_LINE_WIDTH 속성으로 설정
   PlotIndexSetInteger(0,PLOT_LINE_WIDTH,width);
//--- 선 너비 쓰기
   comm=comm+" Width="+IntegerToString(width);
 
//--- 선의 스타일을 변경하기 위한 블록
   number=MathRand();
//--- 제수는 스타일 배열의 크기와 같습니다
   int size=ArraySize(styles);
//--- 정수 나눗셈의 나머지 항목으로 새 스타일을 선택할 인덱스를 가져오기
   int style_index=number%size;
//--- 색상을 PLOT_LINE_COLOR 속성으로 설정
   PlotIndexSetInteger(0,PLOT_LINE_STYLE,styles[style_index]);
//--- 선 스타일 쓰기
   comm=EnumToString(styles[style_index])+", "+comm;
//--- 설명을 사용하여 차트에 정보 표시
   Comment(comm);
  }