//--- 설명
#property description "스크립트는 \"표준 편차 채널\" 그래픽 개체를 그립니다."
#property description "고정점 좌표는 다음 크기의 백분율로 설정됩니다"
#property description "차트 창."
//--- 스크립트 실행 중 입력 매개변수의 표시 창
#property script_show_inputs
//--- 스크립트의 입력 매개변수
input string InpName="StdDevChannel"; // 채널 이름
input int InpDate1=10; // 첫 번째 점 날짜(%)
input int InpDate2=40; // 두 번째 점 날짜(%)
input double InpDeviation=1.0; // 편차
input color InpColor=clrRed; // 채널 색상
input ENUM_LINE_STYLE InpStyle=STYLE_DASHDOTDOT; // 채널 선 스타일
input int InpWidth=2; // 채널 선 너비
input bool InpFill=false; // 채널 색상 채우기
input bool InpBack=false; // 배경 채널
input bool InpSelection=true; // 이동하려면 강조 표시
input bool InpRayLeft=false; // 채널 좌측으로 연장
input bool InpRayRight=false; // 채널 우측으로 연장
input bool InpHidden=true; // 개체 목록에 숨겨짐
input long InpZOrder=0; // 마우스 클릭 우선 순위
//+------------------------------------------------------------------+
//| 주어진 좌표를 기준으로 표준 편차 채널 생성 |
//+------------------------------------------------------------------+
bool StdDevChannelCreate(const long chart_ID=0, // 차트의 ID
const string name="Channel", // 채널 이름
const int sub_window=0, // 하위 창 인덱스
datetime time1=0, // 첫 번째 점 시간
datetime time2=0, // 두 번째 점 시간
const double deviation=1.0, // 편차
const color clr=clrRed, // 채널 색상
const ENUM_LINE_STYLE style=STYLE_SOLID, // 채널 선 스타일
const int width=1, // 채널 선 너비
const bool fill=false, // 채널 색상 채우기
const bool back=false, // 배경에
const bool selection=true, // 이동하려면 강조 표시
const bool ray_left=false, // 좌측으로 채널 연속
const bool ray_right=false, // 우측으로 채널 연속
const bool hidden=true, // 개체 목록에 숨겨짐
const long z_order=0) // 마우스 클릭 우선 순위
{
//--- 고정점이 설정되지 않은 경우 고정점의 좌표 설정
ChangeChannelEmptyPoints(time1,time2);
//--- 오류 값 재설정
ResetLastError();
//--- 주어진 좌표로 채널 생성
if(!ObjectCreate(chart_ID,name,OBJ_STDDEVCHANNEL,sub_window,time1,0,time2,0))
{
Print(__FUNCTION__,
": 표준 편차 채널 생성 실패! Error code = ",GetLastError());
return(false);
}
//--- 채널 너비에 영향을 미치는 편차 값 설정
ObjectSetDouble(chart_ID,name,OBJPROP_DEVIATION,deviation);
//--- 채널 색상 설정
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- 채널 선 스타일 설정
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- 채널 선 너비 설정
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- 채널 채우기 모드 활성화(true) 또는 비활성화(false)
ObjectSetInteger(chart_ID,name,OBJPROP_FILL,fill);
//--- 전경(false) 또는 배경(true)에 표시
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- 이동할 채널을 강조 표시하는 모드를 활성화(true) 또는 비활성화(false)
//--- ObjectCreate 함수를 사용하여 그래픽 개체를 만드는 경우 개체는
//--- 기본적으로 강조 표시되고 이동됩니다. 이 메서드 내에서 선택 매개변수
//--- 기본적으로 true이므로 개체를 강조 표시하고 이동할 수 있습니다.
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- 채널 디스플레이의 좌측 연속 모드 활성화(true) 또는 비활성화(false)
ObjectSetInteger(chart_ID,name,OBJPROP_RAY_LEFT,ray_left);
//--- 채널 디스플레이 우측 연속 모드를 활성화(true) 또는 비활성화(false)
ObjectSetInteger(chart_ID,name,OBJPROP_RAY_RIGHT,ray_right);
//--- 개체 목록에서 그래픽 개체 이름 숨기기(true) 또는 표시(false)
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- 차트에서 마우스 클릭 이벤트 수신 우선 순위 설정
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| 채널의 고정점 이동 |
//+------------------------------------------------------------------+
bool StdDevChannelPointChange(const long chart_ID=0, // 차트의 ID
const string name="Channel", // 채널 이름
const int point_index=0, // 고정점 인덱스
datetime time=0) // 고정점 시간 좌표
{
//--- 점 시간이 설정되지 않은 경우 점을 현재 막대로 이동합니다
if(!time)
time=TimeCurrent();
//--- 오류 값 재설정
ResetLastError();
//--- 고정점 이동
if(!ObjectMove(chart_ID,name,point_index,time,0))
{
Print(__FUNCTION__,
": 고정점 이동 실패! Error code = ",GetLastError());
return(false);
}
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| 채널 편차 변경 |
//+------------------------------------------------------------------+
bool StdDevChannelDeviationChange(const long chart_ID=0, // 차트의 ID
const string name="Channel", // 채널 이름
const double deviation=1.0) // 편차
{
//--- 오류 값 재설정
ResetLastError();
//--- 추세 선 경사각 변경
if(!ObjectSetDouble(chart_ID,name,OBJPROP_DEVIATION,deviation))
{
Print(__FUNCTION__,
": 채널 편차 변경 실패! Error code = ",GetLastError());
return(false);
}
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| 채널 삭제 |
//+------------------------------------------------------------------+
bool StdDevChannelDelete(const long chart_ID=0, // 차트의 ID
const string name="Channel") // 채널 이름
{
//--- 오류 값 재설정
ResetLastError();
//--- 채널 삭제
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": 채널 삭제 실패! Error code = ",GetLastError());
return(false);
}
//--- 실행 성공
return(true);
}
//+-------------------------------------------------------------------------+
//| 채널의 고정점 값을 확인하고 기본값을 설정 |
//| 빈 곳의 경우 |
//+-------------------------------------------------------------------------+
void ChangeChannelEmptyPoints(datetime &time1,datetime &time2)
{
//--- 두 번재 점의 시간이 설정되지 않은 경우 현재 막대에 표시됩니다
if(!time2)
time2=TimeCurrent();
//--- 첫 번째 점의 시간이 설정되지 않은 경우 두 번째 점에 남은 9 막대가 위치합니다
if(!time1)
{
//--- 마지막 10개 막대가 열린 시간을 수신하기 위한 배열
datetime temp[10];
CopyTime(Symbol(),Period(),time2,10,temp);
//--- 두 번째 막대에서 남은 9개 막대에 첫 번째 점을 설정
time1=temp[0];
}
}
//+------------------------------------------------------------------+
//| 스크립트 프로그램 시작 함수 |
//+------------------------------------------------------------------+
void OnStart()
{
//--- 입력 매개변수의 정확성 확인
if(InpDate1<0 || InpDate1>100 ||
InpDate2<0 || InpDate2>100)
{
Print("오류! 입력 매개변수의 잘못된 값!");
return;
}
//--- 차트 창에 표시되는 막대 수
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- 가격 배열 크기
int accuracy=1000;
//--- 사용할 날짜 및 가격 값을 저장하기 위한 배열
//--- 채널 고정점 좌표 설정 및 변경
datetime date[];
double price[];
//--- 메모리 할당
ArrayResize(date,bars);
ArrayResize(price,accuracy);
//--- 날짜 배열 채우기
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("시간 값 복사 실패! Error code = ",GetLastError());
return;
}
//--- 가격 배열 채우기
//--- 차트의 최고값과 최저값을 찾기
double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- 가격의 변경 단계를 정의 하고 배열 채우기
double step=(max_price-min_price)/accuracy;
for(int i=0;i<accuracy;i++)
price[i]=min_price+i*step;
//--- 채널을 그리기 위한 점 정의
int d1=InpDate1*(bars-1)/100;
int d2=InpDate2*(bars-1)/100;
//--- 표준 편차 채널 생성
if(!StdDevChannelCreate(0,InpName,0,date[d1],date[d2],InpDeviation,InpColor,InpStyle,
InpWidth,InpFill,InpBack,InpSelection,InpRayLeft,InpRayRight,InpHidden,InpZOrder))
{
return;
}
//--- 차트를 다시 그리고 1초 동안 대기
ChartRedraw();
Sleep(1000);
//--- 이제 채널을 우측 수평방향으로 이동하여 확장합니다
//--- 루프 카운터
int h_steps=bars/2;
//--- 채널 이동
for(int i=0;i<h_steps;i++)
{
//--- 다음의 값을 사용
if(d1<bars-1)
d1+=1;
if(d2<bars-1)
d2+=1;
//--- 고정점 이동
if(!StdDevChannelPointChange(0,InpName,0,date[d1]))
return;
if(!StdDevChannelPointChange(0,InpName,1,date[d2]))
return;
//--- 스크립트 작업이 강제로 비활성화 되었는지 확인
if(IsStopped())
return;
//--- 차트 다시 그리기
ChartRedraw();
// 0.05초 지연
Sleep(50);
}
//--- 1초 지연
Sleep(1000);
//--- 루프 카운터
double v_steps=InpDeviation*2;
//--- 채널 확장
for(double i=InpDeviation;i<v_steps;i+=10.0/accuracy)
{
if(!StdDevChannelDeviationChange(0,InpName,i))
return;
//--- 스크립트 작업이 강제로 비활성화 되었는지 확인
if(IsStopped())
return;
//--- 차트 다시 그리기
ChartRedraw();
}
//--- 1초 지연
Sleep(1000);
//--- 차트에서 채널을 삭제
StdDevChannelDelete(0,InpName);
ChartRedraw();
//--- 1초 지연
Sleep(1000);
//---
}
|