#property copyright "Copyright 2025, MetaQuotes Ltd."
#property link "https://www.mql5.com"
#property version "1.00"
#define OBJ_NAME "TestObjectGetDouble" // Nombre del objeto
#define WND 0 // Subventana del gráfico
#define EXT " (%$)" // Cadena de formato para mostrar los valores de precio en los niveles
//+------------------------------------------------------------------+
//| Script program start function |
//+------------------------------------------------------------------+
void OnStart()
{
//--- identificador actual del gráfico, símbolo de este gráfico y Digits del símbolo
long chart_id= ChartID();
string symbol = ChartSymbol(chart_id);
int digits = (int)SymbolInfoInteger(symbol, SYMBOL_DIGITS);
//--- construimos el objeto gráfico "Niveles de Fibonacci", sobre los precios máximos y mínimos del gráfico visible
if(!CreateFibo(chart_id))
return;
//--- número de niveles del objeto
int total=(int)ObjectGetInteger(chart_id, OBJ_NAME, OBJPROP_LEVELS);
double value =0;
double price0=0;
double price1=0;
//--- precios de los puntos de anclaje
price0=ObjectGetDouble(chart_id, OBJ_NAME, OBJPROP_PRICE, 0);
price1=ObjectGetDouble(chart_id, OBJ_NAME, OBJPROP_PRICE, 1);
//--- en un ciclo por el número de niveles del objeto
for(int i=0; i<total; i++)
{
//--- obtenemos el valor establecido para el nivel actual
ResetLastError();
if(!ObjectGetDouble(chart_id, OBJ_NAME, OBJPROP_LEVELVALUE, i, value))
{
Print("ObjectGetDouble() failed. Error ", GetLastError());
return;
}
//--- obtenemos los precios máximo y mínimo del anclaje del objeto y la distancia entre ellos en valor de precio
double max=fmax(price0, price1);
double min=fmin(price0, price1);
double range=max-min;
//--- calculamos el valor de precio para el nivel de objeto actual
double level_price=min+range*value;
//--- establecemos el color para el nivel de modo que sea visible en la oscuridad y en el fondo claro del gráfico
ObjectSetInteger(chart_id, OBJ_NAME, OBJPROP_LEVELCOLOR, i, clrRed);
//--- establecemos la cadena de formato para el nivel, de modo que junto con el valor del nivel se muestre su valor de precio
string level_text=ObjectGetString(chart_id, OBJ_NAME, OBJPROP_LEVELTEXT, i);
if(StringFind(level_text, EXT)<0)
{
level_text+=EXT;
ObjectSetString(chart_id, OBJ_NAME, OBJPROP_LEVELTEXT, i, level_text);
}
//--- imprimimos en el diario el número de nivel y sus datos : el valor del nivel y su precio
PrintFormat("Fibo level [%d] value: %.3f, price: %.*f", i, value, digits, level_price);
}
/*
resultado:
Fibo level [0] value: 0.000, price: 0.61989
Fibo level [1] value: 0.236, price: 0.62533
Fibo level [2] value: 0.382, price: 0.62869
Fibo level [3] value: 0.500, price: 0.63140
Fibo level [4] value: 0.618, price: 0.63412
Fibo level [5] value: 1.000, price: 0.64292
Fibo level [6] value: 1.618, price: 0.65715
Fibo level [7] value: 2.618, price: 0.68018
Fibo level [8] value: 4.236, price: 0.71745
*/
}
//+------------------------------------------------------------------+
//| Crea un objeto gráfico de Niveles de Fibonacci en el gráfico especificado |
//+------------------------------------------------------------------+
bool CreateFibo(const long chart_id)
{
//--- los niveles de Fibonacci los dibujaremos desde el mayor hasta el menor valor visible del precio en el gráfico; los obtenemos
double price_high=0, price_low=0;
datetime time_high =0, time_low =0;
if(!GetChartExtremums(chart_id, price_high, price_low, time_high, time_low))
return(false);
//--- construimos el objeto "niveles de Fibonacci" en las coordenadas de precio/hora encontradas
if(!ObjectCreate(chart_id, OBJ_NAME, OBJ_FIBO, WND, time_high, price_high, time_low, price_low))
{
PrintFormat("%s: ObjectCreate() failed. Error %d",__FUNCTION__, GetLastError());
return(false);
}
//--- todo ha tenido éxito, así que actualizamos el gráfico y retornamos true
ChartRedraw();
return(true);
}
//+------------------------------------------------------------------+
//| Retornamos los precios máximos y mínimos en el gráfico y su hora |
//+------------------------------------------------------------------+
bool GetChartExtremums(const long chart_id, double &price_high, double &price_low, datetime &time_high, datetime &time_low)
{
//--- ponemos a cero las variables
price_high=price_low=0;
time_high =time_low =0;
//--- símbolo del gráfico
string symbol = ChartSymbol(chart_id);
//--- según el número de la primera barra visible y el número de barras en el gráfico, calculamos el inicio del rango de las series de tiempo copiadas
int first = (int)ChartGetInteger(chart_id, CHART_FIRST_VISIBLE_BAR);
int count = (int)ChartGetInteger(chart_id, CHART_VISIBLE_BARS);
int start = first+1-count;
//--- arrays donde se copiarán las series temporales
double array_high[];
double array_low[];
datetime array_time[];
int index;
//--- copiamos en arrays tres series temporales en una cantidad count y comenzando desde start
ResetLastError();
if(CopySeries(symbol, PERIOD_CURRENT, start, count, COPY_RATES_TIME|COPY_RATES_HIGH|COPY_RATES_LOW, array_time, array_high, array_low)!=count)
{
PrintFormat("%s: CopySeries() failed. Error %d",__FUNCTION__, GetLastError());
return(false);
}
//--- buscamos el índice de precio máximo en el array array_high
index=ArrayMaximum(array_high);
if(index<0)
{
PrintFormat("%s: ArrayMaximum() failed. Error %d",__FUNCTION__, GetLastError());
return(false);
}
//--- anotamos el precio más alto en el gráfico visible y el valor de la barra de hora en la que se encuentra este precio
price_high=array_high[index];
time_high=array_time[index];
//--- buscamos el índice de precio mínimo en el array array_low
index=ArrayMinimum(array_low);
if(index<0)
{
PrintFormat("%s: ArrayMinimum() failed. Error %d",__FUNCTION__, GetLastError());
return(false);
}
//--- anotamos el precio más bajo en el gráfico visible y el valor de la barra de hora en la que se encuentra este precio
price_low=array_low[index];
time_low=array_time[index];
//--- todo ha tenido éxito
return(true);
}
|