//+------------------------------------------------------------------+
//| DRAW_COLOR_ZIGZAG.mq5 |
//| Copyright 2000-2024, MetaQuotes Ltd. |
//| https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link "https://www.mql5.com"
#property version "1.00"
#property description "Индикатор для демонстрации DRAW_COLOR_ZIGZAG"
#property description "Рисует ломанную линию цветными отрезками, цвет зависит от номера дня недели"
#property description "Цвет, толщина и стиль отрезков меняется случайным"
#property description " образом через каждые N тиков"
#property indicator_chart_window
#property indicator_buffers 3
#property indicator_plots 1
//--- plot Color_Zigzag
#property indicator_label1 "Color_Zigzag"
#property indicator_type1 DRAW_COLOR_ZIGZAG
//--- зададим 8 цветов для раскраски секций (они хранятся в специальном массиве)
#property indicator_color1 clrRed,clrBlue,clrGreen,clrYellow,clrMagenta,clrCyan,clrLime,clrOrange
#property indicator_style1 STYLE_SOLID
#property indicator_width1 1
//--- input параметр
input int N=5; // кол-во тиков для изменения
int color_sections;
//--- буферы значений концов отрезков
double Color_ZigzagBuffer1[];
double Color_ZigzagBuffer2[];
//--- буфер индексов цвета для концов отрезков
double Color_ZigzagColors[];
//--- массив для хранения цветов содержит 14 элементов
color colors[]=
{
clrRed,clrBlue,clrGreen,clrChocolate,clrMagenta,clrDodgerBlue,clrGoldenrod,
clrIndigo,clrLightBlue,clrAliceBlue,clrMoccasin,clrWhiteSmoke,clrCyan,clrMediumPurple
};
//--- массив для хранения стилей отрисовки линии
ENUM_LINE_STYLE styles[]={STYLE_SOLID,STYLE_DASH,STYLE_DOT,STYLE_DASHDOT,STYLE_DASHDOTDOT};
//+------------------------------------------------------------------+
//| Custom indicator initialization function |
//+------------------------------------------------------------------+
int OnInit()
{
//--- indicator buffers mapping
SetIndexBuffer(0,Color_ZigzagBuffer1,INDICATOR_DATA);
SetIndexBuffer(1,Color_ZigzagBuffer2,INDICATOR_DATA);
SetIndexBuffer(2,Color_ZigzagColors,INDICATOR_COLOR_INDEX);
//---- количество цветов для раскраски зигзага
color_sections=8; // см. комментарий к свойству #property indicator_color1
//---
return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| Custom indicator iteration function |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
const int prev_calculated,
const datetime &time[],
const double &open[],
const double &high[],
const double &low[],
const double &close[],
const long &tick_volume[],
const long &volume[],
const int &spread[])
{
static int ticks=0;
//--- считаем тики для изменения стиля, цвета и толщины линии
ticks++;
//--- если накопилось достаточное число тиков
if(ticks>=N)
{
//--- меняем свойства линии
ChangeLineAppearance();
//--- меняем цвета, которыми рисуются секции
ChangeColors(colors,color_sections);
//--- сбрасываем счетчик тиков в ноль
ticks=0;
}
//--- структура времени понадобится для получения дня недели каждого бара
MqlDateTime dt;
//--- позиция начала расчетов
int start=0;
//--- если индикатор рассчитывался на предыдущем тике, то начинам расчет с предпоследнего
if(prev_calculated!=0) start=prev_calculated-1;
//--- цикл расчетов
for(int i=start;i<rates_total;i++)
{
//--- запишем время открытия бара в структуру
TimeToStruct(time[i],dt);
//--- если номер бара четный
if(i%2==0)
{
//--- пишем в 1-ый буфер High, во 2-ой Low
Color_ZigzagBuffer1[i]=high[i];
Color_ZigzagBuffer2[i]=low[i];
//--- цвет отрезка
Color_ZigzagColors[i]=dt.day_of_year%color_sections;
}
//--- номер бара нечетный
else
{
//--- заполняем бар в обратном порядке
Color_ZigzagBuffer1[i]=low[i];
Color_ZigzagBuffer2[i]=high[i];
//--- цвет отрезка
Color_ZigzagColors[i]=dt.day_of_year%color_sections;
}
}
//--- return value of prev_calculated for next call
return(rates_total);
}
//+------------------------------------------------------------------+
//| Изменяет цвет отрезков зигзага |
//+------------------------------------------------------------------+
void ChangeColors(color &cols[],int plot_colors)
{
//--- количество цветов
int size=ArraySize(cols);
//---
string comm=ChartGetString(0,CHART_COMMENT)+"\r\n\r\n";
//--- для каждого цветового индекса зададим новый цвет случайным образом
for(int plot_color_ind=0;plot_color_ind<plot_colors;plot_color_ind++)
{
//--- получим случайное число
int number=MathRand();
//--- получим индекс в массиве col[] как остаток от целочисленного деления
int i=number%size;
//--- установим цвет для каждого индекса как свойство PLOT_LINE_COLOR
PlotIndexSetInteger(0, // номер графического стиля
PLOT_LINE_COLOR, // идентификатор свойства
plot_color_ind, // индекс цвета, куда запишем цвет
cols[i]); // новый цвет
//--- запишем цвета
comm=comm+StringFormat("ZigzagColorIndex[%d]=%s \r\n",plot_color_ind,ColorToString(cols[i],true));
ChartSetString(0,CHART_COMMENT,comm);
}
//---
}
//+------------------------------------------------------------------+
//| Изменяет внешний вид отрезков в зигзаге |
//+------------------------------------------------------------------+
void ChangeLineAppearance()
{
//--- строка для формирования информации о свойствах Color_ZigZag
string comm="";
//--- блок изменения толщины линии
int number=MathRand();
//--- получим толщину как остаток от целочисленного деления
int width=number%5; // толщина задается от о до 4
//--- установим цвет как свойство PLOT_LINE_WIDTH
PlotIndexSetInteger(0,PLOT_LINE_WIDTH,width);
//--- запишем толщину линии
comm=comm+"\r\nWidth="+IntegerToString(width);
//--- блок изменения стиля линии
number=MathRand();
//--- делитель числа равен размеру массива styles
int size=ArraySize(styles);
//--- получим индекс для выбора нового стиля как остаток от целочисленного деления
int style_index=number%size;
//--- установим цвет как свойство PLOT_LINE_COLOR
PlotIndexSetInteger(0,PLOT_LINE_STYLE,styles[style_index]);
//--- запишем стиль линии
comm="\r\n"+EnumToString(styles[style_index])+""+comm;
//--- выведем информацию на график через комментарий
Comment(comm);
}
|
