Recursos do Assistente MQL5 que você precisa conhecer (Parte 77): Uso dos indicadores Gator e A/D (Accumulation/Distribution)

Introdução

Dando continuidade ao estudo das combinações de indicadores para gerar os principais sinais de negociação, vamos analisar o oscilador Gator e o indicador de Acumulação/Distribuição (A/D). Ao contrário do A/D, o oscilador Gator não indica, por si só, a direção do mercado. No entanto, os dois indicadores se complementam: enquanto um acompanha o momentum, o outro considera o volume para confirmar os sinais. Como o Gator não fornece informações sobre a direção da tendência, precisamos recorrer a outro indicador ou à análise da ação do preço para identificá-la. Neste artigo, adotaremos a segunda abordagem.

Oscilador Gator

O oscilador Gator foi desenvolvido por Bill Williams para medir o grau de convergência e divergência entre as três médias móveis do Alligator, outro indicador composto de sua autoria. O Alligator é formado por três buffers conhecidos como "mandíbula", "dentes" e "lábios". O oscilador Gator, por sua vez, oferece uma representação visual do comportamento do Alligator, destacando suas quatro fases: sono, despertar, alimentação e saciedade. Essas fases representam diferentes etapas do ciclo de mercado, que abrange períodos de tendência, períodos sem tendência definida e movimentos laterais voláteis. Elas são especialmente úteis para identificar o início de uma tendência, quando as "mandíbulas" se abrem, e os sinais de seu esgotamento, associados ao fechamento dessas mesmas "mandíbulas".

Segundo os defensores do indicador, sua vantagem é fornecer sinais visuais claros das mudanças de fase da tendência por meio das barras verdes e vermelhas do histograma, distribuídas acima e abaixo da linha zero. Sua limitação é que, por si só, ele não permite prever o movimento dos preços. Para identificar pontos de entrada e saída, é necessário analisar a ação do preço ou recorrer a outros indicadores. O cálculo do oscilador Gator é realizado em etapas. Primeiro, determinamos o preço mediano:

Em seguida, calculamos os buffers das médias móveis correspondentes à "mandíbula", aos "dentes" e aos "lábios":

Onde:

• SMMA(series, n) é a média móvel suavizada da série de preços series, com período n (neste caso, series corresponde ao preço mediano);
• jaw_period=13, jaw_shift=8;
• teeth_period=8, teeth_shift=5;
• lips_period=5, lips_shift=3.

Com os três buffers principais definidos, podemos calcular os valores dos histogramas superior e inferior do indicador.

Onde:

• ∣⋅∣ representa o valor absoluto;
• Gator_Up é plotado acima da linha zero, enquanto Gator_Down é plotado abaixo dela, assumindo valores negativos.

As "linhas do Alligator", correspondentes aos buffers "mandíbula", "dentes" e "lábios", utilizam médias móveis suavizadas (SMMA) com deslocamento para a frente. Essa configuração dá ao indicador a aparência de "olhar adiante", fazendo com que ele funcione mais como um identificador das fases do mercado do que como um simples indicador de cruzamento de médias móveis. O histograma Gator_Up representa a diferença absoluta entre a "mandíbula" e os "dentes". O aumento desse valor indica que a "boca" do Gator está se abrindo, o que pode sinalizar o início de uma tendência. Já o histograma Gator_Down representa o negativo da diferença absoluta entre os "dentes" e os "lábios". O aumento de seu valor absoluto, ou seja, o deslocamento para valores cada vez mais negativos, confirma a fase de tendência ou seu esgotamento. Em geral, uma barra verde indica que seu comprimento aumentou em relação à barra anterior, enquanto uma barra vermelha indica que diminuiu. Quando não há alteração, a barra mantém a cor da anterior.

O oscilador Gator ajuda a identificar momentos favoráveis para entrar no mercado e a evitar períodos de baixa volatilidade e pouca atividade. Uma entrada só deve ser considerada quando as barras dos dois histogramas estiverem aumentando e apresentarem a cor verde, caracterizando a fase de alimentação. Esse indicador é mais adequado a estratégias de acompanhamento de tendência do que à negociação em faixas de preço ou a estratégias de reversão à média. É fundamental preservar os deslocamentos das médias móveis utilizadas nesses buffers: substituí-los por zero resulta em um indicador completamente diferente e de pouca utilidade. Por fim, é necessário combinar o indicador com a análise da ação do preço, identificando rompimentos, máximas mais altas e mínimas mais baixas. Essa análise é indispensável porque o Gator não identifica a direção da tendência.

Oscilador A/D

O segundo indicador abordado neste artigo é o oscilador de Acumulação/Distribuição (A/D). Ele mede a pressão compradora e vendedora com base nos preços e no volume. Seu objetivo é identificar o fluxo efetivo de capital, distinguindo a acumulação, caracterizada por compras realizadas por grandes participantes do mercado, da distribuição, caracterizada pelas vendas desses mesmos participantes. As divergências entre o indicador e o preço podem funcionar como sinais de alerta ou de confirmação, dependendo das condições do mercado. Por exemplo, em determinadas situações, uma alta dos preços acompanhada de queda no A/D pode indicar uma distribuição oculta. Uma das vantagens do indicador é considerar tanto o preço quanto o volume, permitindo avaliar melhor a consistência da tendência. Suas limitações se tornam mais evidentes em períodos de baixo volume e em mercados com pouca liquidez, nos quais as cotações são mais suscetíveis à manipulação.

Além disso, no mercado Forex, dispomos apenas do volume de ticks. O cálculo desse indicador começa pela determinação do multiplicador do fluxo monetário, conforme a seguinte fórmula:

Onde:

• High<i>t</i> - Low<i>t</i> ≠ 0; se o valor for igual a zero, deve-se atribuir NaN ao resultado para evitar a divisão por zero.

Em seguida, calculamos o volume do fluxo monetário utilizando a fórmula abaixo:

Depois disso, podemos calcular a linha de Acumulação/Distribuição (ADL).

Aqui, ADL representa a soma acumulada dos valores do volume do fluxo monetário. Por fim, precisamos determinar os valores efetivos do oscilador A/D. Eles são calculados pela seguinte fórmula:

Onde:

• EMA(series, n) é a média móvel exponencial da série correspondente, com período n (neste caso, series corresponde aos buffers da ADL);
• normalmente, são utilizados os períodos fast_period=3 e slow_period=10, com fast_period<slow_period. Para sincronizar o oscilador A/D com o oscilador Gator, utilizamos os números de Fibonacci 5 e 13 para esses dois períodos, respectivamente.

O multiplicador do fluxo monetário indica a posição do preço de fechamento dentro da faixa diária de preços. O valor +1 corresponde ao limite superior da faixa, -1 ao limite inferior e 0 ao ponto médio. O volume do fluxo monetário pondera esse multiplicador pelo volume: um movimento de preço acompanhado por maior volume recebe mais peso e é considerado mais relevante. A ADL representa o fluxo monetário acumulado e indica quem domina o mercado: os touros ou os ursos. Assim, o oscilador A/D funciona como um indicador de volume que incorpora o sinal positivo ou negativo associado à direção do fluxo, refletindo a diferença entre a EMA rápida e a EMA lenta calculadas sobre a ADL. Valores positivos indicam um sinal de alta, enquanto valores negativos indicam um sinal de baixa.

Em resumo, o oscilador A/D é útil para confirmar tendências, ajudando, por exemplo, a identificar se uma alta dos preços é confirmada pelo volume real. As divergências entre o preço e o A/D podem servir como sinais antecipados de que a tendência atual pode ser falsa ou estar próxima do fim. A aplicação desse indicador é limitada em mercados com pouca liquidez ou quando os dados de volume estão ausentes ou incorretos. Seu uso é mais adequado como filtro para setups de negociação já identificados ou para detectar divergências. O indicador não é recomendado como ferramenta independente para determinar pontos de entrada e saída.

Agora que apresentamos os dois indicadores, vamos analisar dez padrões de sinal que combinam suas informações. Para os testes, utilizaremos o par GBPJPY no timeframe de 30 minutos, com dados de 2023, reservando 2024 para o teste forward. Testaremos os dez padrões individualmente, atribuindo um índice a cada um. Para isso, adotaremos as seguintes regras:

Os padrões recebem índices de 0 a 9, o que facilita o cálculo da máscara de bits utilizada para selecioná-los no EA. Por exemplo, para ativar o padrão de índice 1, devemos atribuir ao parâmetro PatternsUsed o valor de 2 elevado a 1, ou seja, 2. Para o índice 4, o valor será 2 elevado a 4, ou seja, 16, e assim por diante. O valor máximo desse parâmetro é 1023, pois trabalhamos com apenas dez padrões. Qualquer valor entre 0 e 1023 que não seja uma potência exata de dois representará uma combinação de vários desses dez padrões.

Rompimento confirmado pelo volume ("despertar" do Gator + pico do A/D)

O primeiro padrão ocorre quando, após um período de consolidação, correspondente à fase de "sono" do Gator, o oscilador passa a indicar o despertar. Nesse momento, uma das barras do histograma fica verde, enquanto a outra permanece vermelha. Isso indica que as linhas da "mandíbula", dos "dentes" e dos "lábios" estão começando a se afastar, sugerindo o possível início de uma nova tendência de alta. Esse sinal de rompimento de alta é confirmado por uma forte elevação do oscilador A/D. Um aumento acentuado da pressão compradora, acompanhado por novas máximas do A/D ou por uma alta expressiva de seu valor, indica que a recente tendência de alta dos preços é sustentada pelo volume. Dessa forma, a combinação desses dois sinais aponta para um rompimento de alta consistente, confirmado pela tendência e pelo volume. Vamos implementar esse padrão em MQL5 da seguinte maneira:

//+------------------------------------------------------------------+
//| Check for Pattern 0.                                             |
//+------------------------------------------------------------------+
bool CSignalGator_AD::IsPattern_0(ENUM_POSITION_TYPE T)
{  if
   (
      clrRed == Color_UP(m_gator, X()) &&
      clrGreen == Color_LO(m_gator, X())
   )
   {  if
      (
         T == POSITION_TYPE_BUY &&
         High(X() + 2) > High(X() + 3) &&
         High(X() + 1) >= High(X() + 2) &&
         Close(X()) >= High(X() + 1) &&
         AD(X() + 1) > AD(X() + 2) &&
         AD(X()) > AD(X() + 1)
      )
      {  return(true);
      }
      else if
      (
         T == POSITION_TYPE_SELL &&
         Low(X() + 2) < Low(X() + 3) &&
         Low(X() + 1) <= Low(X() + 2) &&
         Close(X()) <= Low(X() + 1) &&
         AD(X() + 1) < AD(X() + 2) &&
         AD(X()) < AD(X() + 1)
      )
      {  return(true);
      }
   }
   return(false);
}

O setup de baixa também ocorre após o despertar do Gator e apresenta a mesma mudança de cor no histograma observada no sinal de alta descrito anteriormente, já que os sinais do Gator não dependem da direção da tendência. Portanto, esse sinal também pode indicar um rompimento de baixa. Nesse caso, a linha A/D apresenta queda e registra novas mínimas, indicando distribuição ou forte pressão vendedora. Como o Gator não identifica a direção da tendência, esse padrão também considera sinais da ação do preço. Conforme mostrado no código anterior, são analisadas as máximas e mínimas. A queda do A/D indica que o movimento de baixa dos preços é acompanhado pelo volume, reforçando o cenário de baixa.

A vantagem desse padrão é permitir a identificação de novas tendências logo no início, aguardando a transição do Gator da fase de sono para a abertura das "mandíbulas". A confirmação pelo volume, por meio do filtro A/D, ajuda a filtrar falsos rompimentos. Quando os dois sinais coincidem, o movimento subsequente costuma ser intenso. Isso pode ser observado, em parte, no relatório abaixo, que abrange os períodos de treinamento e teste mencionados anteriormente.

Embora o teste forward apresente resultados que vão de valores próximos de zero a resultados positivos, eles ainda não são suficientemente convincentes. Isso nos leva a uma das limitações desse padrão, provavelmente relacionada ao momento em que os sinais são gerados. O despertar do Gator pode ocorrer com atraso, especialmente quando as linhas da "mandíbula", dos "dentes" e dos "lábios" só se cruzam após o fechamento da barra de rompimento. Esse atraso é particularmente importante em rompimentos muito fortes, como os provocados por notícias, nos quais o preço pode romper um nível antes que o Gator apresente um sinal verde. Além disso, os picos de volume podem ser eventos isolados, como ocorre nas últimas horas da sessão asiática, quando a liquidez é baixa. Nessas condições, aumentos repentinos no volume de ticks podem gerar sinais enganosos.

Continuação consistente da tendência (fase de "alimentação" do Gator + crescimento sustentado do A/D)

O segundo padrão, pattern-1, apresenta um setup de alta em uma tendência de alta já estabelecida. Nesse cenário, o oscilador Gator está na fase de alimentação, com barras verdes nos histogramas superior e inferior. Isso indica que as linhas da "mandíbula", dos "dentes" e dos "lábios" estão bastante afastadas umas das outras, confirmando a presença de uma tendência. Ao mesmo tempo, o A/D apresenta crescimento sustentado, indicando acumulação contínua ou pressão compradora à medida que os preços sobem. Esse avanço consistente do A/D confirma que a tendência de alta dos preços é sustentada pelo volume, pois cada novo impulso de alta reflete uma participação expressiva dos agentes do mercado. Essa combinação indica uma tendência de alta com potencial para continuar avançando. Assim, os traders podem aproveitar pequenas pausas no movimento dos preços para entrar a favor da tendência, desde que as leituras do indicador de volume permaneçam positivas. Vamos implementar esse padrão em MQL5 da seguinte maneira:

//+------------------------------------------------------------------+
//| Check for Pattern 1.                                             |
//+------------------------------------------------------------------+
bool CSignalGator_AD::IsPattern_1(ENUM_POSITION_TYPE T)
{  if
   (
      clrGreen == Color_UP(m_gator, X() + 1) &&
      clrRed == Color_LO(m_gator, X() + 1) &&
      clrGreen == Color_UP(m_gator, X()) &&
      clrGreen == Color_LO(m_gator, X())
   )
   {  if
      (
         T == POSITION_TYPE_BUY &&
         Close(X() + 1) > Close(X() + 2) &&
         Close(X()) > Close(X() + 1) &&
         AD(X() + 1) > AD(X() + 2) &&
         AD(X()) > AD(X() + 1)
      )
      {  return(true);
      }
      else if
      (
         T == POSITION_TYPE_SELL &&
         Close(X() + 1) < Close(X() + 2) &&
         Close(X()) < Close(X() + 1) &&
         AD(X() + 1) < AD(X() + 2) &&
         AD(X()) < AD(X() + 1)
      )
      {  return(true);
      }
   }
   return(false);
}

A variante de baixa apresenta um sinal semelhante do Gator, pois, como mencionado na introdução, esse oscilador não depende da direção da tendência. Portanto, o Gator permanece na fase de alimentação, com barras verdes nos dois histogramas, enquanto a ação do preço indica queda. Uma redução contínua da linha A/D, acompanhando a queda dos preços, indica distribuição persistente, com vendas sustentadas por um volume expressivo. Se o Gator confirma a continuidade do momentum da tendência e o A/D aponta para a pressão vendedora, a tendência de baixa permanece em vigor. O teste desse padrão, com o parâmetro de entrada PatternsUsed definido como 2, produz o seguinte relatório:

Os resultados do teste forward são mais convincentes do que os obtidos para pattern-0. Isso provavelmente se deve a uma vantagem desse padrão: ele combina o acompanhamento de tendência com a confirmação pelo volume. A identificação da fase de alimentação permite reconhecer o momento mais favorável, quando o potencial de lucro é máximo. Os buffers da "mandíbula", dos "dentes" e dos "lábios" estão alinhados na sequência correta e apresentam um afastamento significativo, indicando uma direção bem definida. O sinal do A/D, alinhado à tendência, aumenta a confiança de que ela não está perdendo força, não há divergências visíveis e os grandes participantes continuam interessados no movimento. No mercado Forex, em particular, essa combinação de sinais nos timeframes de H1 a H4 indica uma continuação confiável da tendência. Esse padrão permite que os traders mantenham posições lucrativas por períodos relativamente longos. Para ilustrar, a variante de baixa do pattern-1 pode apresentar a seguinte configuração no gráfico:

Entrada na continuação da tendência após um recuo (transição do Gator para a fase de convergência, seguida pela retomada do momentum + estabilidade do A/D)

O setup de alta do próximo padrão de sinal ocorre durante um movimento ascendente dos preços, no qual são comuns recuos temporários e correções laterais, como no padrão "bandeira de alta". Nesse contexto, o oscilador Gator reflete um enfraquecimento temporário da tendência: um dos histogramas pode passar a apresentar barras vermelhas, enquanto o outro permanece verde. Isso indica que as linhas da "mandíbula", dos "dentes" e dos "lábios" começaram a se aproximar, caracterizando a fase de convergência do Gator. Esse comportamento pode ocorrer quando o momentum perde força temporariamente. O importante é que, durante esse recuo, o oscilador A/D permanece estável ou apresenta uma ligeira alta, indicando ausência de distribuição significativa. Além disso, durante esses recuos, também pode ocorrer acumulação oculta de volume.

Temos, portanto, um padrão de continuação para uma reentrada em posição comprada, que deve gerar um sinal quando os dois histogramas do Gator, superior e inferior, voltarem a ficar verdes. Além disso, o A/D deve estar próximo de suas máximas recentes ou atingir esses níveis, indicando que a pressão compradora continua presente. Vamos implementar esse padrão em MQL5 da seguinte maneira:

//+------------------------------------------------------------------+
//| Check for Pattern 2.                                             |
//+------------------------------------------------------------------+
bool CSignalGator_AD::IsPattern_2(ENUM_POSITION_TYPE T)
{  if
   (
      clrRed == Color_UP(m_gator, X() + 1) &&
      clrGreen == Color_LO(m_gator, X() + 1) &&
      clrGreen == Color_UP(m_gator, X()) &&
      clrGreen == Color_LO(m_gator, X())
   )
   {  if
      (
         T == POSITION_TYPE_BUY &&
         High(X()) > High(X() + 1) &&
         Close(X()) <= Close(X() + 1) &&
         AD(X() + 1) > AD(X() + 2) &&
         AD(X()) > AD(X() + 1)
      )
      {  return(true);
      }
      else if
      (
         T == POSITION_TYPE_SELL &&
         Low(X()) < Low(X() + 1) &&
         Close(X()) >= Close(X() + 1) &&
         AD(X() + 1) < AD(X() + 2) &&
         AD(X()) < AD(X() + 1)
      )
      {  return(true);
      }
   }
   return(false);
}

O cenário de baixa segue uma lógica semelhante, mas a ação do preço indica claramente uma tendência de baixa. Nessa situação, o A/D apresenta apenas uma ligeira recuperação após a queda, indicando que não há acumulação efetiva durante o repique dos preços. A entrada na continuação da tendência de baixa é confirmada quando, assim como na variante de alta, ambos os histogramas voltam a ficar verdes depois de um deles ter ficado vermelho. O teste do pattern-2 produz o seguinte relatório:

No teste forward, esse padrão apresenta um lucro um pouco mais convincente do que os dois anteriores, embora o EA ainda não conte com medidas adequadas de gestão de risco. Vale lembrar que os testes utilizam níveis de take-profit, mas não de stop-loss: o limite de fechamento definido no EA desempenha a função de stop-loss. Como sempre, devido ao curto período de testes, é fundamental realizar uma validação especialmente rigorosa antes de utilizar esse padrão. No gráfico, o padrão de entrada em posição comprada apresenta a seguinte configuração:

Reversão por divergência de volume (divergência entre preço e A/D + enfraquecimento da tendência no Gator)

O quarto sinal, pattern-3, corresponde a um setup de reversão de alta contra a tendência. Ele ocorre quando uma tendência de baixa apresenta sinais de enfraquecimento, enquanto a dinâmica do volume aponta para um impulso de alta iminente. Normalmente, o preço registra uma mínima mais baixa, enquanto o oscilador A/D forma uma mínima mais alta ou começa a subir, contrariando a tendência dos preços. Essa divergência de alta indica que, apesar da queda dos preços, o volume de compras aumenta gradualmente e que os grandes participantes provavelmente estão acumulando posições nas mínimas.

Nessa etapa, o sinal do oscilador Gator, que não indica a direção da tendência, pode mostrar que o movimento de baixa está perdendo força. Por exemplo, o histograma inferior, antes verde, começa a apresentar barras vermelhas. Isso caracteriza a fase de convergência do Gator, na qual as linhas da "mandíbula", dos "dentes" e dos "lábios" começam a se aproximar. Em alguns casos, ambos os histogramas, superior e inferior, podem ficar vermelhos. Vamos implementar esse padrão em MQL5 da seguinte maneira:

//+------------------------------------------------------------------+
//| Check for Pattern 3.                                             |
//+------------------------------------------------------------------+
bool CSignalGator_AD::IsPattern_3(ENUM_POSITION_TYPE T)
{  if
   (
      clrRed == Color_UP(m_gator, X() + 1) &&
      clrRed == Color_LO(m_gator, X() + 1) &&
      clrRed == Color_UP(m_gator, X()) &&
      clrGreen == Color_LO(m_gator, X())
   )
   {  if
      (
         T == POSITION_TYPE_BUY &&
         Close(X()) - Low(X() + 1) > 0.5 * (High(X() + 1) - Low(X() + 1)) &&
         AD(X() + 2) > AD(X()) &&
         AD(X()) > AD(X() + 1)
      )
      {  return(true);
      }
      else if
      (
         T == POSITION_TYPE_SELL &&
         High(X() + 1) - Close(X()) > 0.5 * (High(X() + 1) - Low(X() + 1)) &&
         AD(X() + 2) < AD(X()) &&
         AD(X()) < AD(X() + 1)
      )
      {  return(true);
      }
   }
   return(false);
}

O setup de baixa ocorre em uma tendência de alta próxima do esgotamento: o preço registra uma máxima mais alta, mas a linha A/D não consegue superar sua máxima anterior ou começa a cair. Isso caracteriza uma divergência de baixa no volume. Em outras palavras, mesmo com a formação de novas máximas nos preços, a acumulação perde força ou começa a ocorrer distribuição. Nessa etapa, o oscilador Gator indica o enfraquecimento da tendência de alta. Assim como no sinal de alta descrito anteriormente, o histograma superior, antes verde, pode ficar vermelho. Ambos os histogramas também podem apresentar barras vermelhas temporariamente.

Esse comportamento indica perda de momentum, à medida que as linhas da "mandíbula", dos "dentes" e dos "lábios" se aproximam cada vez mais. A regra principal é a seguinte: quando uma forte alta até uma nova máxima não é confirmada pelo A/D, a transição do Gator da fase de alimentação para a fase de saciedade indica um sinal de reversão de baixa. Como diria Bill Williams, "O Alligator está pronto para voltar a dormir depois de se saciar, e os ursos podem assumir o controle". O teste desse padrão, utilizando os mesmos períodos empregados nos testes de pattern-0 a pattern-2, produz o seguinte relatório:

Esse padrão apresenta desempenho fraco no teste forward e termina o período sem gerar lucro. Seu ponto fraco está na dificuldade de identificar o momento adequado para confirmar o sinal. Uma divergência pode persistir por algum tempo antes que ocorra uma reversão. Como se costuma dizer, "os mercados podem permanecer em divergência por mais tempo do que um trader consegue se manter solvente". Essa observação é especialmente importante porque a maioria dos traders, sobretudo no mercado Forex, opera com alavancagem. O Gator pode gerar um sinal antecipado, por exemplo, quando uma das barras do histograma fica vermelha. No entanto, a tendência de baixa pode retomar força temporariamente e registrar uma mínima ainda mais baixa, enquanto o A/D pode apenas se estabilizar, sem começar a subir. Esses cenários de fundo duplo podem forçar a saída dos traders que entraram cedo demais. Nenhuma divergência, por si só, garante uma reversão imediata. Por isso, pode ser necessário buscar uma confirmação adicional, como o rompimento de uma linha de tendência ou o cruzamento dos buffers da "mandíbula", dos "dentes" e dos "lábios".

Além disso, em tendências muito fortes, as divergências de volume podem perder completamente sua relevância, pois várias divergências menores podem surgir antes da formação de um topo ou fundo definitivo. O oscilador A/D também é cumulativo. Por isso, após uma tendência prolongada, ele pode apresentar divergência simplesmente porque já não consegue subir no mesmo ritmo de antes, embora o preço ainda possa registrar mais uma ou duas máximas ou mínimas. Portanto, confiar apenas na primeira divergência é arriscado. Além disso, notícias podem invalidar um setup baseado em divergência. Por exemplo, se uma divergência de alta estiver se formando e surgir uma notícia negativa relacionada aos fundamentos econômicos, o preço poderá registrar novas mínimas com aumento do volume, anulando a divergência anterior.

Esgotamento da tendência e sinal de saída (fase de "saciedade" do Gator + queda do volume)

Como nos artigos anteriores, preparamos 10 padrões de sinal para essa combinação de indicadores. No entanto, neste artigo, analisaremos apenas os cinco primeiros. Os padrões de 5 a 9 serão abordados no próximo artigo.

O setup de alta do último padrão deste artigo, pattern-4, baseia-se no esgotamento da tendência. Em uma tendência de baixa prolongada, pode chegar um ponto de inflexão marcado por sinais de esgotamento, em vez de uma reversão brusca associada a uma divergência. Em seguida, o oscilador Gator passa para a fase que Bill Williams chamava de "saciedade" ou "satisfação". Essa fase ocorre após a fase de "alimentação", quando os histogramas superior e inferior estavam verdes. Em seguida, um deles passa a apresentar barras vermelhas. Como vimos anteriormente, isso geralmente indica que as linhas da "mandíbula", dos "dentes" e dos "lábios" começam a convergir e que o momentum da tendência de baixa está enfraquecendo. No entanto, em vez de apresentar imediatamente uma divergência seguida de reversão, o mercado pode simplesmente entrar em um período sem tendência definida ou passar a oscilar dentro de uma faixa de preços. O ponto principal é que a tendência de baixa provavelmente já terminou ou está próxima do fim.

Ao mesmo tempo, o oscilador A/D geralmente se estabiliza ou começa a apresentar uma leve alta. Isso indica que a distribuição ativa foi interrompida: os vendedores já não dominam o mercado, e a pressão indicada pelo volume deixa de ser claramente negativa. Embora ainda não se trate de uma divergência de alta plenamente formada, o volume já não confirma a continuidade da queda. Para quem mantém posições vendidas, a combinação da ausência de uma expansão adicional do histograma inferior do Gator com a interrupção da queda do volume pode representar um sinal confiável de saída. A tendência de baixa pode ter esgotado seu potencial. Por isso, traders mais agressivos podem começar a se preparar para abrir posições compradas, antecipando o início da acumulação à medida que o mercado forma um fundo. Vamos implementar esse padrão em MQL5 da seguinte maneira:

//+------------------------------------------------------------------+
//| Check for Pattern 4.                                             |
//+------------------------------------------------------------------+
bool CSignalGator_AD::IsPattern_4(ENUM_POSITION_TYPE T)
{  if
   (
      clrGreen == Color_UP(m_gator, X() + 1) &&
      clrRed == Color_LO(m_gator, X() + 1) &&
      clrRed == Color_UP(m_gator, X()) &&
      clrGreen == Color_LO(m_gator, X())
   )
   {  if
      (
         T == POSITION_TYPE_BUY &&
         Close(X()) > Close(X() + 1) &&
         Low(X() + 1) > Low(X()) &&
         AD(X()) > AD(X() + 1)
      )
      {  return(true);
      }
      else if
      (
         T == POSITION_TYPE_SELL &&
         Close(X()) < Close(X() + 1) &&
         High(X() + 1) < High(X()) &&
         AD(X()) < AD(X() + 1)
      )
      {  return(true);
      }
   }
   return(false);
}

O padrão de baixa também se baseia em sinais de esgotamento de uma tendência prolongada. Após uma tendência de alta persistente, o oscilador Gator entra na fase de saciedade. Assim como no sinal de alta, essa transição é indicada pela mudança de verde para vermelho nas barras de um dos histogramas. Isso indica novamente que as linhas da "mandíbula", dos "dentes" e dos "lábios" estão se aproximando. O preço ainda pode estar próximo das máximas, mas começam a surgir oscilações bruscas e movimentos laterais, indicando que o "apetite" do Gator por novas altas está diminuindo. Ao mesmo tempo, o A/D pode parar de subir ou registrar apenas pequenas altas, mesmo sem uma queda expressiva dos preços. Isso indica que o volume de compras diminuiu e que os compradores já não sustentam a alta com a mesma intensidade.

Esse comportamento pode ser resultado da realização de lucros ou do esgotamento dos compradores. Os traders podem interpretá-lo como um sinal de venda e se preparar para abrir posições vendidas, especialmente se houver confirmação de outros indicadores: o volume e o momentum já apontam contra a continuidade da alta. O teste desse padrão produz o seguinte relatório:

No período de teste forward, o padrão consegue atingir o ponto de equilíbrio, o que, a rigor, indica algum potencial. Ainda assim, seu desempenho é inferior ao de pattern-2 e pattern-1. Uma vantagem desse padrão de sinal é permitir identificar o fim de uma tendência em tempo hábil, ao contrário dos sinais bruscos de divergência. Isso pode ser especialmente útil na gestão das operações, pois ajuda a responder à pergunta: "Quando encerrar uma operação lucrativa?" A primeira barra vermelha do Gator após uma longa sequência de barras verdes é um forte sinal de mudança nas condições de mercado.

Quando esse sinal coincide com a estabilização do A/D, confirmada pelo comportamento do volume, isso indica que manter a posição a favor da tendência oferece retornos cada vez menores. A força da tendência e a atividade do volume começam a diminuir, e esse padrão antecede um período de fortes oscilações do mercado ou uma reversão gradual. Isso dá aos traders tempo suficiente para reagir, já que esse cenário se desenvolve de forma menos abrupta do que um recuo acentuado.

Conclusão

Analisamos os cinco primeiros dos dez padrões de sinal previstos a partir da combinação do oscilador Gator com o oscilador de Acumulação/Distribuição. Essa combinação permite identificar sinais mais informativos, que levam o volume em consideração, podendo aprimorar tanto as estratégias de acompanhamento de tendência quanto a gestão das operações. Como vimos anteriormente, a atuação conjunta dos dois indicadores cria um filtro multidimensional que ajuda a confirmar o momentum, identificar mais cedo os sinais de esgotamento e evitar movimentos falsos que frequentemente comprometem o desempenho de sistemas de negociação baseados em um único indicador.

No entanto, nenhum método é infalível: a escolha do momento adequado para confirmar os sinais, as entradas tardias e as particularidades dos dados de volume ainda exigem monitoramento constante. Com o apoio do Assistente MQL5, que oferece aos novos leitores um bom ponto de partida para criar um EA, essa combinação de indicadores pode se tornar um conjunto confiável de ferramentas para traders sistemáticos, pois fornece sinais mais refinados e com múltiplas camadas de informação do que a análise isolada da tendência ou do volume. Analisaremos os padrões de 5 a 9 no próximo artigo.

nome	descrição
WZ-77.mq5	EA gerado pelo Assistente MQL5, cujo cabeçalho lista os arquivos incluídos
SignalWZ_77.mqh	Arquivo da classe de sinal personalizada utilizada pelo Assistente MQL5 para criar o EA