ArraySize

int  ArraySize(
   const void&  array[]    // das geprüfte Array
   );

void OnStart()
  {
//--- erstellen Sie die Arrays
   double one_dim[];
   double four_dim[][10][5][2];
//--- Größe
   int one_dim_size=25;
   int reserve=20;
   int four_dim_size=5;
//--- Hilfsvariable
   int size;
//--- trennen Sie den Speichern ohne der Reservierung
   ArrayResize(one_dim,one_dim_size);
   ArrayResize(four_dim,four_dim_size);
//--- 1. das eindimensionale Array
   Print("+==========================================================+");
   Print("die Größe des Arrays:");
   Print("1. Das eindimensionale Array");
   size=ArraySize(one_dim);
   PrintFormat("Die Größe der Nullmessung = %d, Die Größe des Arrays = %d",one_dim_size,size);
//--- 2. das vieldimensionale Array
   Print("2. Das vieldimensionale Array");
   size=ArraySize(four_dim);
   PrintFormat("Die Größe der Nullmessung = %d, Die Größe des Arrays = %d",four_dim_size,size);
//--- die Größe der Messungen
   int d_1=ArrayRange(four_dim,1);
   int d_2=ArrayRange(four_dim,2);
   int d_3=ArrayRange(four_dim,3);
   Print("Uberprüfung:");
   Print("Die Nullmessung = Die Größe des Arrays / (Die erste Messung * Die zweite Messung * Die dritte Messung)");
   PrintFormat("%d = %d / (%d * %d * %d)",size/(d_1*d_2*d_3),size,d_1,d_2,d_3);
//--- 3. das eindimensionale Array mit der Speicherreservierung
   Print("3. Das eindimensionale Array mit der Speicherreservierung");
//--- erhöhen Sie den Wert zweimal
   one_dim_size*=2;
//--- trennen Sie den Speichern mit der Reservierung
   ArrayResize(one_dim,one_dim_size,reserve);
//--- drucken Sie die Größe
   size=ArraySize(one_dim);
   PrintFormat("Die Größe mit der Reservierung = %d, Die wirkliche Größe des Arrays = %d",one_dim_size+reserve,size);
  }