Возможности Мастера MQL5, которые вам нужно знать (Часть 77): Использование индикаторов Gator и A/D (Accumulation/Distribution)

Введение

Продолжая исследование сочетаний индикаторов для формирования ключевых торговых сигналов, рассмотрим осциллятор Gator и осциллятор накопления/распределения (A/D). В отличие от A/D, осциллятор Gator не показывает направление сам по себе. Однако оба индикатора дополняют друг друга: один отслеживает моментум, а второй учитывает объем и подтверждает сигнал. Нейтральность Gator к направлению означает, что для определения тренда потребуется другой индикатор или анализ ценового движения. В этой статье мы используем второй вариант.

Осциллятор Gator

Осциллятор Gator был создан Биллом Вильямсом для измерения степени схождения и расхождения трех скользящих средних другого комплексного индикатора его авторства – Alligator. Индикатор Alligator состоит из трех известных буферов: "челюсти", "зубы" и "губы". Осциллятор Gator, в свою очередь, создает визуальное представление индикатора Alligator, выделяя его четыре фазы: сон, пробуждение, питание и насыщение. Эти четыре фазы соответствуют этапам цикла, включающего трендовые рынки, а также периоды флэта и волатильного бокового движения. Они особенно полезны для выявления начала тренда, то есть открытия "челюстей", или его истощения, которое также связывают с их закрытием. 

Сторонники индикатора считают его преимуществом четкий визуальный сигнал смены фаз тренда с помощью зеленых и красных столбцов гистограммы, расположенных выше и ниже нулевой линии. Недостаток состоит в том, что сам по себе индикатор не прогнозирует движение цены: для определения точек входа и выхода нужен анализ ценового движения или другие индикаторы. Формула осциллятора Gator задается следующими шагами. Сначала определим медианную цену:

Затем определим буферы скользящих средних для "челюсти", "зубов" и "губ":

Где:

• SMMA(series, n) – сглаженная скользящая средняя для ценового ряда series с периодом n (в нашем случае series – это медианная цена);
• jaw_period=13, jaw_shift=8;
• teeth_period=8, teeth_shift=5;
• lips_period=5, lips_shift=3.

Определив три основных буфера, можно задать значения верхней и нижней гистограмм индикатора.

Где:

• ∣⋅∣ – абсолютное значение;
• Gator_Up (строится выше нуля), Gator_Down (строится ниже нуля, имеет отрицательные значения).

"Линии Аллигатора" – буферы "челюсти", "зубов" и "губ" – используют SMMA с опережающим сдвигом. Благодаря этому индикатор как бы "заглядывает вперед" и работает скорее как детектор рыночной фазы, а не как обычное пересечение скользящих средних. Гистограмма Gator_Up представляет собой абсолютную разность между "челюстью" и "зубами". Рост этого значения указывает на открытие "пасти" Gator и возможное начало тренда. Гистограмма Gator_Down, напротив, представляет собой отрицательную абсолютную разность между "зубами" и "губами". Увеличение ее модуля, то есть переход к более отрицательным значениям, подтверждает фазу тренда или его истощение. Зеленый цвет столбца обычно обозначает увеличение его длины. Красный цвет обозначает уменьшение, а при отсутствии изменений сохраняется цвет предыдущего столбца.

Осциллятор Gator помогает выбирать момент входа и избегать вялых рынков с низкой волатильностью. Вход следует рассматривать, только когда столбцы обеих гистограмм увеличиваются и окрашены в зеленый цвет, то есть находятся в фазе питания. Этот индикатор лучше подходит для следования за трендом, а не для торговли в диапазоне или стратегий возврата к среднему. Использование сдвигов для этих буферов MA принципиально важно: замена их нулевыми значениями приводит к совершенно другому и малополезному индикатору. Наконец, необходимо сочетать индикатор с анализом ценового движения: выявлять пробои, более высокие максимумы и более низкие минимумы. Это необходимо, поскольку индикатор не определяет направление тренда.

Осциллятор A/D

Второй индикатор в этой статье – осциллятор накопления/распределения (A/D). Он измеряет давление покупателей и продавцов на основе цены и объема. Он выявляет реальное движение капитала, определяя накопление, то есть покупки со стороны крупных игроков, и распределение, то есть продажи со стороны крупных игроков. Расхождение с ценой, в зависимости от ситуации, может быть как предупреждающим, так и подтверждающим сигналом. Например, в некоторых случаях рост цены при снижении A/D может указывать на скрытое распределение. Преимущество индикатора в том, что он учитывает не только цену, но и объем, что позволяет лучше оценивать устойчивость тренда. Недостатки проявляются в условиях низкого объема и на неликвидных рынках, где котировки легче поддаются манипулированию.

Кроме того, на рынке Forex доступен только тиковый объем. Вывод формулы этого индикатора начинается с расчета множителя денежного потока. Формула имеет следующий вид:

Где:

• High<i>t</i> - Low<i>t</i> ≠ 0; если значение равно нулю, результату нужно присвоить NaN, чтобы избежать деления на ноль.

Затем нужно рассчитать объем денежного потока. Он определяется приведенной ниже формулой:

После этого можно рассчитать линию накопления/распределения (ADL).

Здесь ADL представляет собой накопленную сумму значений объема денежного потока. Наконец, нужно определить фактические значения осциллятора A/D. Они вычисляются по приведенной ниже формуле:

Где:

• EMA(series, n) – экспоненциальная скользящая средняя с периодом n для соответствующего ряда (в нашем случае series – это буферы ADL);
• обычно используются следующие периоды fast_period=3 и slow_period=10, где fast_period<slow_period; чтобы синхронизировать осциллятор AD с осциллятором Gator, для этих двух периодов используются числа Фибоначчи 5 и 13 соответственно.

Множитель денежного потока показывает положение цены закрытия в дневном диапазоне. Значение +1 соответствует верхней границе диапазона, -1 – нижней, а 0 – его середине. Объем денежного потока взвешивает этот множитель по объему: ценовое изменение при большем объеме получает больший вес и считается более значимым. ADL – это накопленное значение денежного потока, показывающее, кто контролирует рынок: быки или медведи. В итоге осциллятор A/D выступает индикатором объема с учетом знака направления и отражает разницу между быстрой и медленной EMA, рассчитанными по ADL. Положительные значения указывают на бычий сигнал, отрицательные – на медвежий.

Подводя итог, осциллятор A/D полезен для подтверждения трендов – например, он помогает определить, подтверждается ли рост цены реальным объемом. Дивергенции между ценой и A/D могут служить ранним предупреждением о том, что текущий ценовой тренд ложный или близок к завершению. Этот индикатор имеет ограниченную применимость на неликвидных рынках и при отсутствии либо ошибочности данных об объеме. Его лучше использовать как фильтр для уже сформированных торговых сетапов или как детектор дивергенций. Индикатор не подходит как самостоятельный инструмент для определения точек входа и выхода. 

Теперь, когда оба индикатора описаны, рассмотрим 10 их сигнальных паттернов. Для тестирования используем пару GBPJPY на 30-минутном таймфрейме за 2023 год, а 2024 год используем для форвардного тестирования. Мы тестируем эти 10 сигнальных паттернов по одному; каждому из них присвоен индекс. При этом руководствуемся следующими правилами:

Индексация выполняется от 0 до 9, что позволяет легко вычислять значение битовой маски для выбора паттернов в советнике. Например, если паттерн имеет индекс 1, параметру PatternsUsed нужно присвоить значение 2 в первой степени, то есть 2. Если индекс равен 4, получаем 2 в степени 4, то есть 16, и т.д. Максимальное значение этого параметра – 1023, поскольку предусмотрено только 10 паттернов. Любое число от 0 до 1023, не являющееся точной степенью двойки, будет представлять комбинацию нескольких из этих 10 паттернов.

Пробой, подтвержденный объемом ("пробуждение" Gator + всплеск A/D)

Первый паттерн формируется, если после периода консолидации, то есть "сна" Gator, осциллятор указывает на пробуждение. При этом один столбец гистограммы становится зеленым, а другой остается красным. Это считается признаком того, что линии "челюсти", "зубов" и "губ" начинают расходиться и может начаться новый восходящий тренд. Этот сигнал бычьего пробоя подтверждается резким ростом осциллятора A/D. Всплеск давления покупателей, сопровождаемый новыми максимумами A/D или его резким ростом, означает, что недавний восходящий тренд цены поддержан объемом. Таким образом, оба признака вместе указывают на уверенный пробой вверх, подтвержденный трендом и объемом. Реализуем это на языке MQL5 следующим образом:

//+------------------------------------------------------------------+
//| Check for Pattern 0.                                             |
//+------------------------------------------------------------------+
bool CSignalGator_AD::IsPattern_0(ENUM_POSITION_TYPE T)
{  if
   (
      clrRed == Color_UP(m_gator, X()) &&
      clrGreen == Color_LO(m_gator, X())
   )
   {  if
      (
         T == POSITION_TYPE_BUY &&
         High(X() + 2) > High(X() + 3) &&
         High(X() + 1) >= High(X() + 2) &&
         Close(X()) >= High(X() + 1) &&
         AD(X() + 1) > AD(X() + 2) &&
         AD(X()) > AD(X() + 1)
      )
      {  return(true);
      }
      else if
      (
         T == POSITION_TYPE_SELL &&
         Low(X() + 2) < Low(X() + 3) &&
         Low(X() + 1) <= Low(X() + 2) &&
         Close(X()) <= Low(X() + 1) &&
         AD(X() + 1) < AD(X() + 2) &&
         AD(X()) < AD(X() + 1)
      )
      {  return(true);
      }
   }
   return(false);
}

Медвежий сетап также следует за пробуждением Gator и сопровождается такой же сменой цвета гистограммы, как бычий сигнал выше, поскольку сигналы Gator не привязаны к направлению тренда. Этот нейтральный к направлению сигнал Gator также может означать пробой вниз. При таком сигнале Gator линия A/D снижается, формируя новые минимумы. Такое снижение указывает на распределение или сильное давление продавцов. Нейтральность Gator к направлению означает, что в этот паттерн включены сигналы ценового движения. Как видно в коде выше, учитываются максимумы и минимумы. Снижение A/D означает, что объем сопровождает падение цены, что усиливает медвежий сценарий.

Преимущество этого паттерна в том, что он выявляет начало новых трендов, ожидая перехода Gator от фазы сна к открытию "челюстей". Подтверждение объема с помощью фильтра A/D помогает отсеивать ложные пробои. Когда оба сигнала совпадают, последующее движение обычно оказывается сильным. Это отчасти видно в приведенном ниже отчете, охватывающем указанные выше периоды обучения и тестирования.

Хотя форвардное тестирование показывает от околонулевого до прибыльного результата, они не вполне убедительны. Это подводит нас к недостатку данного паттерна. Вероятно, проблема связана с выбором времени: пробуждение Gator может запаздывать, особенно если буферы "челюсти", "зубов" и "губ" пересекаются только после закрытия бара пробоя. Это важно, поскольку при очень резких пробоях, например на новостях, пробой может произойти раньше, чем Gator успеет дать зеленый сигнал. Кроме того, всплески объема могут быть разовыми, например в поздние часы азиатской сессии при низкой ликвидности. В таких ситуациях всплески тикового объема могут вводить в заблуждение.

Уверенное продолжение тренда (фаза "питания" Gator + устойчивый рост A/D)

Второй паттерн, pattern-1, имеет бычий сетап в сформировавшемся восходящем тренде: осциллятор Gator находится в фазе питания, а верхняя и нижняя гистограммы окрашены в зеленый цвет. Это признак того, что линии "челюсти", "зубов" и "губ" широко разошлись, что указывает на наличие тренда. На этом фоне A/D также будет устойчиво расти, указывая на последовательное накопление или давление покупателей по мере роста цены. Устойчивый рост A/D подтверждает, что восходящий тренд цены поддержан объемом, поскольку каждый новый импульс вверх отражает значительную вовлеченность участников рынка. Такое сочетание указывает на бычий тренд с достаточным потенциалом для дальнейшего развития. Поэтому трейдеры могут использовать небольшие паузы для входа по тренду, если показатели объема остаются положительными. Реализуем это на языке MQL5 следующим образом:

//+------------------------------------------------------------------+
//| Check for Pattern 1.                                             |
//+------------------------------------------------------------------+
bool CSignalGator_AD::IsPattern_1(ENUM_POSITION_TYPE T)
{  if
   (
      clrGreen == Color_UP(m_gator, X() + 1) &&
      clrRed == Color_LO(m_gator, X() + 1) &&
      clrGreen == Color_UP(m_gator, X()) &&
      clrGreen == Color_LO(m_gator, X())
   )
   {  if
      (
         T == POSITION_TYPE_BUY &&
         Close(X() + 1) > Close(X() + 2) &&
         Close(X()) > Close(X() + 1) &&
         AD(X() + 1) > AD(X() + 2) &&
         AD(X()) > AD(X() + 1)
      )
      {  return(true);
      }
      else if
      (
         T == POSITION_TYPE_SELL &&
         Close(X() + 1) < Close(X() + 2) &&
         Close(X()) < Close(X() + 1) &&
         AD(X() + 1) < AD(X() + 2) &&
         AD(X()) < AD(X() + 1)
      )
      {  return(true);
      }
   }
   return(false);
}

Медвежий вариант будет иметь аналогичный сигнал Gator, поскольку этот осциллятор не зависит от направления тренда, как уже отмечалось во введении. Итак, Gator находится в фазе питания, обе гистограммы зеленые, а ценовое движение показывает снижение. Устойчивое снижение линии A/D одновременно с падением цены указывает на продолжительное распределение: распродажа сопровождается значительным объемом. Если Gator подтверждает сохранение моментума тренда, а A/D указывает на давление продавцов, нисходящий тренд остается в силе. Тестирование этого паттерна при значении входного параметра PatternsUsed, равном 2, дает следующий отчет:

Наши результаты форвардного тестирования выглядят убедительнее, чем для pattern-0. Вероятно, это связано с преимуществом паттерна: он сочетает следование за трендом с подтверждением по объему. Выделение фазы питания позволяет определить наиболее благоприятный момент, когда потенциал прибыли максимален. Буферы "челюсти", "зубов" и "губ" расположены в правильном порядке и заметно расходятся, показывая четкую направленность. Согласованный сигнал A/D повышает уверенность в том, что тренд не ослабевает изнутри, видимой дивергенции нет, а крупные участники не теряют интереса к движению. В частности, на рынке Forex такое совпадение на таймфреймах H1-H4 указывает на надежное продолжение тренда. Этот паттерн позволяет трейдерам сравнительно долго удерживать прибыльные позиции. Для наглядности медвежий вариант pattern-1 на графике может выглядеть следующим образом:

Вход на продолжении после отката (переход Gator в фазу схождения с последующим возобновлением импульса + устойчивость A/D)

Бычий сетап следующего сигнального паттерна формируется в рамках восходящего ценового движения, где распространены временные откаты и боковые коррекции, например паттерн "бычий флаг". Таким образом, осциллятор Gator отражает кратковременное ослабление текущего тренда: одна гистограмма может стать красной, пока другая остается зеленой. Это означает, что линии "челюсти", "зубов" и "губ" начали сходиться, указывая на фазу схождения линий Gator. Это может быть вызвано паузой в моментуме. Важно, что во время такого отката осциллятор A/D остается на прежнем уровне или немного растет, то есть значимого распределения не наблюдается. Более того, в таких просадках может происходить скрытое накопление объема.

Таким образом, получаем паттерн продолжения для повторного входа в длинную позицию; он должен сработать, когда обе гистограммы Gator – верхняя и нижняя – вновь станут зелеными. Кроме того, A/D должен находиться вблизи недавних максимумов или на них, что указывает на сохранение давления покупателей. Реализуем это на языке MQL5 следующим образом:

//+------------------------------------------------------------------+
//| Check for Pattern 2.                                             |
//+------------------------------------------------------------------+
bool CSignalGator_AD::IsPattern_2(ENUM_POSITION_TYPE T)
{  if
   (
      clrRed == Color_UP(m_gator, X() + 1) &&
      clrGreen == Color_LO(m_gator, X() + 1) &&
      clrGreen == Color_UP(m_gator, X()) &&
      clrGreen == Color_LO(m_gator, X())
   )
   {  if
      (
         T == POSITION_TYPE_BUY &&
         High(X()) > High(X() + 1) &&
         Close(X()) <= Close(X() + 1) &&
         AD(X() + 1) > AD(X() + 2) &&
         AD(X()) > AD(X() + 1)
      )
      {  return(true);
      }
      else if
      (
         T == POSITION_TYPE_SELL &&
         Low(X()) < Low(X() + 1) &&
         Close(X()) >= Close(X() + 1) &&
         AD(X() + 1) < AD(X() + 2) &&
         AD(X()) < AD(X() + 1)
      )
      {  return(true);
      }
   }
   return(false);
}

Медвежий сценарий аналогичен описанному выше: ценовое движение явно указывает на нисходящий тренд. В этой ситуации A/D лишь незначительно восстановится после снижения, указывая на отсутствие реального накопления при отскоке. Вход по медвежьему продолжению подтверждается, когда, как и в бычьем паттерне, обе гистограммы становятся зелеными после того, как одна из них была красной. Тестирование pattern-2 дает следующий отчет:

Этот паттерн показывает несколько более убедительную прибыль в форвардном тестировании, чем два предыдущих, хотя в советнике пока не реализованы надлежащие меры управления рисками. Напомним, что тестирование проводится с уровнями тейк-профита и без стоп-лоссов: порог закрытия советника выполняет функцию стоп-лосса. Как всегда, из-за небольшого окна тестирования перед применением этого паттерна необходима особенно тщательная проверка. Паттерн для открытия бычьей позиции на графике выглядит следующим образом:

Разворот на дивергенции объема (дивергенция цены и A/D + ослабление тренда Gator)

Четвертый сигнал, pattern-3, представляет собой бычий сетап контртрендового разворота. Он возникает, когда нисходящий тренд показывает признаки ослабления, а динамика объема указывает на предстоящий бычий импульс. Обычно цена формирует более низкий минимум, но осциллятор A/D формирует более высокий минимум или начинает расти вопреки ценовому тренду. Эта бычья дивергенция указывает на то, что, несмотря на снижение цены, объем покупок постепенно растет, а крупные игроки, вероятно, накапливают позиции на минимумах.

На этом этапе нейтральный к направлению сигнал осциллятора Gator может указывать на затухание нисходящего тренда: например, нижняя гистограмма, ранее окрашенная в зеленый цвет, начинает становиться красной. Это фаза схождения линий Gator, при которой линии "челюсти", "зубов" и "губ" сходятся. В некоторых случаях красными могут стать и верхняя, и нижняя гистограммы. Реализуем это на языке MQL5 следующим образом:

//+------------------------------------------------------------------+
//| Check for Pattern 3.                                             |
//+------------------------------------------------------------------+
bool CSignalGator_AD::IsPattern_3(ENUM_POSITION_TYPE T)
{  if
   (
      clrRed == Color_UP(m_gator, X() + 1) &&
      clrRed == Color_LO(m_gator, X() + 1) &&
      clrRed == Color_UP(m_gator, X()) &&
      clrGreen == Color_LO(m_gator, X())
   )
   {  if
      (
         T == POSITION_TYPE_BUY &&
         Close(X()) - Low(X() + 1) > 0.5 * (High(X() + 1) - Low(X() + 1)) &&
         AD(X() + 2) > AD(X()) &&
         AD(X()) > AD(X() + 1)
      )
      {  return(true);
      }
      else if
      (
         T == POSITION_TYPE_SELL &&
         High(X() + 1) - Close(X()) > 0.5 * (High(X() + 1) - Low(X() + 1)) &&
         AD(X() + 2) < AD(X()) &&
         AD(X()) < AD(X() + 1)
      )
      {  return(true);
      }
   }
   return(false);
}

Медвежий сетап возникает в восходящем тренде, близком к истощению: цена формирует более высокий максимум, однако линия A/D не обновляет максимум или начинает снижаться. Это указывает на медвежью дивергенцию объема. Иными словами, даже при обновлении ценовых максимумов накопление ослабевает или начинает формироваться распределение. На этом этапе осциллятор Gator укажет на ослабление восходящего тренда. Как и в описанном выше бычьем сигнале, верхняя зеленая гистограмма может стать красной; временно красными могут стать и обе гистограммы.

Это указывает на ослабление моментума, поскольку линии "челюсти", "зубов" и "губ" все сильнее сходятся. Основное правило таково: если резкий рост цены к новому максимуму не подтверждается A/D, Gator переходит из фазы питания в фазу насыщения, что указывает на медвежий разворотный сигнал. Как сказал бы Билл Вильямс, "Аллигатор готов снова заснуть после того, как наелся, и медведи могут взять верх". Тестирование этого паттерна за те же периоды, что и pattern-0 – pattern-2, дает следующий отчет:

Этот паттерн показывает слабые результаты в форвардном тестировании и в итоге не приносит прибыли в форвардном периоде. Его слабое место – выбор момента для подтверждения сигнала, что может оказаться непростой задачей. Дивергенция может сохраняться некоторое время до разворота. Как говорят, "рынки могут оставаться в дивергенции дольше, чем трейдер способен сохранять платежеспособность". Поскольку большинство трейдеров, особенно на рынке Forex, используют кредитное плечо, это очень важное замечание. Gator может подать ранний сигнал, например когда один столбец становится красным. Однако затем нисходящий тренд способен ненадолго возобновиться и сформировать более низкий минимум, а A/D может лишь выровняться, не начав расти. Такие сценарии с двойным дном могут выбивать из позиции тех, кто вошел слишком рано. Ни одна дивергенция сама по себе не гарантирует немедленного разворота, поэтому может потребоваться дополнительное подтверждение в виде пробоя трендовой линии ценой или пересечения буферов "челюсти", "зубов" и "губ".

Кроме того, в очень сильных трендах дивергенции объема иногда полностью теряют значимость: до формирования окончательной вершины или окончательного дна может возникнуть несколько небольших дивергенций. Осциллятор A/D также является накопительным, поэтому после длительного тренда он может указывать на дивергенцию лишь потому, что уже не способен расти с прежней скоростью, хотя цена еще может сформировать один или два экстремума. Поэтому полагаться только на первую дивергенцию рискованно. Кроме того, новостные события могут аннулировать сетап на дивергенции. Например, если формируется бычья дивергенция, а затем выходит негативная фундаментальная новость, цена может обновить минимумы при увеличении объема, нивелировав предыдущую дивергенцию.

Истощение тренда и сигнал выхода (фаза "насыщения" Gator + снижение объема)

Как и в предыдущих статьях, для этой пары индикаторов подготовлено 10 сигнальных паттернов. Однако в этой статье мы рассмотрим только первые пять. Паттерны с 5 по 9 будут рассмотрены в следующей статье. 

Таким образом, бычий сетап последнего паттерна этой статьи, pattern-4, основан на истощении тренда. В затяжном нисходящем тренде может наступить переломный момент, когда появляются признаки истощения, а не резкого разворота на дивергенции. Затем осциллятор Gator перейдет в фазу, которую Билл Вильямс называл "насыщением" или "удовлетворением". Она следует за фазой "питания", когда верхняя и нижняя гистограммы были зелеными. После этого одна из гистограмм станет красной. Как уже было сказано выше, это обычно указывает на начало схождения линий "челюсти", "зубов" и "губ", а также на ослабление моментума нисходящего тренда. Однако вместо немедленной дивергенции и разворота рынок может просто перейти во флэт или диапазон. Главное здесь то, что нисходящий тренд, вероятно, уже завершился либо близок к завершению.

Одновременно осциллятор A/D обычно выравнивается или начинает слегка расти. Это указывает на прекращение активного распределения: продавцы больше не доминируют, а давление объема уже не является выраженно отрицательным. Хотя это еще не полноценная бычья дивергенция, объем не подтверждает дальнейшее снижение. Для трейдера с короткими позициями сочетание отсутствия дальнейшего расширения Gator вниз и прекращения снижения объема может служить надежным сигналом выхода. Нисходящий тренд мог исчерпать потенциал, поэтому агрессивные трейдеры могут заранее готовиться к открытию длинных позиций в ожидании начала накопления по мере формирования рынком дна. Реализуем этот паттерн в MQL5 следующим образом:

//+------------------------------------------------------------------+
//| Check for Pattern 4.                                             |
//+------------------------------------------------------------------+
bool CSignalGator_AD::IsPattern_4(ENUM_POSITION_TYPE T)
{  if
   (
      clrGreen == Color_UP(m_gator, X() + 1) &&
      clrRed == Color_LO(m_gator, X() + 1) &&
      clrRed == Color_UP(m_gator, X()) &&
      clrGreen == Color_LO(m_gator, X())
   )
   {  if
      (
         T == POSITION_TYPE_BUY &&
         Close(X()) > Close(X() + 1) &&
         Low(X() + 1) > Low(X()) &&
         AD(X()) > AD(X() + 1)
      )
      {  return(true);
      }
      else if
      (
         T == POSITION_TYPE_SELL &&
         Close(X()) < Close(X() + 1) &&
         High(X() + 1) < High(X()) &&
         AD(X()) < AD(X() + 1)
      )
      {  return(true);
      }
   }
   return(false);
}

Медвежий паттерн также строится на признаках истощения затяжного тренда. После продолжительного восходящего тренда осциллятор Gator перейдет в фазу насыщения. Как и в бычьем сигнале, об этом свидетельствует переход одной из гистограмм из зеленого цвета в красный. Это вновь указывает на сближение линий "челюсти", "зубов" и "губ". Цена может по-прежнему находиться вблизи максимумов, однако становятся заметны резкие колебания и боковое движение – аппетит Gator к дальнейшему росту ослабевает. Соответственно, A/D может перестать расти или лишь незначительно повышаться, хотя существенного снижения цены еще нет. Это признак того, что объем покупок ослаб, а покупатели больше не поддерживают рост так активно.

Причиной этого может быть фиксация прибыли или истощение покупателей. Трейдеры могут использовать это как сигнал к продаже и готовиться к открытию коротких позиций, особенно если его подтверждают дополнительные индикаторы: объем и моментум уже направлены против дальнейшего роста цены. Тестирование этого паттерна дает следующий отчет:

В периоде форвардного тестирования паттерн позволяет остаться на уровне безубыточности, что, строго говоря, указывает на некоторый потенциал. Однако он все же уступает pattern-2 и pattern-1. Преимущество этого сигнального паттерна в том, что, в отличие от резких дивергентных сигналов, он позволяет своевременно определить окончание тренда. Это может быть особенно полезно для управления сделками, поскольку помогает ответить на вопрос: "Когда закрывать прибыльную сделку?" Первый красный столбец Gator после длительной последовательности зеленых столбцов – сильный сигнал об изменении рыночной ситуации.

В сочетании с объемными признаками выравнивания A/D это показывает, что дальнейшее удержание позиции по тренду приносит все меньшую отдачу. Сила тренда и объемная активность начинают снижаться – такой паттерн предшествует периоду резких колебаний рынка или медленному развороту. Это дает трейдерам достаточно времени для реакции, поскольку такой сценарий развивается не так внезапно, как резкий откат. 

Заключение

Мы рассмотрели первые 5 из 10 запланированных сигнальных паттернов, которые можно получить, объединив осциллятор Gator и осциллятор накопления/распределения. Сочетание этих индикаторов позволяет выявлять более содержательные сигналы с учетом объема, что может улучшить как следование за трендом, так и управление сделками. Как отмечалось выше, их взаимодействие создает многомерный фильтр, который помогает подтвердить моментум, раньше выявить истощение и избежать ложных движений, на которых часто сбоят торговые системы, основанные на одном индикаторе.

Однако ни один метод не безупречен: выбор момента для подтверждения сигнала, поздние входы и особенности данных об объеме по-прежнему требуют активного контроля. В сочетании с Мастером MQL5, который может служить хорошей отправной точкой для новых читателей при создании советника, эта пара индикаторов может стать надежным инструментарием для системных трейдеров, поскольку дает более тонкий и многослойный сигнал, чем анализ одного лишь тренда или одного лишь объема. Мы рассмотрим паттерны с 5 по 9 в следующей статье.

имя	описание
WZ-77.mq5	Советник, собранный Мастером, в заголовке которого перечислены включенные файлы
SignalWZ_77.mqh	Файл пользовательского класса сигнала, используемый Мастером для создания советника