#property indicator_separate_window
#property indicator_minimum 0
#property indicator_maximum 100
//--- visualiza três níveis horizontais na janela separada
#property indicator_level1 20
#property indicator_level2 50
#property indicator_level3 80
//--- definir a espessura dos níveis horizontais
#property indicator_levelwidth 5
//--- definir a cor dos níveis horizontais
#property indicator_levelcolor clrAliceBlue
//--- definir o estilo dos níveis horizontais
#property indicator_levelstyle STYLE_DOT
//+------------------------------------------------------------------+
//| Função de inicialização do indicador customizado |
//+------------------------------------------------------------------+
int OnInit()
{
//--- definir as descrições dos níveis horizontais
IndicatorSetString(INDICATOR_LEVELTEXT,0,"Primeiro Nível (índice 0)");
IndicatorSetString(INDICATOR_LEVELTEXT,1,"Segundo Nível (índice 1)");
IndicatorSetString(INDICATOR_LEVELTEXT,2,"Terceiro Nível (índice 2)");
//--- define o mome abreviado para o indicador
IndicatorSetString(INDICATOR_SHORTNAME,"IndicatorSetInteger() Demo");
return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| Função de iteração do indicador customizado |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
const int prev_calculated,
const datetime &time[],
const double &open[],
const double &high[],
const double &low[],
const double &close[],
const long &tick_volume[],
const long &volume[],
const int &spread[])
{
static int tick_counter=0;
//--- calcular ticks
tick_counter++;
//--- e calcular as cores dos níveis horizontais, dependendo do contador de tick
ChangeLevelColor(0,tick_counter,3,6,10); // três últimos parâmetros estão comutando a cor
ChangeLevelColor(1,tick_counter,3,6,8);
ChangeLevelColor(2,tick_counter,4,7,9);
//--- modificar o estilo dos níveis horizontais
ChangeLevelStyle(0,tick_counter);
ChangeLevelStyle(1,tick_counter+5);
ChangeLevelStyle(2,tick_counter+15);
//--- obter a largura como o restante da divisão inteira por 5 ticks
int width=tick_counter%5;
//--- iteração em todos os níveis horizontais e definir espessura
for(int l=0;l<3;l++)
IndicatorSetInteger(INDICATOR_LEVELWIDTH,l,width+1);
//--- valor retorno de prev_calculated para a próxima chamada
return(rates_total);
}
//+------------------------------------------------------------------+
//| Definir a cor da linha horizontal na janela separada do indicador|
//+------------------------------------------------------------------+
void ChangeLevelColor(int level, // número de linha horizontal
int tick_number,// dividendo, para obter o número do restante da divisão
int f_trigger, // primeiro divisor de comutação de cor
int s_trigger, // segundo divisor de comutação de cor
int t_trigger) // terceiro divisor de comutação de cor
{
static color colors[3]={clrRed,clrBlue,clrGreen};
//--- índice de cor a partir do array colors[]
int index=-1;
//--- calcular o número de cor a partir do array colors[] para pintar linha horizontal
if(tick_number%f_trigger==0)
index=0; // se tick_number divide por f_trigger sem o restante
if(tick_number%s_trigger==0)
index=1; // se tick_number divide por s_trigger sem o restante
if(tick_number%t_trigger==0)
index=2; // se tick_number divide por t_trigger sem o restante
//--- se a cor está definida, estabeleça-a
if(index!=-1)
IndicatorSetInteger(INDICATOR_LEVELCOLOR,level,colors[index]);
//---
}
//+------------------------------------------------------------------+
//| Define estilo de linha horizontal na janela do indicador separado|
//+------------------------------------------------------------------+
void ChangeLevelStyle(int level, // número de linha horizontal
int tick_number// número para obter o resto da divisão
)
{
//--- array para armazenar estilos
static ENUM_LINE_STYLE styles[5]=
{STYLE_SOLID,STYLE_DASH,STYLE_DOT,STYLE_DASHDOT,STYLE_DASHDOTDOT};
//--- índice de estilo a partir do array styles[]
int index=-1;
//--- calcular o número a partir do array styles[] para definir a linha horizontal
if(tick_number%50==0)
index=5; // se tick_number divide por 50 sem o restante, então o estilo é STYLE_DASHDOTDOT
if(tick_number%40==0)
index=4; // ... style is STYLE_DASHDOT
if(tick_number%30==0)
index=3; // ... STYLE_DOT
if(tick_number%20==0)
index=2; // ... STYLE_DASH
if(tick_number%10==0)
index=1; // ... STYLE_SOLID
//--- se o estilo está definido, estabeleça-o
if(index!=-1)
IndicatorSetInteger(INDICATOR_LEVELSTYLE,level,styles[index]);
}
|
