//--- 설명
#property description "스크립트가 차트 장에 \"Buy\" 기호를 그립니다."
//--- 스크립트 실행 중 입력 매개변수의 표시 창
#property script_show_inputs
//--- 스크립트의 입력 매개변수
input color InpColor=C'3,95,172'; // 기호 색상
//+------------------------------------------------------------------+
//| 매수 기호 생성 |
//+------------------------------------------------------------------+
bool ArrowBuyCreate(const long chart_ID=0, // 차트의 ID
const string name="ArrowBuy", // 신호 이름
const int sub_window=0, // 하위 창 인덱스
datetime time=0, // 고정점 시간
double price=0, // 고정점 가격
const color clr=C'3,95,172', // 기호 색상
const ENUM_LINE_STYLE style=STYLE_SOLID, // 선 스타일(강조 표시된 경우)
const int width=1, // 선 크기 (강조 표시된 경우)
const bool back=false, // 배경에
const bool selection=false, // 이동하려면 강조 표시
const bool hidden=true, // 개체 목록에 숨겨짐
const long z_order=0) // 마우스 클릭 우선 순위
{
//--- 고정점 좌표를 설정하지 않은 경우
ChangeArrowEmptyPoint(time,price);
//--- 오류 값 재설정
ResetLastError();
//--- 기호 생성
if(!ObjectCreate(chart_ID,name,OBJ_ARROW_BUY,sub_window,time,price))
{
Print(__FUNCTION__,
": \"Buy\" 기호 생성 실패! Error code = ",GetLastError());
return(false);
}
//--- 기호 설정 설정
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- 선 스타일 설정 (강조 표시된 경우)
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- 선 크기 설정 (강조 표시된 경우)
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- 전경(false) 또는 배경(true)에 표시
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- 마우스를 사용하여 기호를 이동하는 모드를 활성화(true) 또는 비활성화(false)
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- 개체 목록에서 그래픽 개체 이름 숨기기(true) 또는 표시(false)
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- 차트에서 마우스 클릭 이벤트 수신 우선 순위 설정
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| 고정점 이동 |
//+------------------------------------------------------------------+
bool ArrowBuyMove(const long chart_ID=0, // 차트의 ID
const string name="ArrowBuy", // 개체 이름
datetime time=0, // 고정점 시간 좌표
double price=0) // 고정점 가격 좌표
{
//--- 포인트 위치가 설정되지 않은 겨우 입찰 가격이 있는 현재 막대로 이동합니다
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- 오류 값 재설정
ResetLastError();
//--- 고정점 이동
if(!ObjectMove(chart_ID,name,0,time,price))
{
Print(__FUNCTION__,
": 고정점 이동 실패! Error code = ",GetLastError());
return(false);
}
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| 매수 기호 삭제 |
//+------------------------------------------------------------------+
bool ArrowBuyDelete(const long chart_ID=0, // 차트의 ID
const string name="ArrowBuy") // 기호 이름
{
//--- 오류 값 재설정
ResetLastError();
//--- 기호 삭제
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": \"Buy\" 기호 삭제 실패! Error code = ",GetLastError());
return(false);
}
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| 고정점 값 확인 및 기본값 설정 |
//| 빈 곳의 경우 |
//+------------------------------------------------------------------+
void ChangeArrowEmptyPoint(datetime &time,double &price)
{
//--- 점의 시간이 설정되지 않은 경우 현재 막대에 표시됩니다
if(!time)
time=TimeCurrent();
//--- 포인트 가격이 설정되지 않은 경우 입찰 값을 갖습니다
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
}
//+------------------------------------------------------------------+
//| 스크립트 프로그램 시작 함수 |
//+------------------------------------------------------------------+
void OnStart()
{
datetime date[]; // 표시된 막대의 날짜를 저장하기 위한 배열
double low[]; // 표시된 막대의 저가 가격을 저장하기 위한 배열
double high[]; // 표시된 막대의 고가 가격을 저장하기 위한 배열
//--- 차트 창에 표시되는 막대 수
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- 메모리 할당
ArrayResize(date,bars);
ArrayResize(low,bars);
ArrayResize(high,bars);
//--- 날짜 배열 채우기
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("시간 값 복사 실패! Error code = ",GetLastError());
return;
}
//--- 저가 가격의 배열 채우기
if(CopyLow(Symbol(),Period(),0,bars,low)==-1)
{
Print("저가 가격의 값 복사 실패! Error code = ",GetLastError());
return;
}
//--- 고가 가격의 배열 채우기
if(CopyHigh(Symbol(),Period(),0,bars,high)==-1)
{
Print("고가 가격 값 복사 실패! Error code = ",GetLastError());
return;
}
//--- 표시된 각 막대에 대해 저가 지점에 매수 기호 생성
for(int i=0;i<bars;i++)
{
if(!ArrowBuyCreate(0,"ArrowBuy_"+(string)i,0,date[i],low[i],InpColor))
return;
//--- 스크립트 작업이 강제로 비활성화 되었는지 확인
if(IsStopped())
return;
//--- 차트 다시 그리기
ChartRedraw();
// 0.05초 지연
Sleep(50);
}
//--- 표시된 각 막대에 대해 고가 지점으로 매수 기호 이동
for(int i=0;i<bars;i++)
{
if(!ArrowBuyMove(0,"ArrowBuy_"+(string)i,date[i],high[i]))
return;
//--- 스크립트 작업이 강제로 비활성화 되었는지 확인
if(IsStopped())
return;
//--- 차트 다시 그리기
ChartRedraw();
// 0.05초 지연
Sleep(50);
}
//--- 매수 기호 삭제
for(int i=0;i<bars;i++)
{
if(!ArrowBuyDelete(0,"ArrowBuy_"+(string)i))
return;
//--- 차트 다시 그리기
ChartRedraw();
// 0.05초 지연
Sleep(50);
}
//---
}
|