Nesnelerin Görünürlükleri

void OnStart()
  {
//---
   string highlevel="PreviousDayHigh";
   string lowlevel="PreviousDayLow";
   double prevHigh;           // Önceki günün yüksek (High) fiyatı
   double prevLow;            // Önceki günün düşük (Low) fiyatı
   double highs[],lows[];     // High ve Low için diziler
 
//--- Son hata değerini sıfırla
   ResetLastError();
//--- Günlük zaman aralığındaki son 2 High değerini al
   int highsgot=CopyHigh(Symbol(),PERIOD_D1,0,2,highs);
   if(highsgot>0) // Eğer kopyalama başarılı olduysa
     {
      Print("Son iki günün High (yüksek) fiyatları başarıyla alındı");
      prevHigh=highs[0]; // Önceki günün High değeri
      Print("prevHigh = ",prevHigh);
      if(ObjectFind(0,highlevel)<0) // highlevel isminde bir nesne bulunamadı
        {
         ObjectCreate(0,highlevel,OBJ_HLINE,0,0,0); // Yatal çizgi nesnesini oluştur
        }
      //--- highlevel çizgisi için fiyat seviyesinin değerini ayarla
      ObjectSetDouble(0,highlevel,OBJPROP_PRICE,0,prevHigh);
      //--- Görünürlüğü sadece PERIOD_M10 ve PERIOD_H4 için ayarla
      ObjectSetInteger(0,highlevel,OBJPROP_TIMEFRAMES,OBJ_PERIOD_M10|OBJ_PERIOD_H4);
     }
   else
     {
      Print("Son 2 günün High fiyatları alınamadı, Hata = ",GetLastError());
     }
 
//--- Son hata değerini sıfırla
   ResetLastError();
//--- Son 2 günün, günlük High fiyatlarını al
   int lowsgot=CopyLow(Symbol(),PERIOD_D1,0,2,lows);
   if(lowsgot>0) // Eğer kopyalama başarılıysa
     {
      Print("Son iki günün Low (düşük) fiyatları başarıyla alındı");
      prevLow=lows[0]; // Önceki günün Low değeri
      Print("prevLow = ",prevLow);
      if(ObjectFind(0,lowlevel)<0) // lowlevel isimli bir nesne bulunmadı
        {
         ObjectCreate(0,lowlevel,OBJ_HLINE,0,0,0); // Yatay Çizgi nesnesini oluştur 
        }
      //--- lowlevel çizgisi fiyat seviyesini ayarla
      ObjectSetDouble(0,lowlevel,OBJPROP_PRICE,0,prevLow);
      //--- Görünürlüğü sadece PERIOD_M10 ve PERIOD_H4 için ayarla
      ObjectSetInteger(0,lowlevel,OBJPROP_TIMEFRAMES,OBJ_PERIOD_M10|OBJ_PERIOD_H4);
     }
   else Print("Son iki gün için Low (düşük) fiyatlar alınamadı, Error = ",GetLastError());
 
   ChartRedraw(0); // çizelgeyi zorla yenile
  }