Скачать MetaTrader 5

DRAW_CANDLES

Стиль DRAW_CANDLES рисует японские свечи по значениям четырёх индикаторных буферов, в которых содержатся цены Open, High, Low и Close. Предназначен для создания собственных индикаторов в виде свечей, в том числе в отдельном подокне графика и по другим финансовым инструментам.

Цвет свечей можно задавать директивами компилятора или динамически с помощью функции PlotIndexSetInteger(). Динамическое изменение свойств графического построения позволяет "оживить" индикаторы, чтобы они меняли свой вид в зависимости от  текущей ситуации.

Индикатор рисуется только для тех баров, для которых заданы непустые значения всех четырёх индикаторных буферов. Чтобы указать, какое значение следует считать "пустым", установите это значение в свойстве PLOT_EMPTY_VALUE:

//--- значение 0 (пустое значение) не будет участвовать в отрисовке
   PlotIndexSetDouble(индекс_построения_DRAW_CANDLES,PLOT_EMPTY_VALUE,0);

Всегда явно заполняйте значениями индикаторные буферы, на пропускаемых барах указывайте в буфере пустое значение.

Количество требуемых буферов для построения DRAW_CANDLES — 4. Все буферы для построения должны идти последовательно один за другим в заданном порядке: Open, High, Low и Close.  Ни один из буферов не может содержать только пустые значения, так как в этом случае отрисовка не происходит.

Для стиля DRAW_CANDLES можно задавать от одного до трёх цветов, в зависимости от этого меняется внешний вид свечей. Если указан только один цвет, то все свечи на графике будут полностью окрашены этим цветом.

//--- одинаковые свечи, окрашенные в один цвет 
#property indicator_label1  "One color candles"
#property indicator_type1   DRAW_CANDLES
//--- указан только один цвет, поэтому все свечи будут одного цвета
#property indicator_color1  clrGreen  

Если указать два цвета через запятую, то контуры свечи будут отрисовываться первым цветом, а тело вторым цветом.

//--- цвет свечей отличается от цвета теней
#property indicator_label1  "Two color candles"
#property indicator_type1   DRAW_CANDLES
//--- тени и контур свечей зеленого цвета, тело белого цвета
#property indicator_color1  clrGreen,clrWhite 

Для того чтобы по разному показывать растущие и падающие свечи, необходимо указать через запятую 3 цвета. В этом случае контур свечи будет нарисован первым цветом, а цвет бычьей и медвежьей свечей будет задаваться вторым и третьим цветом.

//--- цвет свечей отличается от цвета теней
#property indicator_label1  "One color candles"
#property indicator_type1   DRAW_CANDLES
//--- тени и контур зелёного цвета, тело бычьей свечи белого цвета, тело медвежьей свечи красного цвета
#property indicator_color1  clrGreen,clrWhite,clrRed

Таким образом, с помощью стиля DRAW_CANDLES можно создавать собственные пользовательские варианты раскраски свечей. Все цвета можно также менять динамически в процессе работы индикатора с помощью функции PlotIndexSetInteger(индекс_построения_DRAW_CANDLES, PLOT_LINE_COLOR, номер_модификатора, цвет) , где номер_модификатора можеть иметь следующие значения:

  • 0 – цвет контура и теней
  • 1– цвет тела бычьей свечи
  • 2 – цвет тела медвежьей свечи

//--- установим цвет контура и теней
PlotIndexSetInteger(0,PLOT_LINE_COLOR,0,clrBlue);
//--- установим цвет тела для бычьей свечи
PlotIndexSetInteger(0,PLOT_LINE_COLOR,1,clrGreen);
//--- установим цвет тела для медвежьей свечи
PlotIndexSetInteger(0,PLOT_LINE_COLOR,2,clrRed);

Пример индикатора, рисующего в отдельном окне японские свечи по указанному финансовому инструменту. Цвет свечей меняется случайным образом каждые N тиков. Параметр N вынесен во внешние параметры индикатора для возможности ручной установки (закладка "Параметры" в окне свойств индикатора).

Пример стиля DRAW_CANDLES

Обратите внимание, первоначально для графического построения plot1 цвет задается с помощью директивы компилятора #property, а затем в функции OnCalculate() выбирается новый цвет случайным образом из заранее подготовленного списка.

//+------------------------------------------------------------------+
//|                                                 DRAW_CANDLES.mq5 |
//|                        Copyright 2011, MetaQuotes Software Corp. |
//|                                              https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2011, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
 
#property description "Индикатор для демонстрации DRAW_CANDLES."
#property description "Рисует в отдельном окне разным цветом свечи по случайно выбранному из MarketWatch символу."
#property description " "
#property description "Цвет и толщина свечей, а также символ, меняются"
#property description "случайным образом через каждые N тиков."
 
#property indicator_separate_window
#property indicator_buffers 4
#property indicator_plots   1
//--- plot Bars
#property indicator_label1  "DRAW_CANDLES1"
#property indicator_type1   DRAW_CANDLES
#property indicator_color1  clrGreen
#property indicator_style1  STYLE_SOLID
#property indicator_width1  1
 
//--- input параметры
input int      N=5;              // количество тиков для смены вида
input int      bars=500;         // сколько баров показывать
input bool     messages=false;   // вывод сообщений в лог "Эксперты"
//--- индикаторные буферы
double         Candle1Buffer1[];
double         Candle1Buffer2[];
double         Candle1Buffer3[];
double         Candle1Buffer4[];
//--- имя символа
string symbol;
//--- массив для хранения цветов
color colors[]={clrRed,clrBlue,clrGreen,clrPurple,clrBrown,clrIndianRed};
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- если bars слишком мало - досрочно завершаем работу
   if(bars<50)
     {
      Comment("Укажите большее количество баров! Работа индикатора прекращена");
      return(INIT_PARAMETERS_INCORRECT);
     }
//--- indicator buffers mapping
   SetIndexBuffer(0,Candle1Buffer1,INDICATOR_DATA);
   SetIndexBuffer(1,Candle1Buffer2,INDICATOR_DATA);
   SetIndexBuffer(2,Candle1Buffer3,INDICATOR_DATA);
   SetIndexBuffer(3,Candle1Buffer4,INDICATOR_DATA);
//--- пустое значение
   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0);
//--- имя символа, по которому рисуются бары
   symbol=_Symbol;
//--- установим отображение символа 
   PlotIndexSetString(0,PLOT_LABEL,symbol+" Open;"+symbol+" High;"+symbol+" Low;"+symbol+" Close");
   IndicatorSetString(INDICATOR_SHORTNAME,"DRAW_CANDLES("+symbol+")");
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
   static int ticks=INT_MAX-100;
//--- считаем тики для изменения стиля, цвета и толщины линии
   ticks++;
//--- если накопилось достаточное число тиков
   if(ticks>=N)
     {
      //--- выберем новый символ из окна "Обзор рынка"
      symbol=GetRandomSymbolName();
      //--- сменим вид
      ChangeLineAppearance();
      //--- выберем новый символ из окна "Обзор рынка"
      int tries=0;
      //--- сделаем 5 попыток заполнить буферы plot1 ценами из symbol
      while(!CopyFromSymbolToBuffers(symbol,rates_total,0,
            Candle1Buffer1,Candle1Buffer2,Candle1Buffer3,Candle1Buffer4)
            && tries<5)
        {
         //--- счетчик вызовов функции CopyFromSymbolToBuffers()
         tries++;
        }
      //--- сбрасываем счетчик тиков в ноль
      ticks=0;
     }
//--- return value of prev_calculated for next call
   return(rates_total);
  }
//+------------------------------------------------------------------+
//| Заполняет указанную свечу                                        |
//+------------------------------------------------------------------+
bool CopyFromSymbolToBuffers(string name,
                             int total,
                             int plot_index,
                             double &buff1[],
                             double &buff2[],
                             double &buff3[],
                             double &buff4[]
                             )
  {
//--- в массив rates[] будем копировать цены Open, High, Low и Close
   MqlRates rates[];
//--- счетчик попыток
   int attempts=0;
//--- сколько скопировано
   int copied=0;
//--- делаем 25 попыток получить таймсерию по нужному символу
   while(attempts<25 && (copied=CopyRates(name,_Period,0,bars,rates))<0)
     {
      Sleep(100);
      attempts++;
      if(messagesPrintFormat("%s CopyRates(%s) attempts=%d",__FUNCTION__,name,attempts);
     }
//--- если не удалось скопировать достаточное количество баров
   if(copied!=bars)
     {
      //--- сформируем строку сообщения
      string comm=StringFormat("Для символа %s удалось получить только %d баров из %d затребованных",
                               name,
                               copied,
                               bars
                               );
      //--- выведем сообщение в комментарий на главное окно графика
      Comment(comm);
      //--- выводим сообщения
      if(messagesPrint(comm);
      return(false);
     }
   else
     {
      //--- установим отображение символа 
      PlotIndexSetString(plot_index,PLOT_LABEL,name+" Open;"+name+" High;"+name+" Low;"+name+" Close");
     }
//--- инициализируем буферы пустыми значениями
   ArrayInitialize(buff1,0.0);
   ArrayInitialize(buff2,0.0);
   ArrayInitialize(buff3,0.0);
   ArrayInitialize(buff4,0.0);
//--- на каждом тике копируем цены в буферы
   for(int i=0;i<copied;i++)
     {
      //--- вычислим соответствующий индекс для буферов
      int buffer_index=total-copied+i;
      //--- записываем цены в буферы
      buff1[buffer_index]=rates[i].open;
      buff2[buffer_index]=rates[i].high;
      buff3[buffer_index]=rates[i].low;
      buff4[buffer_index]=rates[i].close;
     }
   return(true);
  }
//+------------------------------------------------------------------+
//| Возвращает случайным образом символ из Market Watch              |
//+------------------------------------------------------------------+
string GetRandomSymbolName()
  {
//--- количество символов, показываемых в окне "Обзор рынка"
   int symbols=SymbolsTotal(true);
//--- позиция символа в списке - случайное число от 0 до symbols
   int number=MathRand()%symbols;
//--- вернем имя символа по указанной позиции
   return SymbolName(number,true);
  }
//+------------------------------------------------------------------+
//| Изменяет внешний вид баров                                       |
//+------------------------------------------------------------------+
void ChangeLineAppearance()
  {
//--- строка для формирования информации о свойствах баров
   string comm="";
//--- блок изменения цвета баров
   int number=MathRand(); // получим случайное число
//--- делитель числа равен размеру массива colors[]
   int size=ArraySize(colors);
//--- получим индекс для выбора нового цвета как остаток от целочисленного деления
   int color_index=number%size;
//--- установим цвет как свойство PLOT_LINE_COLOR
   PlotIndexSetInteger(0,PLOT_LINE_COLOR,colors[color_index]);
//--- запишем цвет 
   comm=comm+"\r\n"+(string)colors[color_index];
//--- запишем имя символа
   comm="\r\n"+symbol+comm;
//--- выведем информацию на график через комментарий
   Comment(comm);
  }

 


Обновлено: 2016.10.10