ArraySwap

Vertauscht die Inhalte von zwei dynamischen Arrays eines Typs. Für mehrdimensionale Arrays muss die Anzahl der Elemente in allen Dimensionen außer der ersten gleich sein.

bool  ArraySwap(
   void&  array1[],      // erstes Array
   void&  array2[]       // zweites Array
   );

Parameter

array1[]

[in][out]  Array numerischen Typs.

array2[]

[in][out]  Array numerischen Typs.

Rückgabewert

Wenn erfolgreich true, andernfalls false. In diesem Fall gibt GetLastError() den Fehlercode ERR_INVALID_ARRAY zurück.

Hinweis

Die Funktion akzeptiert dynamische Arrays von einem Typ und einer Dimension, außer der ersten. Für Integer-Typen wird das Vorzeichen ignoriert, d.h. char==uchar

Beispiel:

//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- Arrays für das Speichern von Kursen
   double source_array[][8];
   double   dest_array[][8];
   MqlRates rates[];
//--- Daten der letzten 20 Kerzen im aktuellen Zeitrahmen erhalten
   int copied=CopyRates(NULL,0,0,20,rates);
   if(copied<=0)
     {
      PrintFormat("CopyRates(%s,0,0,20,rates) failed, error=%d",
                  Symbol(),GetLastError());
      return;
     }
//--- die Größe des Arrays entsprechend der Anzahl der kopierten Daten setzen
   ArrayResize(source_array,copied);
//--- das Array rate_array_1[] mit Daten aus rates[] füllen
   for(int i=0;i<copied;i++)
     {
      source_array[i][0]=(double)rates[i].time;
      source_array[i][1]=rates[i].open;
      source_array[i][2]=rates[i].high;
      source_array[i][3]=rates[i].low;
      source_array[i][4]=rates[i].close;
      source_array[i][5]=(double)rates[i].tick_volume;
      source_array[i][6]=(double)rates[i].spread;
      source_array[i][7]=(double)rates[i].real_volume;
     }
//--- Daten zwischen source_array[] und dest_array[] vertauschen
   if(!ArraySwap(source_array,dest_array))
     {
      PrintFormat("ArraySwap(source_array,rate_array_2) failed, error code=%d",GetLastError());
      return;
     }
//--- sicherstellen, dass die Größe des Quellarrays nach dem Vertauschen gleich Null ist
   PrintFormat("ArraySwap() done: ArraySize(source_array)=%d",ArraySize(source_array));
//--- Daten des Empfänger-Arrays dest_array[] ausgeben
   ArrayPrint(dest_array);
  }

Siehe auch

ArrayCopy, ArrayFill, ArrayRange, ArrayIsDynamic