//--- 설명
#property description "스크립트는 차트 창에 비트맵을 생성합니다."
//--- 스크립트 실행 중 입력 매개변수의 표시 창
#property script_show_inputs
//--- 스크립트의 입력 매개변수
input string InpFile="\\Images\\dollar.bmp"; // 비트맵 파일 이름
input int InpWidth=24; // 가시 범위 X 좌표
input int InpHeight=24; // 가시 범위 Y 좌표
input int InpXOffset=4; // X축 가시 범위 변경
input int InpYOffset=4; // Y 축 가시 범위 변경
input color InpColor=clrRed; // 강조 표시된 경우 테두리 색상
input ENUM_LINE_STYLE InpStyle=STYLE_SOLID; // 강조 표시된 경우 선 스타일
input int InpPointWidth=1; // 이동하려는 점 크기
input bool InpBack=false; // 배경 개체
input bool InpSelection=false; // 이동하려면 강조 표시
input bool InpHidden=true; // 개체 목록에 숨겨짐
input long InpZOrder=0; // 마우스 클릭 우선 순위
//+------------------------------------------------------------------+
//| 차트 창에 비트맵 생성 |
//+------------------------------------------------------------------+
bool BitmapCreate(const long chart_ID=0, // 차트의 ID
const string name="Bitmap", // 비트맵 이름
const int sub_window=0, // 하위 창 인덱스
datetime time=0, // 고정점 시간
double price=0, // 고정점 가격
const string file="", // 비트맵 파일 이름
const int width=10, // X 좌표 가시 범위
const int height=10, // Y 좌표 가시 범위
const int x_offset=0, // X 축 가시 범위 변경
const int y_offset=0, // Y 축 가시 범위 변경
const color clr=clrRed, // 강조 표시된 경우 테두리 색상
const ENUM_LINE_STYLE style=STYLE_SOLID, // 강조 표시된 경우 선 스타일
const int point_width=1, // 점 크기 이동
const bool back=false, // 배경에
const bool selection=false, // 이동하려면 강조 표시
const bool hidden=true, // 개체 목록에 숨겨짐
const long z_order=0) // 마우스 클릭 우선 순위
{
//--- 고정점 좌표를 설정하지 않은 경우
ChangeBitmapEmptyPoint(time,price);
//--- 오류 값 재설정
ResetLastError();
//--- 비트맵 생성
if(!ObjectCreate(chart_ID,name,OBJ_BITMAP,sub_window,time,price))
{
Print(__FUNCTION__,
": 차트에 비트맵 생성 실패! Error code = ",GetLastError());
return(false);
}
//--- 이미지 파일 경로 설정
if(!ObjectSetString(chart_ID,name,OBJPROP_BMPFILE,file))
{
Print(__FUNCTION__,
": 이미지 불러오기 실패! Error code = ",GetLastError());
return(false);
}
//--- 너비 또는 높이 값인 경우, 이미지에 대한 가시 범위 설정
//--- 원본 이미지의 너비와 높이가 (각각) 초과합니다,
//--- 반대의 경우, 그려지는 것이 아닙니다,
//--- 이 값에 해당하는 부분만 그려집니다
ObjectSetInteger(chart_ID,name,OBJPROP_XSIZE,width);
ObjectSetInteger(chart_ID,name,OBJPROP_YSIZE,height);
//--- 가시 범위 내에 표시할 이미지 부분을 설정
//--- 기본 부분은 이미지 좌측 상단 영역이며, 값이 허용됩니다
//--- 이 영역에서 이동 수행 이미지의 다른 부분 표시
ObjectSetInteger(chart_ID,name,OBJPROP_XOFFSET,x_offset);
ObjectSetInteger(chart_ID,name,OBJPROP_YOFFSET,y_offset);
//--- 개체 강조 모드가 활성화된 경우 테두리 색 설정
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- 개체 강조 모드가 활성화된 경우 테두리 스타일 설정
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- 개체를 이동할 고정점 크기를 설정
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,point_width);
//--- 전경(false) 또는 배경(true)에 표시
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- 마우스를 사용하여 레이블 이동 모드 활성화(true) 또는 비활성화(false)
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- 개체 목록에서 그래픽 개체 이름 숨기기(true) 또는 표시(false)
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- 차트에서 마우스 클릭 이벤트 수신 우선 순위 설정
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| 비트맵의 새 이미지 설정 |
//+------------------------------------------------------------------+
bool BitmapSetImage(const long chart_ID=0, // 차트의 ID
const string name="Bitmap", // 비트맵 이름
const string file="") // 파일 경로
{
//--- 오류 값 재설정
ResetLastError();
//--- 이미지 파일 경로 설정
if(!ObjectSetString(chart_ID,name,OBJPROP_BMPFILE,file))
{
Print(__FUNCTION__,
": 이미지 불러오기 실패! Error code = ",GetLastError());
return(false);
}
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| 차트 창에 비트맵 이동 |
//+------------------------------------------------------------------+
bool BitmapMove(const long chart_ID=0, // 차트의 ID
const string name="Bitmap", // bitmap name
datetime time=0, // 고정점 시간
double price=0) // 고정점 가격
{
//--- 포인트 위치가 설정되지 않은 겨우 입찰 가격이 있는 현재 막대로 이동합니다
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- 오류 값 재설정
ResetLastError();
//--- 고정점 이동
if(!ObjectMove(chart_ID,name,0,time,price))
{
Print(__FUNCTION__,
": 고정점 이동 실패! Error code = ",GetLastError());
return(false);
}
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| 가시 범위(비트맵) 크기 설정 |
//+------------------------------------------------------------------+
bool BitmapChangeSize(const long chart_ID=0, // 차트의 ID
const string name="Bitmap", // 비트맵 이름
const int width=0, // 비트맵 너비
const int height=0) // 비트맵 높이
{
//--- 오류 값 재설정
ResetLastError();
//--- 비트맵 크기 변경
if(!ObjectSetInteger(chart_ID,name,OBJPROP_XSIZE,width))
{
Print(__FUNCTION__,
": 비트맵 너비 변경 실패! Error code = ",GetLastError());
return(false);
}
if(!ObjectSetInteger(chart_ID,name,OBJPROP_YSIZE,height))
{
Print(__FUNCTION__,
": 비트맵 높이 변경 실패! Error code = ",GetLastError());
return(false);
}
//--- 실행 성공
return(true);
}
//+--------------------------------------------------------------------+
//| 가시 범위 좌측 상단 모서리 좌표 변경 |
//+--------------------------------------------------------------------+
bool BitmapMoveVisibleArea(const long chart_ID=0, // 차트의 ID
const string name="Bitmap", // 비트맵 이름
const int x_offset=0, // X 좌표 가시 범위
const int y_offset=0) // Y 좌표 가시 범위
{
//--- 오류 값 재설정
ResetLastError();
//--- 비트맵의 가시성 범위 좌표 변경
if(!ObjectSetInteger(chart_ID,name,OBJPROP_XOFFSET,x_offset))
{
Print(__FUNCTION__,
": 가시 범위의 X 좌표 변경 실패! Error code = ",GetLastError());
return(false);
}
if(!ObjectSetInteger(chart_ID,name,OBJPROP_YOFFSET,y_offset))
{
Print(__FUNCTION__,
": 가시 범위의 Y 좌표 변경 실패! Error code = ",GetLastError());
return(false);
}
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| 비트맵 삭제 |
//+------------------------------------------------------------------+
bool BitmapDelete(const long chart_ID=0, // 차트의 ID
const string name="Bitmap") // 비트맵 이름
{
//--- 오류 값 재설정
ResetLastError();
//--- 레이블 삭제
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": 비트맵 삭제 실패! Error code = ",GetLastError());
return(false);
}
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| 고정점 값 확인 및 기본값 설정 |
//| 빈 곳의 경우 |
//+------------------------------------------------------------------+
void ChangeBitmapEmptyPoint(datetime &time,double &price)
{
//--- 점의 시간이 설정되지 않은 경우 현재 막대에 표시됩니다
if(!time)
time=TimeCurrent();
//--- 포인트 가격이 설정되지 않은 경우 입찰 값을 갖습니다
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
}
//+------------------------------------------------------------------+
//| 스크립트 프로그램 시작 함수 |
//+------------------------------------------------------------------+
void OnStart()
{
datetime date[]; // 표시된 막대의 날짜를 저장하기 위한 배열
double close[]; // 종가 가격을 저장하기 위한 배열
//--- 비트맵 파일 이름
string file="\\Images\\dollar.bmp";
//--- 차트 창에 표시되는 막대 수
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- 메모리 할당
ArrayResize(date,bars);
ArrayResize(close,bars);
//--- 날짜 배열 채우기
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("시간 값 복사 실패! Error code = ",GetLastError());
return;
}
//--- 종가 가격 배열 채우기
if(CopyClose(Symbol(),Period(),0,bars,close)==-1)
{
Print("종가 가격 값 복사 실패! Error code = ",GetLastError());
return;
}
//--- 이미지 표시 빈도 지정
int scale=(int)ChartGetInteger(0,CHART_SCALE);
//--- 단계 지정
int step=1;
switch(scale)
{
case 0:
step=27;
break;
case 1:
step=14;
break;
case 2:
step=7;
break;
case 3:
step=4;
break;
case 4:
step=2;
break;
}
//--- 고가 및 저가 막대의 값(간격 포함)에 대한 비트맵 생성
for(int i=0;i<bars;i+=step)
{
//--- 비트맵 생성
if(!BitmapCreate(0,"Bitmap_"+(string)i,0,date[i],close[i],InpFile,InpWidth,InpHeight,InpXOffset,
InpYOffset,InpColor,InpStyle,InpPointWidth,InpBack,InpSelection,InpHidden,InpZOrder))
{
return;
}
//--- 스크립트 작업이 강제로 비활성화 되었는지 확인
if(IsStopped())
return;
//--- 차트 다시 그리기
ChartRedraw();
// 0.05초 지연
Sleep(50);
}
//--- 0.5초 지연
Sleep(500);
//--- 매도 기호 삭제
for(int i=0;i<bars;i+=step)
{
if(!BitmapDelete(0,"Bitmap_"+(string)i))
return;
if(!BitmapDelete(0,"Bitmap_"+(string)i))
return;
//--- 차트 다시 그리기
ChartRedraw();
// 0.05초 지연
Sleep(50);
}
//---
}
|